User:TweetsFactsAndQueries/Queries/pictures of animals with female grammatical gender in German but male grammatical gender in French

Originally posted on Twitter and on Mastodon. Following a suggestion by Jens Ohlig.

#defaultView:ImageGrid
SELECT ?animal ?deLemmas ?frLemmas ?image
WITH {
  SELECT ?animal (STRLANG(GROUP_CONCAT(?deLemma; separator = "/"), "de") AS ?deLemmas) (STRLANG(GROUP_CONCAT(?frLemma; separator = "/"), "fr") AS ?frLemmas) WHERE {
    ?de dct:language wd:Q188;
        wikibase:lexicalCategory wd:Q1084;
        wikibase:lemma ?deLemma;
        wdt:P5185 wd:Q1775415;
        ontolex:sense [ wdt:P5137 ?animal ].
    ?fr dct:language wd:Q150;
        wikibase:lexicalCategory wd:Q1084;
        wikibase:lemma ?frLemma;
        wdt:P5185 wd:Q499327;
        ontolex:sense [ wdt:P5137 ?animal ].
    ?animal wdt:P279+ wd:Q729.
  }
  GROUP BY ?animal
} AS %animals
WITH {
  SELECT ?animal ?animalLabel ?deLemmas ?frLemmas WHERE {
    INCLUDE %animals.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
} AS %animalsWithLabels
WHERE {
  INCLUDE %animalsWithLabels.
  BIND(CONCAT("haswbstatement:P180=", STRAFTER(STR(?animal), STR(wd:))) AS ?search)
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "commons.wikimedia.org";
                    mwapi:srsearch ?search;
                    mwapi:srnamespace "6"; # NS_FILE
                    mwapi:srlimit "max".
    ?title wikibase:apiOutput mwapi:title.
  }
  BIND(IRI(CONCAT("http://commons.wikimedia.org/wiki/Special:FilePath/", STRAFTER(?title, "File:"))) AS ?image)
}

Try it!