Open main menu

Welcome

For a detailed presentation : please read my page in Wikipedia

Bienvenu

Pour une présentation détaillée : lisez ma page sur Wikipédia

Contents

RessourcesEdit

OutilsEdit

NomenclatureEdit

AvancementsEdit

Lac dans Lanaudière sans drainage basin (P4614) : 98%Edit

# Lac de Lanaudière sans bassin versant
SELECT DISTINCT ?item ?itemLabel ?locLabel 
WHERE
{
    ?item wdt:P31 wd:Q23397 .
    ?item wdt:P131* wd:Q692825 .
    ?item wdt:P131 ?loc .
    FILTER NOT EXISTS { ?item wdt:P4614 ?bassin }
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr" 
    }
}
ORDER BY (?itemLabel) 
LIMIT 3000

Try it!

Affluents et sous-affluent du Saint-Laurent sans drainage basin (P4614)Edit

# Affluents et sous-affluent du Saint-Laurent 
SELECT DISTINCT ?id ?idLabel ?municipLabel ?mrcLabel ?regionLabel  
WHERE 
{
    ?id wdt:P31 wd:Q4022 .
    ?id wdt:P403* wd:Q134750 .
    ?id wdt:P131 ?municip .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131* wd:Q176 .
    ?mrc wdt:P131 ?region .
    FILTER NOT EXISTS { ?id wdt:P4614 ?bassin }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 500

Try it!

Cours d'eau du bassin de l'estuaire du Saint-Laurent sans identifiant CTQEdit

# Cours d'eau du bassin de l'estuaire du Saint-Laurent
SELECT DISTINCT ?id ?idLabel ?municipLabel ?mrcLabel ?regionLabel  
WHERE 
{
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id wdt:P4614* wd:Q51885235  .
    ?id wdt:P131 ?municip .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .
    FILTER NOT EXISTS { ?id wdt:P2100 ?ctq }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 500

Try it!

Canton du Québec ayant une municipalité en P131 : 22%Edit

# Canton du Québec ayant une municipalité en P131
SELECT ?item ?itemLabel ?itemDescription ?alias ?dtFondation ?km2 ?munLabel ?mrcLabel ?regionLabel ?coord 
WHERE {
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
    ?item wdt:P17 wd:Q16 .
    ?item wdt:P131/wdt:P131* ?mun .
    ?mun wdt:P31/wdt:P279* wd:Q3327873 .
    ?mun wdt:P131/wdt:P131* ?mrc .
    ?mrc wdt:P31/wdt:P279* wd:Q204613.
    ?mrc wdt:P131/wdt:P131* ?region .
    ?region wdt:P31/wdt:P279* wd:Q55998242 .
    OPTIONAL {?item skos:altLabel ?alias filter (lang(?alias) = "fr")} .
    OPTIONAL {?item wdt:P571 ?dtFondation} .
    OPTIONAL {?item p:P2046 ?area_statement .
              ?area_statement psv:P2046 ?area_node .
              ?area_node wikibase:quantityAmount ?area .  
              ?area_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(?area*?conversionSI/1000000 AS ?km2)} .
    OPTIONAL {?item wdt:P625 ?coord}
    SERVICE wikibase:label {
	    bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY (?regionLabel) 
LIMIT 1800

Try it!

Seigneurie sans identifiant CTQ : 12%Edit

SELECT DISTINCT ?id ?idLabel ?municipLabel ?mrcLabel ?regionLabel  
WHERE 
{
    ?id wdt:P31 wd:Q1550557 .
    ?id wdt:P17 wd:Q16 .
    ?id wdt:P131 ?municip .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .
    FILTER NOT EXISTS { ?id wdt:P2100 ?ctq }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 200

Try it!

Municipalités sans images : 17%Edit

SELECT DISTINCT ?item ?itemLabel ?mrcLabel 
WHERE {
        {?item wdt:P31*/wdt:P279* wd:Q3327873 }  
	    ?item  wdt:P131 ?mrc;
	           wdt:P625 ?coord;
        MINUS { ?item wdt:P18 [] } . 
        FILTER NOT EXISTS { ?item wdt:P576 ?dissolu}
        FILTER NOT EXISTS { ?item wdt:P582 ?fin }
        SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" . } 
     }

Try it!

geographical township of Quebec (Q23019040) sans date de fondation : 3%Edit

# Canton du Québec
SELECT ?item ?itemLabel ?itemDescription ?alias ?dtFondation ?km2 ?locLabel ?coord
WHERE {
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
    OPTIONAL {?item skos:altLabel ?alias filter (lang(?alias) = "fr")} .
    OPTIONAL {?item wdt:P571 ?dtFondation} .
    OPTIONAL {?item p:P2046 ?area_statement .
              ?area_statement psv:P2046 ?area_node .
              ?area_node wikibase:quantityAmount ?area .  
              ?area_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(?area*?conversionSI/1000000 AS ?km2)} .
    OPTIONAL {?item wdt:P131 ?loc} .
    FILTER NOT EXISTS { ?item wdt:P571 ?dtFondation }
    SERVICE wikibase:label {
	    bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY (?regionLabel) 
LIMIT 1800

Try it!

Municipalités sans URL officiel : 1%Edit

SELECT DISTINCT ?municip ?link ?municipLabel ?dateCreation ?superficie ?mrcLabel ?regionLabel  
WHERE 
{   # Municipalités sans URL officiel
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 }  
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P571 ?dateCreation }
    Optional {?municip wdt:P2046 ?superficie }
    Optional {?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
    OPTIONAL {
            ?link schema:about ?municip .
            ?link schema:isPartOf <https://fr.wikipedia.org/> }
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

Municipalités sans date de création : 0%Edit

10 % à renseigner Municipalités sans date de création

Municipalités sans identifiant OSM : 0%Edit

SELECT DISTINCT ?municip ?municipLabel ?statutLabel ?mrcLabel ?regionLabel  
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P402 ?mrc .}
    FILTER NOT EXISTS { ?municip wdt:P402 ?osm }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

Municipalités sans identifiant CTQ : 0%Edit

Aucune

SELECT DISTINCT ?municip ?municipLabel ?statutLabel ?mrcLabel ?regionLabel  
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P2100 ?mrc .}
    FILTER NOT EXISTS { ?municip wdt:P2100 ?ctq }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

Municipalités sans identifiant statcan : 0%Edit

SELECT DISTINCT ?municip ?link ?municipLabel ?dateCreation ?superficie ?mrcLabel ?regionLabel  
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P3012 ?statscan }
    Optional {?municip wdt:P571 ?dateCreation }
    Optional {?municip wdt:P2046 ?superficie }
    Optional {?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P856 ?statscan }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
    OPTIONAL {
            ?link schema:about ?municip .
            ?link schema:isPartOf <https://fr.wikipedia.org/> }
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

SPARQLEdit

protected area (Q473972) du Quebec (Q176)Edit

# Aire protégée du Québec
SELECT DISTINCT ?item ?itemLabel ?regionLabel 
WHERE
{
    ?item wdt:P31/wdt:P279 wd:Q473972 .
    ?item wdt:P17 wd:Q16 . 
    ?item wdt:P131 ?region .
    ?region wdt:P131* wd:Q176 .
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr" 
    }
}
ORDER BY (?itemLabel) 
LIMIT 500

Try it!

geographical township of Quebec (Q23019040)Edit

# Canton du Québec
SELECT ?item ?itemLabel ?itemDescription ?alias ?dtFondation ?km2 ?locationLabel ?coord 
WHERE {
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
    ?item wdt:P131* ?location .
    ?location wdt:P31 wd:Q55998242 .
    OPTIONAL {?item skos:altLabel ?alias filter (lang(?alias) = "fr")} .
    OPTIONAL {?item wdt:P571 ?dtFondation} .
    OPTIONAL {?item p:P2046 ?area_statement .
              ?area_statement psv:P2046 ?area_node .
              ?area_node wikibase:quantityAmount ?area .  
              ?area_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(?area*?conversionSI/1000000 AS ?km2)} .
    OPTIONAL {?item wdt:P625 ?coord}
    SERVICE wikibase:label {
	    bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY (?regionLabel) 
LIMIT 1800

Try it!

geographical township of Quebec (Q23019040) en Abitibi-TémiscamingueEdit

# Canton du Québec
SELECT ?item ?itemLabel ?dtFondation ?km2 ?locationLabel ?coord
WHERE {
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
    { ?item wdt:P131/wdt:P279* wd:Q321529 }  
    OPTIONAL {?item wdt:P571 ?dtFondation} .
    OPTIONAL {?item p:P2046 ?area_statement .
              ?area_statement psv:P2046 ?area_node .
              ?area_node wikibase:quantityAmount ?area .  
              ?area_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(?area*?conversionSI/1000000 AS ?km2)} .
    OPTIONAL {?item wdt:P131 ?location }
    SERVICE wikibase:label {
	    bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY (?regionLabel) 
LIMIT 500

Try it!


Cours d'eau alimentant la Saint-Maurice river (Q203862).Edit

SELECT DISTINCT ?item ?itemLabel ?riveLabel ?confluentLabel ?locationLabel ?locationCoord ?sourceLabel ?sourceLocationLabel ?sourceCoord ?longueur 
  WHERE { {?item (wdt:P403)* wd:Q203862 }                  # rivière Saint-Maurice
    OPTIONAL {?item p:P403 [ pq:P31 ?rive ] }              # qualificatif rive de la confluence
    OPTIONAL {?item wdt:P403 ?confluent }
    OPTIONAL {?item p:P403 [ pq:P131 ?location ] }         # qualificatif unité administrative   
    OPTIONAL {?item p:P403 [ pq:P625 ?locationCoord ] }    # qualificatif coordonnés de la confluence 
    OPTIONAL {?item wdt:P885 ?source }
    OPTIONAL {?item p:P885 [ pq:P131 ?sourceLocation ] }              
    OPTIONAL {?item p:P885 [ pq:P625 ?sourceCoord ] }                
    OPTIONAL {?item wdt:P885 ?tempCo .                     # Chercher les coordonnées de la source
              ?tempCo wdt:P625 ?sourceCoord }              
    OPTIONAL {?item wdt:P885 ?tempLoc .                    # Chercher la localisation de la source
              ?tempLoc wdt:P131 ?sourceLocation }
    OPTIONAL {?item wdt:P131 ?location }
    OPTIONAL {?item wdt:P131 ?sourceLocation } 
    OPTIONAL {?item wdt:P3871 ?rive } 
    OPTIONAL {?item wdt:P625 ?locationCoord }
    OPTIONAL {?item wdt:P2043 ?longueur } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" . }  # français sinon anglais
}
ORDER BY (?itemLabel) 
LIMIT 500

Try it!

Cours d'eau du bassin de l'estuaire du Saint-Laurent (Q51885235).Edit

SELECT DISTINCT ?id ?idLabel ?confluenceLabel ?localisationLabel ?bassinLabel ?sousbassinLabel
WHERE        
{   # affluents de l'estuaire du Saint-Laurent
    ?id wdt:P4614/wdt:P361* wd:Q51885235.     # bassin de l'estuaire du Saint-Laurent
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id wdt:P403 ?confluence .
    ?id wdt:P131 ?localisation .
    ?id wdt:P4614 ?bassin .
    OPTIONAL { ?id p:P4614 [ pq:P518 ?sousbassin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY ?sousbassinLabel ?bassinLabel ?idLabel
LIMIT 1000

Try it!

Montagnes des Q9195483.Edit

# Montagnes des Collines de l'Oka
SELECT DISTINCT ?item ?itemLabel ?typeLabel ?massifLabel ?altitude ?localisationLabel ?coord 
  WHERE { ?item (wdt:P4552)* wd:Q9195483 .
          ?item wdt:P31 ?type .
          ?item wdt:P4552 ?massif .
          OPTIONAL {?item p:P2044 ?alt_statement .
              ?alt_statement psv:P2044 ?alt_node .
              ?alt_node wikibase:quantityAmount ?alt .  
              ?alt_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(ROUND(?alt*?conversionSI) AS ?altitude)} 
          OPTIONAL { ?item wdt:P131 ?localisation }
          OPTIONAL { ?item wdt:P625 ?coord } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" . }  # français sinon anglais
}
ORDER BY (?massifLabel) 
LIMIT 1000

Try it!

local municipality of Quebec (Q3327873) et unorganized area of Canada (Q3518810) du Quebec (Q176) :Edit

# Municipalités locales et Territoires non-organisés du Québec.
SELECT DISTINCT ?municip ?link ?municipLabel ?statutLabel ?mrcLabel ?regionLabel 
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P131*/wdt:P279* wd:Q176 .
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    Optional {?municip wdt:P402 ?mrc}
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    FILTER NOT EXISTS { ?municip wdt:P582 ?datefin }
    OPTIONAL {
            ?link schema:about ?municip .
            ?link schema:isPartOf <https://fr.wikipedia.org/> }
    SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" .}
} 
ORDER BY ?regionLabel  ?mrcLabel ?municipLabel
LIMIT 1500

Try it!

Municipalités existantes au Québec créées en 1855Edit

#Municipalités existantes au Québec créées en 1855
SELECT DISTINCT ?item ?itemLabel ?statutLabel ?mrcLabel ?regionLabel ?dateCreation
WHERE 
{
    ?item(wdt:P31*/wdt:P279*) wd:Q3327873 .
    ?item wdt:P31 ?statut .
    ?item wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .
    ?item wdt:P571 ?dateCreation .
    FILTER (?dateCreation >= "1855-01-01T00:00:00Z"^^xsd:dateTime ) .
    FILTER (?dateCreation < "1856-01-01T00:00:00Z"^^xsd:dateTime ) .
    FILTER NOT EXISTS { ?item wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?item wdt:P582 ?fin }
    FILTER NOT EXISTS { ?item p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" }
} 
ORDER BY ?itemLabel
LIMIT 1000

Try it!

Municipalités dissoutes ou ayant changé de statutEdit

SELECT DISTINCT ?item ?itemLabel ?statutLabel  ?pqfin ?dissolution
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?item wdt:P31 ?statut .
    {?item p:P31 [ pq:P582 ?pqfin ] } union {?item wdt:P576 ?dissolution }
	SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr" .
	}
} 
ORDER BY  ?itemLabel
LIMIT 100

Try it!

regional county municipality (Q204613) et equivalent territory (Q3518817) :Edit

# MRC et TE du Québec
SELECT DISTINCT ?item ?itemLabel ?statutLabel ?regionLabel 
WHERE
{
    { ?item wdt:P31 wd:Q204613 } UNION  { ?item wdt:P31 wd:Q3518817 }
    ?item wdt:P131 ?region .
    ?item wdt:P31 ?statut .
    FILTER NOT EXISTS { ?item p:P131 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr" 
    }
}
ORDER BY ?regionLabel ?itemLabel 
LIMIT 200

Try it!

country (Q6256)s du mondeEdit

SELECT DISTINCT ?item ?itemLabel ?ccioLabel
WHERE
{
    ?item wdt:P31* wd:Q6256 .
    OPTIONAL {?item wdt:P984 ?ccio}. 
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr" 
    }
}
ORDER BY (?itemLabel) 
LIMIT 300

Try it!

Premiers ministres du QuébecEdit

SELECT DISTINCT ('Q176' as ?qid) (?pmqid as ?P6) (?position as ?qal1545) (?debut as ?qal580) (?fin as ?qal582) ?pmLabel
WHERE { 
  ?pm p:P39 ?statement .
  ?statement ps:P39 wd:Q2911019 .
  OPTIONAL { ?statement pq:P1545 ?position }
  OPTIONAL {
    ?statement pqv:P580 [wikibase:timeValue ?dt; wikibase:timePrecision ?dp] .
    FILTER STRENDS(?dt, 'Z') .
    BIND(CONCAT('+', STR(?dt), '/', STR(?dp)) as ?debut) .
  }
  OPTIONAL { 
    ?statement pqv:P582 [wikibase:timeValue ?ft; wikibase:timePrecision ?fp] .
    FILTER STRENDS(?ft, 'Z') .
    BIND(CONCAT('+', STR(?ft), '/', STR(?fp)) as ?fin) .
  }
  BIND(STRAFTER(STR(?pm), 'http://www.wikidata.org/entity/') as ?pmqid) .
  FILTER STRSTARTS(?pmqid, 'Q') .
#  MINUS {
#    wd:Q176 p:P6 ?s.
#    ?s ps:P6 ?pm
#  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
ORDER BY ?debut

Try it!

Premiers ministres provinciaux et fédérauxEdit

SELECT DISTINCT ?pm ?pmLabel ?position ?fonctionLabel
WHERE {
  ?pm wdt:P39 ?fonction .
  VALUES ?fonction { wd:Q839078 wd:Q2560704 wd:Q2911019 wd:Q3401750 wd:Q3401758 wd:Q4377222 wd:Q6578215 wd:Q7240349 wd:Q7240356 wd:Q7240360 wd:Q7240361 wd:Q7240368 wd:Q12270252 wd:Q12270260 }
  OPTIONAL {?pm p:P39 [ pq:P1545 ?position ] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  }
ORDER BY (?pmLabel)

Try it!

ski resort (Q130003) au Quebec (Q176)Edit

#station de sports d'hiver au Québec
SELECT DISTINCT ?item ?itemLabel ?regionLabel 
WHERE
{
    ?item wdt:P31* wd:Q130003 .
    ?item wdt:P17 wd:Q16 . 
    ?item wdt:P131 ?region .
    ?region wdt:P131* wd:Q176 .
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr" 
    }
}
ORDER BY (?itemLabel) 
LIMIT 100

Try it!

CartesEdit

Aéroport à l'intérieur de 200 km de la L'Assomption River (Q1570842)Edit

#defaultView:Map
SELECT ?place ?placeLabel ?location
WHERE
{
  wd:Q1570842 wdt:P625 ?centerLoc . #Centre de la carte =  rivière L'Assomption
  SERVICE wikibase:around { 
      ?place wdt:P625 ?location . 
      bd:serviceParam wikibase:center ?centerLoc . 
      bd:serviceParam wikibase:radius "200" . 
  } 
  # Is an airport
  ?place wdt:P31 wd:Q1248784 . 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr" . 
	}
}

Try it!

Affluents et sous-affluents du Saint Lawrence River (Q134750)Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {  
  {?id wdt:P403* wd:Q134750} .               # se jette dans le fleuve Saint-Laurent
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Affluents et sous-affluents du Gulf of Saint Lawrence (Q169523)Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {  
  ?id wdt:P403* wd:Q169523;               # se jette dans le golfe du Saint-Laurent
        wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Arrondissements de Montreal (Q340)Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?carte ?link WHERE     
{
  ?id wdt:P31/wdt:P279* wd:Q19905455 .  # Arrondissement
  ?id wdt:P131 wd:Q340 .                # Ville de Montréal
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P242 ?carte }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Cours d'eau alimentant le Taureau Reservoir (Q16025181)Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE { 
  ?id wdt:P403* wd:Q16025181 .              # se jette dans Lac Taureau
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Cours d'eau du Saint Lawrence River basin (Q48983740)Edit

#defaultView:Map
SELECT DISTINCT ?id ?idLabel ?location ?image ?link
WHERE {
    ?id wdt:P4614/wdt:P361* wd:Q48983740 . # Bassin du fleuve Saint-Laurent
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id wdt:P625 ?location .
    OPTIONAL {?id wdt:P18 ?image }
    SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
    OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
   }
}

Try it!

Cours d'eau du Q51991620Edit

#defaultView:Map
SELECT DISTINCT ?id ?idLabel ?location ?image ?link
WHERE {
    ?id wdt:P4614/wdt:P361* wd:Q51991620 . # Bassin du tronçon fluviale du fleuve Saint-Laurent
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id wdt:P625 ?location .
    OPTIONAL {?id wdt:P18 ?image }
    SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
    OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
   }
}

Try it!

Cours d'eau du Q50375272Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {    
  ?id wdt:P4614 wd:Q50375272 .              # bassin du lac Saint-Pierre
  ?id wdt:P31/wdt:P279* wd:Q355304 .  
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Cours d'eau du bassin de l'estuaire du Saint-Laurent (Q51885235)Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {  
  ?id wdt:P4614/wdt:P361* wd:Q51885235.     # bassin de l'estuaire du Saint-Laurent
  ?id wdt:P31/wdt:P279* wd:Q355304 .
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Cours d'eau du bassin de l'Upper estuary of the St. Lawrence (Q50415467)Edit
#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {   
    ?id wdt:P4614/wdt:P361* wd:Q51885235.     # bassin de l'estuaire du Saint-Laurent
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id p:P4614 [ pq:P518 wd:Q50415467 ] .
    ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Cours d'eau du bassin du middle estuary of the St. Lawrence (Q50415472)Edit
#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {   
    ?id wdt:P4614/wdt:P361* wd:Q51885235.     # bassin de l'estuaire du Saint-Laurent
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id p:P4614 [ pq:P518 wd:Q50415472 ] .    # estuaire moyen
    ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Cours d'eau du bassin de l'maritime estuary of the St. Lawrence (Q50415473)Edit
#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link WHERE {   
    ?id wdt:P4614/wdt:P361* wd:Q51885235.     # bassin de l'estuaire du Saint-Laurent
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id p:P4614 [ pq:P518 wd:Q50415473 ] .    # estuaire maritime
    ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Municipalités d'Abitibi-Ouest Regional County Municipality (Q321503)Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?carte ?link WHERE     
{
  ?id wdt:P31/wdt:P279* wd:Q3327873 .  # Municipalité locale
  ?id wdt:P131 wd:Q321503 .            # Abitibi-Ouest
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P242 ?carte }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

Seigneuries québécoisesEdit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?regionLabel ?link
WHERE
{
  # Seigneurie québécoise
   ?id wdt:P31 wd:Q1550557 . 
   ?id wdt:P17 wd:Q16 . 
   ?id wdt:P131 ?region .
   ?region wdt:P131* wd:Q176 .
   ?id wdt:P625 ?geo  
   OPTIONAL {?id wdt:P18 ?image }  
   SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" .}
    OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
    }
}

Try it!

Sommets du Jacques-Cartier Lake massif (Q22813085).Edit

#defaultView:Map
SELECT ?id ?idLabel ?geo ?image ?link ?altitude WHERE     
{
  ?id wdt:P4552 wd:Q22813085 .              # massif du Lac Jacques-Cartier
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P2044 ?altitude }
  OPTIONAL {?id wdt:P18 ?image }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}

Try it!

SchemaEdit

Description d'élémentEdit

SELECT DISTINCT ?item ?itemL ?description_en ?description_fr WHERE {
  ?item wdt:P17 wd:Q155 ;
        wdt:P31/wdt:P279* wd:Q486972 .
   ?item schema:description ?description_en filter (lang(?description_en) = "en") .
   ?item schema:description ?description_fr filter (lang(?description_fr) = "fr") .
   ?item rdfs:label ?itemL filter (lang(?itemL) = "en") .
   FILTER((regex(?description_en, "Brazil", "i"))) .
   FILTER(!(regex(?description_fr, "Br[eé]sil", "i"))) .
}
ORDER BY ?itemL

Try it!

Libellés doublonsEdit

SELECT ?itemLabel (COUNT(?itemLabel) as ?count) 
WHERE
{
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

GROUP BY ?itemLabel
HAVING (?count > 1)

Try it!

Utilisation de propriétésEdit

#propriétés les plus utilisées (et sous-classes de)
SELECT ?property ?propertyLabel ?propertyDescription ?count 
 WHERE 
 { 
  {
  select ?propertyclaim (COUNT(*) AS ?count) where {
         ?item wdt:P31/wdt:P279* wd:Q166620 .          # bassin versant
         ?item ?propertyclaim [] .
  } group by ?propertyclaim 
 }
 ?property wikibase:claim ?propertyclaim .
 SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" . }
} 
ORDER BY DESC (?count)

Try it!

 

Welcome to Wikidata, YanikB!

Wikidata is a free knowledge base that you can edit! It can be read and edited by humans and machines alike and you can go to any item page now and add to this ever-growing database!

Need some help getting started? Here are some pages you can familiarize yourself with:

  • Introduction – An introduction to the project.
  • Wikidata tours – Interactive tutorials to show you how Wikidata works.
  • Community portal – The portal for community members.
  • User options – including the 'Babel' extension, to set your language preferences.
  • Contents – The main help page for editing and using the site.
  • Project chat – Discussions about the project.
  • Tools – A collection of user-developed tools to allow for easier completion of some tasks.

Please remember to sign your messages on talk pages by typing four tildes (~~~~); this will automatically insert your username and the date.

If you have any questions, please ask me on [[User talk:|my talk page]]. If you want to try out editing, you can use the sandbox to try. Once again, welcome, and I hope you quickly feel comfortable here, and become an active editor for Wikidata.

Best regards!