User talk:TomT0m

Previous discussion was archived at User talk:TomT0m/Archive 1 on 2015-08-10.

Salut,
J'ai lancé une nouvelle section sur les fr:WP:RAW qui s'intitule "SPARQL du mois" (exemple). Je lance l'invitation ici et là à des contributeurs qui maîtrisent relativement bien le SPARQL. Si jamais tu penses avoir une bonne idée de thématique et/ou de bonne requêtes à partager, n'hésite pas !
La section de février est déjà prête. Pour celle de mars, je pensais faire un tableau avec le nombre d'articles consacré aux hommes et aux femmes par différentes publications externes. J'ai commencé quelque chose, mais je bloque.
En gros, j'aimerais faire un tableau montrant le nombre d'éléments de certaines publications selon les genres. Pour ce faire, j'ai filtré certains identifiants avec cette requête :

SELECT DISTINCT ?property ?propertyLabel ?propertyDescription
WHERE
{
    ?property rdf:type wikibase:Property ;
              wdt:P31/wdt:P279* wd:Q36218176 ;
              wdt:P31/wdt:P279* wd:Q55452870 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }	
}

Try it!

J'aimerais savoir si tu sais comment, pour chacune de ces 23 propriétés, recenser tous les éléments humains et les diviser en genre ? J'ai trouvé la requête suivante dans les exemples, mais elle n'est construite que pour un cas spécifique.

En bref, je suis capable de faire "à la main" ce travail : faire une requête individuelle pour chacune de ces 23 propriétés, diviser les éléments en genres et entrer ces valeurs dans un tableau. Je me demandais si tu connaissais un moyen de faire la chose d'un seul coup en SPARQL.

Oui c'est possible, première tentative : https://query.wikidata.org/#SELECT%20DISTINCT%20%3Fproperty%20%3FpropertyLabel%20%3FpropertyDescription%20%3Fsexe%20%3FsexeLabel%20%28count%28%3Fperson%29%20as%20%3Feffectif%29%0AWHERE%0A%7B%0A%20%20%20%20%3Fproperty%20rdf%3Atype%20wikibase%3AProperty%20%3B%0A%20%20%20%20%20%20%20%20%20%20%20%20%20%20wdt%3AP31%2Fwdt%3AP279%2a%20wd%3AQ36218176%2C%20wd%3AQ55452870%20%3B%0A%20%20%20%20%20%20%20%20%20%20%20%20%20%20wikibase%3AdirectClaim%20%3FpropertyMainValue%20.%0A%20%20%20%20%3Fperson%20%3FpropertyMainValue%20%5B%5D%20%3B%0A%20%20%20%20%20%20%20%20%20%20%20%20wdt%3AP21%20%3Fsexe%20.%0A%20%20%20%20%20%20%20%20%20%20%20%20%20%20%0A%20%20%20%20SERVICE%20wikibase%3Alabel%20%7B%20bd%3AserviceParam%20wikibase%3Alanguage%20%22%5BAUTO_LANGUAGE%5D%2Cen%22%20%7D%09%0A%0A%7D%20group%20by%20%3Fproperty%20%3FpropertyLabel%20%3FpropertyDescription%20%3Fsexe%20%3FsexeLabel%20%0A%20%20order%20by%20%3Fproperty%20%3Fsexe mais il y a un peu de nettoyage à faire pour les "valeurs inconnues" je crois.

Entre une étape intermédiaire pour me rendre compte que les cas ou le sexe est inconnus sont probablement des cas ou il s'agit de compagnie ferroviaires ou de groupes donc que beaucoup de "non spécifié" ou "inconnus" ne sont pas très pertinent, je pense être arrivé à un truc pas mal en se restreignant aux humains :

select ?property ?propertyLabel ?propertyDescription ?sexe ?sexeLabel (count(?person) as ?effectif)
{
    ?property rdf:type wikibase:Property ;
              wdt:P31/wdt:P279* wd:Q36218176, wd:Q55452870 ;
              wikibase:directClaim ?propertyMainValue .
  
    ?person ?propertyMainValue [] ;
            wdt:P31 wd:Q5 .
    optional {
       ?person wdt:P21 ?sexe2
       bind(if(isBlank(?sexe2), "inconnu", ?sexe2) as ?sexe3) 
    }
    bind(if(!bound(?sexe3), "non specifié", ?sexe3) as ?sexe) 
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }	
  
} group by ?property ?propertyLabel ?propertyDescription ?sexe ?sexeLabel
  order by ?property ?sexe

Try it!

(cela concerne ton premier message. J'explore ton second à l'instant)

Vraiment trop cool !
Ça fait une demi-heure que je tente de transformer en % les effectifs en insérant ici et là des BIND et des count, mais je n'y arrive pas. Tu peux encore m'aider ?
Sinon, pour mieux apprendre le SPARQL, à part le livre sur Wikibook en anglais et les pages de W3C, tu as des suggestions ?

Une dernière version (pour l'instant, on verra les pourcentages plus tard) avec moins de ligne :

select ?property ?propertyLabel ?propertyDescription (group_concat(concat(str(?sexe_label_final), ": ", str(?effectif));separator=" - ") as ?sexes) (sum(?effectif) as ?total)

with {

select ?property ?sexe (count(?person) as ?effectif)
{
    ?property rdf:type wikibase:Property ;
              wdt:P31/wdt:P279* wd:Q36218176, wd:Q55452870 ;
              wikibase:directClaim ?propertyMainValue .
  
    ?person ?propertyMainValue [] ;
            wdt:P31 wd:Q5 .
    optional {
       ?person wdt:P21 ?sexe2 .
       bind(if(isBlank(?sexe2), "inconnu", ?sexe2) as ?sexe3) 
    }
    bind(if(!bound(?sexe3), "non specifié", ?sexe3) as ?sexe)
    
 
} group by ?property ?sexe
  order by ?property ?sexe
} as %dataset

where {
  {
    select ?property ?propertyLabel ?propertyDescription ?sexe ?sexe_label_final ?effectif{
      include %dataset .
      optional { ?sexe rdfs:label ?label_sexe filter langmatches(lang(?label_sexe), "fr") }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
      bind (if(bound(?label_sexe), ?label_sexe, ?sexe) as ?sexe_label_final)
    }
  }
} group by ?property ?propertyLabel ?propertyDescription

Try it!

Et finalement voilà les pourcentages :

select ?property ?propertyLabel ?propertyDescription 
       (group_concat(concat(str(?sexe_label_final), 
                           ": ", 
                           str(?effectif), " ",
                           "(", str(round(?effectif / sum(?effectif) * 100)), "%",")") ; separator=" - ") as ?sexes) 
       (sum(?effectif) as ?total)

with {

select ?property ?sexe (count(?person) as ?effectif)
{
    ?property rdf:type wikibase:Property ;
              wdt:P31/wdt:P279* wd:Q36218176, wd:Q55452870 ;
              wikibase:directClaim ?propertyMainValue .
  
    ?person ?propertyMainValue [] ;
            wdt:P31 wd:Q5 .
    optional {
       ?person wdt:P21 ?sexe2 .
       bind(if(isBlank(?sexe2), "inconnu", ?sexe2) as ?sexe3) 
    }
    bind(if(!bound(?sexe3), "non specifié", ?sexe3) as ?sexe)
    
 
} group by ?property ?sexe
  order by ?property ?sexe
} as %dataset

where {
  {
    select ?property ?propertyLabel ?propertyDescription ?sexe ?sexe_label_final ?effectif{
      include %dataset .
      optional { ?sexe rdfs:label ?label_sexe filter langmatches(lang(?label_sexe), "fr") }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
      bind (if(bound(?label_sexe), ?label_sexe, ?sexe) as ?sexe_label_final)
    }
  }
  bind( (?effectif / ?total )  as ?pourcent)
} group by ?property ?propertyLabel ?propertyDescription

Try it!

Je suis K.O.

Hello,

pour ce qui est de mon message sur le Bistro, malheureusement je ne trouve plus d'exemple :(. Je cherche.

Puisque je vois que tu es logué et actif sur WD, j'en profite ;). Tu te rappelles la condition d'affichage que tu avais créé pour le Who's Who in France dans le module Autorité ? Comme la propriété a été transférée dans le nouveau modèle Dictionnaires, est-ce que tu pourrais la réécrire à cet endroit, éventuellement ? (J'ai essayé de faire un simple copier-coller mais ça me dit qu'il y a des erreurs :/.)

Oui j’ai vu ça, pour l’instant j’ai autre chose dans ma TODO list lua, faire afficher le nom de la commune à la date de naissance d’une personne si le nom de la commune a changé depuis dans biographie2. Je regarderai quand j’aurai fini (pas avant quelque jours parce que je manque de courage pour ça ce soir :) )

Ah oui, c'est un gros morceau ça ^^. Bon ben, bon courage et à bientôt ;).

Hello. Si tu n'as vraiment pas le temps, je t'invite à le dire... J'essaierai trouverai un autre contributeur compétent pour bricoler ce bout de code.

Merci beaucoup ; mais je viens de vérifier dans l'article sur fr:Emmanuel Macron#Liens externes , ça n'a pas l'air de fonctionner...

Quel est l’article ? J’avoue que j’ai fait ça vite fait en testant sur un article sur lequel le lien était supposé s’afficher, pas regardé sur un article sur lequel ce n’était pas supposé :)

Lien corrigé ; je voulais parler de l'article sur Macron.

Cette fois-ci, ça m'a l'air de marcher... Merci encore !!

Can you think of anything for this to be a subclass of? Otherwise, it can't have instances, without violating constraints at least.

It’s a subclass of « mathematical class » or something like this (as any complexity class is a mathematical class, in the sense of set theories)

Every response for this survey can help the Wikimedia Foundation improve your experience on the Wikimedia projects. So far, we have heard from just 29% of Wikimedia contributors. The survey is available in various languages and will take between 20 and 40 minutes to be completed. Take the survey now.

If you have already taken the survey, we are sorry you've received this reminder. We have design the survey to make it impossible to identify which users have taken the survey, so we have to send reminders to everyone. If you wish to opt-out of the next reminder or any other survey, send an email through EmailUser feature to WMF Surveys. You can also send any questions you have to this user email. Learn more about this survey on the project page. This survey is hosted by a third-party service and governed by this Wikimedia Foundation privacy statement. Thanks!

WMF Surveys, 01:40, 13 April 2018 (UTC)

You are receiving this message because you commented at the above RFC. There are additional proposals that have been made there that you are welcome to comment on. MediaWiki message delivery (talk) 03:50, 9 April 2018 (UTC) (for Rschen7754)

Hello! The Wikimedia Foundation is asking for your feedback in a survey. We want to know how well we are supporting your work on and off wiki, and how we can change or improve things in the future. The opinions you share will directly affect the current and future work of the Wikimedia Foundation. You have been randomly selected to take this survey as we would like to hear from your Wikimedia community. The survey is available in various languages and will take between 20 and 40 minutes.

Take the survey now!

You can find more information about this survey on the project page and see how your feedback helps the Wikimedia Foundation support editors like you. This survey is hosted by a third-party service and governed by this privacy statement (in English). Please visit our frequently asked questions page to find more information about this survey. If you need additional help, or if you wish to opt-out of future communications about this survey, send an email through the EmailUser feature to WMF Surveys to remove you from the list.

Thank you!

WMF Surveys, 18:57, 29 March 2018 (UTC)

I sees "union of" as the sets of parts whose union is the item itself, so a particular case of "has part". Probably I'm wrong. What are your thoughts?

No, « union of » is for classes of stuffs (instance of / subclass of) and not for whole/parts relationships (part of (P361) / has part (P527) ) (see Help:BMP for an introduction). Physical objects have parts (my arm bart of my body, mereology (Q1194916) type relation), classes (types) have instances (my arm is an arm). If a class (say « arm » has a statement that states it’s a part of another class, say « body » it means that an instance of the former is a part of an instance of a latter (like with my arm and my body, so arm is part of body).

We can’t really mix up both notions, as the logic is not the same at all behind these two. People are already confused with part/instance sometimes, this would make this worse. Even if we could, this would not fit as « union of » expects a list of values as qualifiers when « part of » expects a single main value, so this means we could not substitute « union of » with « part of » and still get a meaningful value, as it should be for subproperties. This is because we don’t expect that Wikidata has items for all the parts/kind of parts, while « union of » was created precisely to model some kind of completeness.

I proposed something that is an analog of « union of » for physical parthood with Wikidata:Property proposal/fully divised into but it was recently rejected for not enough support, we could reopen it, I guess one more could have been enough, if you want.

I understand, thank you for your explanation (though I think you confused "part of" with "has part").

As regards your proposal, since "union of" exists I don't see why "fully divised into" shouldn't exist. I have only a doubt: is it possible to reach the same result using "has part" with qualifier "expected completeness": "is complete"?

It brings up another question: which of the two is preferable between a subproperty and a property with a qualifier?

Actually a better option, I think, would be to use « has part of the type » qualified with a number :

• < me > has parts of the class (P2670) < arm >
  quantity (P1114) < 2 >

such that if we have

< me > has part (P527) < my left arm >

and

< me > has part (P527) < my right arm >

we know there is enough statements for all my arms.

The « expected completeness » qualifier approach would be tricky. I don’t actually think this can work. You can have many other kind of parts than « arm », like « legs », and each arm or leg may have its own « has part » statement. To which would you attach the « expected completeness » statement ? Moreother, « arm » or « leg » are both « bodyparts ». Then bodypart completeness would entail arm completeness, for example …

I also don’t like an « expected completeness » because this seems to be like « pure » metadata, an information about the dataset itself and not about the object described by this dataset. We should avoid make these kind of statements if we can.

I think I’ll right an Completeness page at some point. Related : some queries about parts and instance completeness Wikidata:Project chat/Archive/2018/01#Instance completeness

Hey, about a year ago I proposed a new property (Wikidata:Property proposal/Cartridge case rim) and you added a disjoint union to cartridge (Q37144). I still haven't figured out how to use it. Could demonstrate how to state that 11x58mmR (Q17560835) has a rimmed (rimmed (Q29842212)) case and uses centerfire (Q190476) ignition? Thanks.

It’s both a rimmed cartridge and centerfire ignition cartridge. It’s then enough to state that

• < 11x58mmR (Q17560835)   > subclass of (P279) < rimmed (Q29842212)   >
  and
• < 11x58mmR (Q17560835)   > subclass of (P279) < centerfire (Q190476)   >

subclass of (P279) means that any example of 11x58mmR (Q17560835) is an example of rimmed (Q29842212) and of 11x58mmR (Q17560835).

Now the key is to describe the different classes. For example centerfire (Q190476) is a type of cartridge, for sure, but in what way is it different from the cartridge that are not of this type ? The type of ignition they use.

This means using a class of class (metaclass see an introduction User:TomT0m/Classification) approach we can use a metaclass « « cartridge ignition type », whose instances are « centerfire cartridge » and « rimfire (Q1289462) »

I added a « item documentation » template to the talk page of the « cartridge » item to demonstrate how it’s useful. The part « Union and disjoint queries » is generated thanks to them. I did not expect this queries to get answor as I did not expect there was item about specific ammunitions on Wikidata instance on Wikidata, (almost only) only types of ammunitions, but the result of the query I copy paste from here types should only be specific object, it seem this is not the case. An instance of ammunition would be « the Bullet that killed JFK » for example. An instance of « Bomb » would be Little Boy (Q181013), « atomic bomb » is not an instance of bomb, just a subclass.

Now seing centerfire (Q190476) I see there is a mess : the frwiki article is about the cartridge type, while the statement states that it’s a percussion type … This should be sorted out by creating an item for the percussion type itself and one for the munition of that type, actually. Then we can think of a property to link both items. I’m thinking an existing property of another project fits perfectly well : has disposition. I’ll try a proposal.

In September, you did a run of petscan adding instance of (P31) unincorporated community (Q17343829) to many items, including many about humans, assorted geographic features, roads, businesses, educational institutions, film studios, golf courses, timelines, etc. Could you take a look at this? Thanks.

I seldom remember this but it seem to be imported from https://en.wikipedia.org/wiki/Category:Census-designated_places_in_the_United_States_by_state https://en.wikipedia.org/wiki/Category:Unincorporated_communities_in_the_United_States_by_state. I’ll try to find the items related to these categories with another value for instance of (P31).

I cleaned what I could, this leaves a lot of unknown however. I used the following queries to find all « unincorporated community » instances (including instances of the subclasses of « unincorporated community » that are instances of another class. I assumed the results may be items with problems.

Other class by other class, I used petscan to clean stuffs up (removed « instance of : unincorporated community » for humans, for example). This leaves a number of class I excluded because : either they seemed compatible with « unincorporated community », either the topic of the item is unclear or mixed up, or I was not sure what to do. This also leaves individual items that may be to cleanup and that are the result of the query.

select ?item ?itemLabel ?val2 {
  ?item wdt:P31/wdt:P279* wd:Q17343829 .
  ?item wdt:P31 ?val2 
        filter not exists { 
          ?val2 wdt:P279* wd:Q17343829 
        }
        filter not exists { 
          # whitelisting some classes for some reason to exclude their instance from the candidates items to clean
          values ?val2 { 
            wd:Q515       # town, those one seems OK
            wd:Q532       # villages, seems OK
            wd:Q751708    # united state village
            wd:Q15127012  # town US municipality
            wd:Q5084      # hamlet, seems consistent
            wd:Q3957      # small town
            
            wd:Q269528    # seems consistent but may be somehow redundant.          
            wd:Q74047     # ghost city
            wd:Q123705    # neighborhood
            wd:Q486972    # human etsablishment
            wd:Q15642541  # human territorial geographical entity
            
            wd:Q1620797  # not sure : historical neighborhood in the US
            wd:Q15243209 # not sure  : what to do about that one, historic neighborhood
            wd:Q17362920 # duplicates, not sure either (4 or five articles, candidate for merging ?)
            wd:Q2373919  # not sure what to do, seems consistent however
            wd:Q738570   # business neighboorhood, not sure.
            wd:Q1248784  # military airports, not sure what to do
            wd:Q695850  wd:Q245016 # and air force bases, same     
            wd:Q23002039 # public universities are census designated place, do not know what to do with that
            
            wd:Q23397    # mixed topic article : both leh lake and its surrounding community. Ideally to split.
            wd:Q55488    # mixed topic, some former station that became populated places (?)
            wd:Q23442    # mixed topic, islands that incorporate communities 
          }
        }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?val2

Try it!

Items for which I added the statement but that had no « instance of » statement cannot be found by this process.

Please let me know if you have any question.

select ?item ?itemLabel {
  ?item wdt:P31/wdt:P279* wd:Q17343829 .
  filter not exists {
    ?item wdt:P31 ?val2 filter (?val2 != wd:Q17343829 )
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?val2

Try it!

There is quite a few items which are instances of wd:Q17343829 and no other class, but a quick sampling did not reveal anything that seems like a problem in them.

Bonjour. Tu as dit quelque chose dans une conversation récemment qui m'a marqué. Je n'y avais pas pensé, mais c'est très vrai : il faudrait discuter des propriétés à créer non pas une par une mais globalement en fonction des relations qu'il s'agit d'établir entre plusieurs entités. La question est : pouvons-nous faire quelque chose de cette idée ? Il va être difficile de bousculer tout un système de votes, modèles et autres procédures déjà en place. Pourtant c'est vrai que proposer une par une la propriété de A à B puis de B à C alors qu'il faudrait d'emblée regarder A, B, C et D pour savoir que faire de plus pertinent et économe.

Je l’ai dit un certain nombre de fois :) le pêché originel c’est qu’il y a un droit de « création de propriété » et que tout s’est organisé autours de ça, les admins demandant une approbation communautaire pour chaque création.

Sinon j’ai plus ou moins obtenu qu’on puisse faire une proposition groupée, mais ça ne fonctionne pas vraiment. Faudrait peut être revenir à un fonctionnement « aligné sur les infobox » mais j’aime pas trop non plus parce que ça aurait tendance à créer autant de propriété que de paramètres d’infobox, je pense, et à pas faciliter la réutilisation pour des sous classes d’objets qui ont des infoboites différentes mais qui sont essentiellement la même chose.

Ce genre de problème est particulièrement intéressant quand il existe des triptyques (ou même des complexes à quatre ou cinq pôles, plutôt que deux seulement) qu'il faut structurer, à l'exemple du barrage, du cours d'eau et du lac de barrage évoqués récemment dans plusieurs discussions. C'est alors qu'une procédure plus large serait nécessaire. Mais je ne sais pas si ce genre de configuration est fréquent, d'un autre côté.