Wikidata:ExLibris-Primo

This page is third-party documentation of the use of wikidata data by the commercial library search engine Primo by ExLibris.

Overview

The system builds on existing library authority systems using autocomplete in the primary search box (below existing autocomplete options, see official documentation below for screenshots).

Matching is via LCCN AKA Library of Congress authority ID AKA Property:P244. This is distinct from LCCN AKA Library of Congress Control Number (LCCN) (bibliographic) AKA Property:P1144 which concerns bibliographic items (books, newspapers, etc).

If you want the functionality to appear you will need (a) a wikidata person (Q5), with a P244 property and (b) an LCCN in the $0 part of the 100 (main author) or 600 (subject) of a MARC record in the print holdings in ALMA.

If the user chooses to navigate to the information, they will be shown:

a brief summary taken from the lead of the subject's en.wikipedia article (contains == titles ==, etc)
basic facts derived from wikidata: Short Description, date and place of birth, date and place of death, field of work, occupation,
minimal credit line,
titles (in the print collection) BY the subject (matched on the 100 fields)
titles (in the print collection) ABOUT the subject (matched on the 600 fields)
related subjects (derived from ?)

Very little of no normalisation of fields is done, not even normalising hyphens, en-dashes and em-dashes in year ranges. Updates are weekly.

Currently this feature is English-only.

Related queries

These queries relate to finding people affiliated with a university and checking that they have the necessary lccn to make the functionality work.

These queries return gender so you can filter on gender after the fact. Filtering on gender as part of the query turns out to be very costly, so the query usually times out.

Thesis students

#title: Thesis students for a university and their various IDs
SELECT ?academic ?scholia ?academicLabel ?academicDescription ?academicAltLabel  ?degreeLabel ?gender ?lccn ?lccnurl  ?viaf ?viafurl ?orcid ?orcidurl ?gscholarurl  WHERE {
  ?academic wdt:P31 wd:Q5 ; # instances (P31) of humans (Q5)
            p:P69 ?statement . # check for an "educated at" (P69) statement

  ?statement ps:P69 wd:Q1150437 . # educated at Victoria University of Wellington
  
  ?statement pq:P512 ?degree . # get qualifier "academic degree" (P512)

  BIND( URI(CONCAT('https://scholia.toolforge.org/author/', STRAFTER(STR(?academic), "/entity/")))  AS ?scholia ) .

   OPTIONAL { ?academic wdt:P21 ?gender . } .   
   OPTIONAL { ?academic wdt:P244 ?lccn .  BIND( IRI(CONCAT('https://lccn.loc.gov/', STR(?lccn)))  AS ?lccnurl ) .   } . 
   OPTIONAL { ?academic wdt:P214 ?viaf .  BIND( IRI(CONCAT('https://viaf.org/viaf/', STR(?viaf)))  AS ?viafurl ) . } . 
   OPTIONAL { ?academic wdt:P496 ?orcid .  BIND( IRI(CONCAT('https://orcid.org/', STR(?orcid)))  AS ?orcidurl ) . } . 
   OPTIONAL { ?academic wdt:P1960 ?gscholar .  BIND( IRI(CONCAT('https://scholar.google.com/citations?user=', STR(?gscholar)))  AS ?gscholarurl ) . } . 
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

} LIMIT 50

Thesis students for a university and their various IDs

Students of a university

#title: Students of a university and their IDs
SELECT ?academic ?scholia ?academicLabel ?academicDescription ?academicAltLabel  ?gender ?lccn ?lccnurl  ?viaf ?viafurl ?orcid ?orcidurl ?gscholar ?gscholarurl  WHERE {
   ?academic wdt:P31 wd:Q5 . # academic has a person
  
   ?academic wdt:P69 wd:Q1150437 . # educated at Victoria University of Wellington

   BIND( URI(CONCAT('https://scholia.toolforge.org/author/', STRAFTER(STR(?academic), "/entity/")))  AS ?scholia ) .

   OPTIONAL { ?academic wdt:P21 ?gender . } .   
   OPTIONAL { ?academic wdt:P244 ?lccn .  BIND( IRI(CONCAT('https://lccn.loc.gov/', STR(?lccn)))  AS ?lccnurl ) .   } . 
   OPTIONAL { ?academic wdt:P214 ?viaf .  BIND( IRI(CONCAT('https://viaf.org/viaf/', STR(?viaf)))  AS ?viafurl ) . } . 
   OPTIONAL { ?academic wdt:P496 ?orcid .  BIND( IRI(CONCAT('https://orcid.org/', STR(?orcid)))  AS ?orcidurl ) . } . 
   OPTIONAL { ?academic wdt:P1960 ?gscholar .  BIND( IRI(CONCAT('https://scholar.google.com/citations?user=', STR(?gscholar)))  AS ?gscholarurl ) . } . 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

}
LIMIT 50

Students of a university and their IDs

Staff of a university

#title: Staff of a university and their IDs
SELECT ?academic ?scholia ?academicLabel ?academicDescription ?academicAltLabel ?gender ?lccn ?lccnurl  ?viaf ?viafurl ?orcid ?orcidurl ?gscholar ?gscholarurl  WHERE {
   ?academic wdt:P31 wd:Q5 . # academic has a person
  
   ?academic wdt:P108 wd:Q1150437 . # employed by Victoria University of Wellington

   BIND( URI(CONCAT('https://scholia.toolforge.org/author/', STRAFTER(STR(?academic), "/entity/")))  AS ?scholia ) .

   #uncomment out these two lines to just show non-men
   #?item wdt:P21 ?gender. # get their gender (because this is not wrapped in OPTIONAL{}, items with a null gender are excluded from the results)
   #FILTER (?gender != wd:Q6581097) # not male
 
   OPTIONAL { ?academic wdt:P21 ?gender . } .   
   OPTIONAL { ?academic wdt:P244 ?lccn .  BIND( IRI(CONCAT('https://lccn.loc.gov/', STR(?lccn)))  AS ?lccnurl ) .   } . 
   OPTIONAL { ?academic wdt:P214 ?viaf .  BIND( IRI(CONCAT('https://viaf.org/viaf/', STR(?viaf)))  AS ?viafurl ) . } . 
   OPTIONAL { ?academic wdt:P496 ?orcid .  BIND( IRI(CONCAT('https://orcid.org/', STR(?orcid)))  AS ?orcidurl ) . } . 
   OPTIONAL { ?academic wdt:P1960 ?gscholar .  BIND( IRI(CONCAT('https://scholar.google.com/citations?user=', STR(?gscholar)))  AS ?gscholarurl ) . } . 

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

}
LIMIT 50

Staff of a university and their IDs

People associated university who have no LCCN

#title: People accociated with a university who have no LCCN
SELECT DISTINCT ?academic ?academicLabel ?academicDescription ?academicAltLabel ?viafurl ?orcidurl WHERE {
   
   ?academic wdt:P31 wd:Q5 . # academic is a person
  
   {
     ?academic wdt:P69 wd:Q1150437 . #educated at Victoria University of Wellington
   } UNION {
     ?academic wdt:P108 wd:Q1150437 . # employed by Victoria University of Wellington
   } 
   
   FILTER NOT EXISTS { ?academic wdt:P244 ?lccn . } # filter out those with an lccn
   OPTIONAL { ?academic wdt:P214 ?viaf .  BIND( IRI(CONCAT('https://viaf.org/viaf/', STR(?viaf)))  AS ?viafurl ) . } . 
   OPTIONAL { ?academic wdt:P496 ?orcid .  BIND( IRI(CONCAT('https://orcid.org/', STR(?orcid)))  AS ?orcidurl ) . } . 
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

People accociated with a university who have no LCCN

Links

Official Documentation
Control Subfields - the MARC fields against which the Property:P244 is matched.