Wikidata:Gruppo Wikidata per Musei, Archivi e Biblioteche/Marche bibliografiche
Il progetto Marche bibliografiche (Q109613116) si pone l’obiettivo di costruire e collaudare un prototipo di banca dati open source liberamente accessibile contenente tutte le informazioni sui protagonisti passati e presenti della filiera editoriale e sulle pubblicazioni prodotte nelle Marche o che hanno come tema le Marche, condividendo i dati bibliografici attraverso i progetti Wikimedia.
Descrizione
editIl progetto intende favorire la conservazione e l’accesso via web a ogni forma di pubblicazione riguardante la cultura marchigiana, esponendola a un pubblico più numeroso di quello che può avere fisicamente accesso alle biblioteche, e garantendone così la disponibilità per il lavoro di ricercatori, studiosi e semplici cittadini.
La pubblicazione dei dati renderà possibile effettuare la ricerca e la mappatura riguardante, monografie, periodici e quotidiani marchigiani per argomento, autore, editore, data e luogo di pubblicazione, luogo di conservazione, consentendo così di iniziare a costruire una storia del panorama editoriale marchigiano nel corso dei secoli.
Obiettivi specifici
editTra gli obiettivi specifici rientrano
- la pubblicazione dei dati relativi al commercio librario nelle Marche, includendo autori, pubblicazioni, editori e distributori, tramite la condivisione dei dati presenti negli archivi dei quotidiani storici e delle pubblicazioni periodiche delle biblioteche marchigiane;
- la pubblicazione in Wikidata dei metadati di ogni opera pubblicata nelle Marche, o di interesse marchigiano.
- la pubblicazione di dati bibliografici dei codici manoscritti appartenenti alle biblioteche marchigiane.
- gli elementi Wikidata delle collezioni potranno essere arricchiti dalle immagini delle opere digitalizzate che le biblioteche vorranno mettere a disposizione caricandole in Commons.
Attività
editIl progetto prevede vari step:
- la creazione di gruppi di lavoro locali per l'apprendimento collaborativo e la realizzazione di progetti specifici;
- raccogliere i dati essenziali di ogni opera come titolo, autore, editore, data e luogo di pubblicazione, ISBN e altri identificativi;
- aggiungere dati descrittivi, come il soggetto, il genere e altri dati utili;
- infine collegare queste opere alle loro versioni digitalizzate messe a disposizione dalle biblioteche. In particolare per quest’ultima fase, si auspica di poter collegare ogni elemento ai suoi dati OCR pubblicati in maniera libera e alle proprie immagini digitalizzate.
Creare un elemento Wikidata per ogni entità bibliografica permetterà di avere accesso a tool open source per l’interrogazione e la visualizzazione dei dati della collezione.
Contributori
editLascia qui la tua firma se sei interessato al progetto:
Lavori svolti
edit- Fano. Supplemento del Notiziario di informazione sui problemi cittadini (Q109650346)
- Nuovi studi fanesi (Q109613247)
- Caricamento dei dati marchigiani dell'Anagrafe delle biblioteche italiane (ICCU)
- Inserimento, correzione, integrazione dei dati anagrafici degli archivi marchigiani registrati su Wikidata di cui la maggior parte provenienti da Archives portal Europe.
Query
edit#title:Classificazione CDD
SELECT ?item ?itemLabel
?P1036 ?ccd_opere WHERE {
?item wdt:P1433 wd:Q109613247.
OPTIONAL { ?item wdt:P1036 ?P1036. }
OPTIONAL { ?item wdt:P8359 ?ccd_opere. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "it" . }
}
#title:Riviste e libri censiti
SELECT ?opera ?operaLabel ?operaDescription
WHERE {
?opera wdt:P5008 wd:Q109613116 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?operaLabel
#title:Contributi pubblicati nelle riviste e nei libri censiti
SELECT ?item ?itemLabel ?opera ?operaLabel
WHERE {
?opera wdt:P5008 wd:Q109613116 .
?item wdt:P1433 ?opera .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
#title:Autori dei contributi pubblicati nelle riviste e nei libri censiti
SELECT ?autore ?autoreLabel ?item ?itemLabel ?opera ?operaLabel
WHERE {
?opera wdt:P5008 wd:Q109613116 .
?item wdt:P1433 ?opera .
?item wdt:P50 ?autore .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
#title:Contributi pubblicati in Nuovi studi fanesi, con rispettivi autori
SELECT ?item ?itemLabel ?autore ?autoreLabel
WHERE {
?item wdt:P1433 wd:Q109613247 .
?item wdt:P50 ?autore .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
#title:All museums (including subclass of museum) in Fano with coordinates
SELECT DISTINCT ?item ?name ?coord ?lat ?lon
WHERE
{
hint:Query hint:optimizer "None" .
?item wdt:P131* wd:Q1492 .
?item wdt:P31/wdt:P279* wd:Q33506 .
?item wdt:P625 ?coord .
?item p:P625 ?coordinate .
?coordinate psv:P625 ?coordinate_node .
?coordinate_node wikibase:geoLatitude ?lat .
?coordinate_node wikibase:geoLongitude ?lon .
SERVICE wikibase:label { bd:serviceParam wikibase:language "it" . ?item rdfs:label ?name }
}
ORDER BY ASC (?name)
Archivi nelle Marche
edit#title:All archives (including subclass of archives) in Marche with coordinates
SELECT DISTINCT ?item ?name ?coord ?lat ?lon
WHERE
{
hint:Query hint:optimizer "None" .
?item wdt:P131* wd:Q1279 .
?item wdt:P31/wdt:P279* wd:Q166118 .
?item wdt:P625 ?coord .
?item p:P625 ?coordinate .
?coordinate psv:P625 ?coordinate_node .
?coordinate_node wikibase:geoLatitude ?lat .
?coordinate_node wikibase:geoLongitude ?lon .
SERVICE wikibase:label { bd:serviceParam wikibase:language "it" . ?item rdfs:label ?name }
}
ORDER BY ASC (?name)
Query su archival institution
editSELECT ?item ?itemLabel ?unitammLabel ?cap
WHERE
{
?item wdt:P131 ?unitamm; schema:description ?itemdesc.
?unitamm wdt:P281 ?cap
FILTER((LANG(?itemdesc)) = "en")
FILTER(CONTAINS(STR(?itemdesc), "archival institution in Italy"))
FILTER ("60010" < ?cap)
FILTER (?cap < "63900")
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Ricerca MAB nelle Marche
edit#title:All MAB (including subclass of museum) in Marche with coordinates
SELECT DISTINCT ?item ?name ?coord ?lat ?lon
WHERE
{
hint:Query hint:optimizer "None" .
?item wdt:P131* wd:Q1279 .
?item wdt:P31/wdt:P279* wd:Q11834910 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "it" . ?item rdfs:label ?name }
}
ORDER BY ASC (?name)
Tutte le biblioteche
edit#title:All libraries (including subclass of library) in Marche
SELECT DISTINCT ?item ?name ?cap WHERE {
?item (wdt:P131*) wd:Q1279;
(wdt:P31/(wdt:P279*)) wd:Q7075.
?item wdt:P281 ?cap #restituisce tutte le righe con o senza cap, per avere solo quelle senza cap sostituire optional con minus. togliendo minus/optional e le graffe si ottengono solo le righe piene
SERVICE wikibase:label {
bd:serviceParam wikibase:language "it".
?item rdfs:label ?name.
}
}
ORDER BY (?name)
Tutti gli archivi
editTabella biblioteche marche con istanza
edit#title: biblioteche pubbliche in Italia presenti su Wikidata. tabella di controllo
SELECT DISTINCT ?isil ?item ?istanzaLabel ?itemLabel ?itemDescription ?unitammLabel ?addr ?cap ?tel ?mail ?website ?coord WHERE {
?item wdt:P31/wdt:P279* wd:Q7075; wdt:P31 ?istanza; wdt:P131* wd:Q1279; wdt:P791 ?isil.
#proprietà minime
OPTIONAL { ?item wdt:P131 ?unitamm . }
OPTIONAL { ?item wdt:P625 ?coord . }
OPTIONAL { ?item wdt:P6375 ?addr . }
OPTIONAL { ?item wdt:P281 ?cap . }
#contatti
OPTIONAL { ?item wdt:P1329 ?tel . }
OPTIONAL { ?item wdt:P968 ?mail . }
OPTIONAL { ?item wdt:P856 ?website . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}