Wikidata:Gruppo Wikidata per Musei, Archivi e Biblioteche/Riviste di biblioteconomia

Utenti coinvoltiEdit

ObiettiviEdit

Il progetto ha lo scopo di utilizzare Wikidata come dataset per l'analisi, la visualizzazione e la scoperta di informazioni relative alle riviste italiane di biblioteconomia. L'importazione dei dati relativi agli autori di articoli pubblicati sulle riviste italiane e agli articoli pubblicati da ciascun autore consente infatti di fare analisi approfondite in termini quantitativi e qualitativi delle pubblicazioni stesse, avvalendosi anche di strumenti già creati e resi disponibili dalla comunità Wikidata, come Scholia. Per esempio, il caricamento degli articoli pubblicati su JLIS.it consente la data visualization della produzione scientifica della rivista.

Materiali e metodiEdit

Il gruppo di lavoro sulle riviste italiane di biblioteconomia si è costituito in ottobre 2020 e ha subito iniziato a lavorare, procedendo in una prima fase a testare le diverse possibilità tecniche (inserimento manuale, Zotero + QuickStatements, OAI-PMH + Open Refine) e poi al caricamento dei dati degli autori e degli articoli indicati nella tabella sottostante. In particolare ha realizzato il caricamento su Wikidata di tutti gli articoli pubblicati nelle seguenti riviste:

  • AIB studi (vol. 52, 2012 - 62, 2022)
  • Bibliothecae.it (vol. 1, 2021 - 10, 2021, a cura della redazione della rivista)
  • Biblioteche Oggi trends (vol. 1, 2015 - 6, 2020)
  • Biblioteche Oggi (vol. 31, 2013 - 38, 2020)
  • Bollettino AIB (vol. 32, 1992 - 51, 2011)
  • JLIS.it (vol. 1, 2010 - 11, 2020)
  • altre, indicate in dettaglio nella tabella più sotto.

Ciascun articolo risulta corredato dei metadati essenziali (titolo, data di pubblicazione, numero di volume e fascicolo, DOI, ecc.), è opportunamente collegato alla propria rivista, ai propri autori e, in alcuni casi, alle parole chiave.

L'intero processo per le riviste sopra elencate si è basato sull’utilizzo di dati ricavabili dal protocollo OAI-PMH e sulla loro manipolazione e riconciliazione attraverso il software libero OpenRefine. La scelta delle riviste elencate, tra tante, è dovuta proprio alla disponibilità dei metadati in questo formato (solo di recente, in gennaio 2022, si è iniziato a caricare dati ottenuti mediante tecniche di scraping sul web). Il software OpenRefine garantisce infatti l’importazione di dati attraverso molteplici modalità, tra cui l’import per URL da sistemi e protocolli esterni: attraverso la chiamata da OpenRefine al servizio OAI-PMH, di cui si è reso necessario recuperare prima l’URL di accesso, è stato possibile importare i dati di ogni singolo articolo in vari formati (nlm, oai_dc). Per una introduzione di base a OpenRefine, si vedano i due seminari tenuti all'interno delle attività di formazione del GWMAB (Incontri del ciclo avanzato).

Successivamente i singoli elementi dei dati sono stati estratti attraverso appositi comandi in linguaggio GREL, riconciliati con le entità già presenti in Wikidata e mappati con un apposito schema per l’export vero e proprio verso Wikidata. Questa procedura, apparentemente complessa, ha permesso di caricare in poco tempo una grande quantità di dati: purtroppo risulta applicabile solamente a quelle riviste che utilizzano OJS o che forniscono i dati in un formato elettronico anche minimamente strutturato.

Il lavoro sta procedendo con un’attività di miglioramento dei dati caricati, in particolare di quelli legati agli autori (con un incremento delle proprietà e degli identificativi disponibili) e alle parole chiave. In futuro vorremmo ampliare il numero delle riviste coperte (cerchiamo collaboratori!)

Per visualizzazioni provvisorie dei dati, utilizzare le query

Istruzioni per fornire dati per arricchire gli autoriEdit

1. La query predisposta consente di ottenere un elenco degli autori che hanno pubblicato articoli sulle riviste di biblioteconomia italiane (naturalmente, solo per gli articoli e per le riviste che sono state caricate finora in Wikidata!). L'elenco è in ordine alfabetico per cognome, ma la prima parte dell'elenco presenta in ordine di etichetta gli item privi di cognome; quindi, per esempio, Ada Rossi, se priva della proprietà cognome, viene ordinata sotto la A, non sotto la R.

2. Si scorre la query e si individua un autore del quale si pensa di poter rintracciare dati e fonti sul web.

3a. Se si è utenti pratici di Wikidata è meglio modificare direttamente l'item, invece che compilare il modulo. Un esempio di autore ben arricchito, con esempi di identificativi e di proprietà, a cui ispirarsi per aggiungere identificativi e proprietà è questo: Carlo Revelli (Q22093383).

3b. Se non si è pratici di Wikidata, si copia l'identificativo (per esempio Q22093383) e si procede a compilare il modulo di raccolta dei dati. Il modulo prevede due dati sempre obbligatori: l'identificativo Wikidata (es. Q22093383) e il nome e cognome (es. Carlo Revelli). Tuttavia è estremamente importante fornire anche il link a una o più fonti dalle quali si sono ricavati i dati che si inseriscono e uno o più identificatori.

Alcuni identificatori suggeriti (gli esempi di questi identificatori si trovano nel modulo)

Qualsiasi altro ID sia disponibile e facilmente reperibile (per esempio, LinkedIn personal profile ID (P6634), Twitter username (P2002), Facebook ID (P2013), ecc.).

Stato di avanzamento dei lavoriEdit

magazine (Q41298) periodo anni completi inseriti indirizzo del servizio OAI tipo di accesso ai dati ISSN (P236) priorità importazione
Accademie e biblioteche d'Italia (Q27715472) 1927- ma non pubblicato dal 1944 al 1949 e nel 2005; N.s dal 2006 2010-2018 Disponibili indici dell'Istituto Datini dal 2001 al 2020 0001-4451 1   Done
AIB studi (Q3600960) 2014- 2012-2022 https://aibstudi.aib.it/oai Oai 2239-6144 1   Done
AIDAinformazioni (Q59907687) 1984- 1995-2007 1121-0095 3   Done
Archivi & computer (Q106006922) 1991-2013 ---- 1121-2462 1
Biblioteche Oggi (Q3639685) 1983- 1993-nov. 2020 http://www.bibliotecheoggi.it/rivista/oai Oai 0392-8586 1   Done
Biblioteche Oggi Trends (Q58294861) 2015- 2015-2020 http://www.bibliotecheoggi.it/trends/oai Oai 2421-3810 1   Done
Bibliothecae.it (Q50811189) 2012- 2012- https://bibliothecae.unibo.it/oai Oai 2283-9364 1   Done
Bollettino AIB (Q102069715) 1992-2011 1992-2011 https://bollettino.aib.it/oai 1121-1490 1   Done
Bollettino d'informazioni. Associazione italiana biblioteche (Q104701272) 1961-1991 1961-1991 [con lacune di intere annate] https://riviste.aib.it/index.php/boll/oai 1121-1490 2
Bollettino dell'Istituto Centrale per la Patologia del Libro Alfonso Gallo (Q106008699) 1973-1991 ---- ---- 0391-5972 3
Bollettino di informazione ABEI (Q106008618) 1981- ---- ---- 1121-712X 3
Culture del testo e del documento (Q3699359) 2000- ---- ---- 1593-5698 1
Culture del testo (Q106006980) 1995-1999 ---- ---- 1126-7437 1
DigItalia (Q63871016) 2005- ---- http://digitalia.sbn.it/oai Oai 1972-621X 1
Giornale della Libreria (Q96703962) 1994- ---- 1124-9137 3
Il Bibliotecario : rivista di biblioteconomia, bibliografia e scienze dell'informazione
Il bibliotecario. Rivista di studi bibliografici. I e II serie (Q105477687) + Il bibliotecario. Rivista di studi bibliografici. III serie (Q102149654)
1984-2011 1984-2011 1125-0992 1   Done
JLIS.it (Q3805294) 2010- 2010- https://www.jlis.it/oai Oai 2038-1026 1   Done
La Bibliofilia: rivista di storia del libro e di bibliografia (Q15755863) 1899- 1950-1979 [lac. 1951-52 e 1980-83] e 1984-2018, per il momento lacunosi 0006-0941 1   In progress
La rivisteria 1984-1990 ---- 0393-5914 3
La rivisteria 1993-2007 ---- 1128-7578 3
La rivisteria, librinovità 1991-1993 ---- 1128-756X 3
Nuovi Annali della Scuola Speciale per Archivisti e Bibliotecari (Q65611322) (a stampa) 1987- ---- http://www.istitutodatini.it/biblio/riviste/a-c/arc-bib1.htm 1122-0775 1
Nuovi Annali della Scuola Speciale per Archivisti e Bibliotecari (Q65611322) (online) 2009- ---- http://digital.casalini.it/20376073 2037-6073 2
Rara volumina (Q106008979) 1994- ---- http://digital.casalini.it/24213357 2421-3357 3
SBN Notizie (Q106007032) 1989-2001 ---- 3
Sfoglialibro (Q106007063) 1988-2011 ---- 1120-253X 3
Q104089775 1989- ---- ---- 2281-0617 3

QueryEdit

RivisteEdit

#Riviste italiane relative alla scienza dell'informazione e delle biblioteche
SELECT DISTINCT ?rivista ?rivistaLabel
WHERE {
  ?rivista wdt:P31 ?v . VALUES ?v { wd:Q5633421 wd:Q41298 }
  ?rivista wdt:P495 wd:Q38 ; wdt:P921 wd:Q13420675 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?rivistaLabel
Try it!
#Riviste italiane relative alla scienza dell'informazione e delle biblioteche in ordine di numero decrescente di articoli
SELECT DISTINCT ?rivista ?rivistaLabel (COUNT(?articolo) AS ?count) # ?articoloLabel ?rivista ?rivistaLabel
WHERE {
  ?rivista wdt:P31 ?v . VALUES ?v { wd:Q5633421 wd:Q41298 }
  ?rivista wdt:P495 wd:Q38 ; wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P1433 ?rivista .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}

GROUP BY ?rivista ?rivistaLabel
ORDER BY DESC(?count)
Try it!

ArticoliEdit

#Articoli di riviste italiane relative alla scienza dell'informazione e delle biblioteche, in ordine di rivista, data crescente e titolo dell'articolo, escluse le recensioni
SELECT DISTINCT ?articolo ?articoloLabel ?rivista ?rivistaLabel ?dataPubbl
WHERE {
  ?rivista wdt:P31 wd:Q5633421 ; wdt:P495 wd:Q38 ; wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P1433 ?rivista ; wdt:P577 ?dataPubbl .
  MINUS { ?articolo wdt:P31 wd:Q637866 .} # escluse le recensioni
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?rivista ?dataPubbl ?articoloLabel
Try it!
#Articoli di una specifica rivista italiana di scienza dell'informazione e delle biblioteche, in ordine di volume e fascicolo, data crescente e titolo dell'articolo. N.B. Modificare la seconda riga del WHERE per ottenere la rivista desiderata
SELECT DISTINCT ?articolo ?articoloLabel ?volume ?fascicolo ?dataPubbl
WHERE {
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P577 ?dataPubbl ; wdt:P478 ?volume ; wdt:P433 ?fascicolo ; wdt:P1433 wd:Q27715472 . # modificare questo valore Q27715472 - riferito a Accademie e biblioteche d'Italia - inserendo il Q della rivista desiderata
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?dataPubbl ?volume ?fascicolo ?articoloLabel
Try it!

AutoriEdit

#Autori di articoli di riviste italiane relative alla scienza dell'informazione e delle biblioteche
SELECT DISTINCT ?autore ?autoreLabel
WHERE {
  ?rivista wdt:P31 wd:Q5633421 ; wdt:P495 wd:Q38 ; wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P1433 ?rivista ; wdt:P50 ?autore .
  ?autore wdt:P31 ?inst .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?autoreLabel
Try it!
#Elenco di autori per numero di articoli nelle riviste italiane di biblioteconomia censite e inserite
SELECT DISTINCT ?autoreLabel (COUNT(?articolo) AS ?count)
WHERE {
  ?rivista wdt:P31 wd:Q5633421 ; wdt:P495 wd:Q38 ; wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P1433 ?rivista ; wdt:P50 ?autore .
  ?autore wdt:P31 ?inst .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?autoreLabel
ORDER BY DESC(?count)
Try it!
#Elenco per numero assoluto di opere al momento censite in Wikidata di autori che hanno pubblicato almeno un articolo nelle riviste italiane di biblioteconomia censite nel progetto
SELECT DISTINCT ?autore ?autoreLabel (COUNT(DISTINCT ?tutto) AS ?n)
WHERE {
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P1433 ?rivista .
  VALUES ?rivista { wd:Q27715472 wd:Q3600960 wd:Q59907687 wd:Q3639685 wd:Q58294861 wd:Q50811189 wd:Q102069715 wd:Q3805294 wd:Q105477687 wd:Q102149654 }.
  ?articolo wdt:P50 ?autore .
  ?tutto wdt:P50 ?autore .
  ?autore wdt:P31 ?inst .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?autore ?autoreLabel ?n
ORDER BY DESC(?n)
Try it!
#Suddivisione per numero di identificativi degli autori di articoli di riviste italiane relative alla scienza dell'informazione e delle biblioteche
SELECT ?identificativi (COUNT(DISTINCT ?autore) AS ?autori)
WHERE {
  ?rivista wdt:P31 wd:Q5633421 ; wdt:P495 wd:Q38 ; wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 ; wdt:P1433 ?rivista ; wdt:P50 ?autore .
  ?autore wdt:P31 ?inst ; wikibase:identifiers ?identificativi .
}
GROUP BY ?identificativi
ORDER BY xsd:integer(?identificativi)
Try it!

Query di lavoroEdit

Queste query sono predisposte per trovare item con dati incompleti o presumibilmente errati, allo scopo migliorare la qualità dei dati stessi.

#Autori di articoli di riviste italiane relative alla scienza dell'informazione e delle biblioteche privi di qualsivoglia identificativo
SELECT DISTINCT ?autore ?autoreLabel ?cognomeLabel ?autoreDescription
WHERE {
  ?rivista wdt:P31 wd:Q5633421 .
  ?rivista wdt:P495 wd:Q38 .
  ?rivista wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 .
  ?articolo wdt:P1433 ?rivista .
  ?articolo wdt:P50 ?autore .
  ?autore wikibase:identifiers ?identificativi .
  OPTIONAL { ?autore wdt:P734 ?cognome . }
  FILTER(?identificativi = 0)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?cognomeLabel ?autoreLabel
Try it!
#Articoli di riviste italiane relative alla scienza dell'informazione e delle biblioteche privi di autore
SELECT DISTINCT ?articolo ?articoloLabel ?rivistaLabel
WHERE {
  ?rivista wdt:P31 wd:Q5633421 .
  ?rivista wdt:P495 wd:Q38 .
  ?rivista wdt:P921 wd:Q13420675 .
  ?articolo wdt:P31 wd:Q13442814 .
  ?articolo wdt:P1433 ?rivista .
 FILTER NOT EXISTS { ?articolo wdt:P50 ?autore . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?rivistaLabel
Try it!