Wikidata:Gruppo Wikidata per Musei, Archivi e Biblioteche/SAIA

Il progetto SAIA prevede la creazione e il miglioramento degli elementi di Wikidata relativi, sotto diversi punti di vista, alla Italian School of Archaeology at Athens (Q1576779).

La prima fase del progetto, svolta dall'utente Epìdosis tra il 27 aprile e il 6 novembre 2021, ha riguardato la copertura integrale in Wikidata degli allievi della Scuola dalla sua fondazione al 2021 su cui sia stato possibile trovare un minimo di informazioni nella lista ufficiale, per un totale di 433 elementi unici.

Query edit

Allievi edit

#title:Lista degli allievi della SAIA, in ordine alfabetico per cognome
SELECT DISTINCT ?person ?personLabel
WHERE {
  ?person wdt:P69 wd:Q1576779 .
  OPTIONAL { ?person wdt:P734 ?cognome . ?cognome wdt:P1705 ?n . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
}
ORDER BY ?n
Lista degli allievi della SAIA, in ordine alfabetico per cognome

Nota: minime anomalie sui cognomi ancora da risolvere

#title:Lista degli allievi della SAIA, per anno di frequenza (con anni di nascita e morte se noti)
SELECT ?person ?personLabel ?birthyear ?deathyear ?start ?end
WHERE {
  ?person p:P69 [ ps:P69 wd:Q1576779 ; pq:P580 ?sd ; pq:P582 ?ed ] .
  BIND(YEAR(?sd) AS ?start)
  BIND(YEAR(?ed) AS ?end)
  OPTIONAL { ?person wdt:P569 ?born . BIND(YEAR(?born) AS ?birthyear) }
  OPTIONAL { ?person wdt:P570 ?died . BIND(YEAR(?died) AS ?deathyear) }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
}
ORDER BY ?start
Lista degli allievi della SAIA, per anno di frequenza (con anni di nascita e morte se noti)
#title:Mappa dei luoghi di nascita e di morte degli allievi della SAIA
#defaultView:Map{ "markercluster": true}
SELECT ?person ?personLabel ?place ?placeLabel  ?coord ?layer
WHERE {  
  {?person wdt:P69 wd:Q1576779 .
  OPTIONAL { ?person wdt:P19 ?place . ?place wdt:P625 ?coord . BIND("birth" AS ?layer)} }
  UNION
  {?person wdt:P69 wd:Q1576779 .
  OPTIONAL { ?person wdt:P20 ?place . ?place wdt:P625 ?coord . BIND("death" AS ?layer)} }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
}
Mappa dei luoghi di nascita e di morte degli allievi della SAIA

Nota: ovviamente non tutti i luoghi di nascita e di morte sono noti, quindi la mappa è parziale

#title:Grafico del numero di identificativi per gli allievi della SAIA
#defaultView:LineChart
SELECT ?n (COUNT(?person) AS ?persons)
WHERE {
  ?person wdt:P69 wd:Q1576779 .
  ?person wikibase:identifiers ?n .
}
GROUP BY ?n ?persons
ORDER BY ?n
Grafico del numero di identificativi per gli allievi della SAIA
#title:Lista degli identificativi (con codice VIAF, per i membri VIAF) connessi ad allievi SAIA
SELECT ?id ?idLabel (COUNT(?idst) AS ?n) ?codice_viaf
WHERE {
  ?person wdt:P69 wd:Q1576779 .
  ?person ?idst ?idv .
  ?id wikibase:directClaim ?idst .
  ?id wikibase:propertyType wikibase:ExternalId .
  OPTIONAL { ?id p:P1552 [ ps:P1552 wd:Q26921380 ; pq:P3295 ?codice_viaf ] . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
}
GROUP BY ?id ?idLabel ?n ?codice_viaf
ORDER BY DESC(?n)
Lista degli identificativi (con codice VIAF, per i membri VIAF) connessi ad allievi SAIA
Intersezioni con identificativi esterni Distribuzione per occupazione Intersezioni col catalogo SAIA
See it in Wikidata Query Service See it in Wikidata Query Service See it in Wikidata Query Service

Progetti correlati edit