Wikidata:WikiProject France/Queries/Communes

Cette page contient des requêtes SPARQL utiles pour la maintenance.

Liste des communes françaises actuelles

Note: toute tentative d'ajouter un champ (par exemple le département) fait actuellement partir la requête en timeout.

The following query uses these:

Items: commune of France (Q484170)

Properties: subclass of (P279)   , instance of (P31)   , INSEE municipality code (P374)   , end time (P582)  
```
# Communes françaises
SELECT DISTINCT ?commune ?commune_label ?insee {
      ?commune p:P31 ?typeStatement . # Les éléments qui ont pour nature...
      ?typeStatement ps:P31/wdt:P279* wd:Q484170 . # commune française ou une sous-classe
      FILTER NOT EXISTS { ?typeStatement pq:P582 [] } . # La commune n'a pas de date de fin
      
      ?commune p:P374 ?inseeStatement .
      ?inseeStatement ps:P374 ?insee .
      FILTER NOT EXISTS { ?inseeStatement pq:P582 [] } . # Le code insee n'a pas de date de fin
  
  OPTIONAL { ?commune rdfs:label ?commune_label . FILTER (LANG(?commune_label) = "fr") . }
}
```

Try it!

Communes françaises n'ayant pas de département

(cette requête ne doit renvoyer aucun résultat)

The following query uses these:

Items: commune of France (Q484170)   , commune nouvelle (Q2989454)   , commune of France with specific status (Q22927616)   , department of France (Q6465)   , overseas department and region of France (Q202216)   , French overseas collectivity (Q719487)   , province of New Caledonia (Q3408484)   , Metropolis of Lyon (Q16665897)   , Paris (Q90)

Properties: INSEE municipality code (P374)   , instance of (P31)   , located in the administrative territorial entity (P131)   , end time (P582)  
```
# Communes françaises sans département
# Cette requête ne doit renvoyer aucun résultat.
SELECT DISTINCT ?commune ?communeLabel ?communeDescription ?departementLabel ?insee {
  ?commune p:P31 ?statement .	# Les éléments qui ont pour nature...
  ?statement ps:P31 ?type . # ...un des types autorisés ci-dessous
  VALUES ?type {
     wd:Q484170 # commune française
     wd:Q2989454 # commune nouvelle
     wd:Q22927616 # commune française à statut particulier
    }
  FILTER NOT EXISTS { ?statement pq:P582 ?fin_com } . # La commune n'a pas de date de fin
  
  ?commune wdt:P374 ?insee . 
  
  # Il n'y a pas de département sans date de fin
  FILTER NOT EXISTS { ?commune p:P131 ?departementStatement .
            ?departementStatement ps:P131 ?directdepartement .
            ?directdepartement wdt:P31 ?typeDep .
            VALUES ?typeDep {
              wd:Q6465 # département
              wd:Q202216 # département d'Outre-mer
              wd:Q719487 # collectivité d'Outre-mer
              wd:Q3408484 # Province de la Nouvelle-Calédonie
            }
            FILTER NOT EXISTS { ?departementStatement pq:P582 ?fin_dep } .
           } 
  
  # Il reste à ignorer Paris et les communes de la métropole lyonnaise
  FILTER NOT EXISTS { ?commune wdt:P131 wd:Q16665897 . } # Métropole lyonnaise
  FILTER ( ?commune != wd:Q90 ) . # Paris
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" . }
} ORDER BY ?communeLabel
```

Try it!

Communes françaises dont le code INSEE du département ne correspond pas

(cette requête ne doit renvoyer aucun résultat)

The following query uses these:

Items: commune of France (Q484170)   , commune nouvelle (Q2989454)   , commune of France with specific status (Q22927616)   , department of France (Q6465)   , overseas department and region of France (Q202216)   , French overseas collectivity (Q719487)   , province of New Caledonia (Q3408484)   , Metropolis of Lyon (Q16665897)   , Paris (Q90)

Properties: INSEE municipality code (P374)   , instance of (P31)   , INSEE department code (P2586)   , located in the administrative territorial entity (P131)   , end time (P582)  
```
# Communes françaises dont le département ne correspond pas
# Cette requête ne doit renvoyer aucun résultat.
SELECT DISTINCT ?commune ?communeLabel ?communeDescription ?insee ?deptinsee ?departementLabel {
  ?commune p:P31 ?statement .	# Les éléments qui ont pour nature...
  ?statement ps:P31 ?type . # ...un des types autorisés ci-dessous
  VALUES ?type {
     wd:Q484170 # commune française
     wd:Q2989454 # commune nouvelle
     wd:Q22927616 # commune française à statut particulier
    }
  FILTER NOT EXISTS { ?statement pq:P582 ?fin_com } . # La commune n'a pas de date de fin
  
  ?commune wdt:P374 ?insee . 
  
  ?commune p:P131 ?departementStatement .
  ?departementStatement ps:P131 ?departement .
  ?departement wdt:P31 ?typeDep .
  VALUES ?typeDep {
    wd:Q6465 # département
    wd:Q202216 # département d'Outre-mer
    wd:Q719487 # collectivité d'Outre-mer
    wd:Q3408484 # Province de la Nouvelle-Calédonie
  }
  FILTER NOT EXISTS { ?departementStatement pq:P582 ?fin_dep } .  # Le statement de localisation administrative dans le département n'a pas de date de fin

  ?departement wdt:P2586 ?deptinsee .
  # Il reste à ignorer Paris et les communes de la métropole lyonnaise
  FILTER NOT EXISTS { ?commune wdt:P131 wd:Q16665897 . } # Métropole lyonnaise
  FILTER ( ?commune != wd:Q90 ) . # Paris
  FILTER ( ! STRSTARTS( ?insee, ?deptinsee ) ) . # Le code INSEE de la commune ne commence pas par le code INSEE du département
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" . }
} ORDER BY ?insee
```

Try it!

Communes françaises directement placées dans une région (hors DOM/COM), hormis Paris

(Cette requête ne doit renvoyer aucun résultat)

The following query uses these:

Items: commune of France (Q484170)   , Paris (Q90)   , region of France (Q36784)   , overseas department and region of France (Q202216)   , French overseas collectivity (Q719487)

Properties: instance of (P31)   , subclass of (P279)   , located in the administrative territorial entity (P131)  
```
SELECT ?commune ?communeLabel ?region ?regionLabel
WHERE {
  ?commune wdt:P31/wdt:P279* wd:Q484170 . # commune
  FILTER ( ?commune != wd:Q90 ) # qui n'est pas Paris
  ?commune wdt:P131 ?region . # qui est dans une entité administrative
  ?region wdt:P31/wdt:P279* wd:Q36784 . # qui est une région…
  FILTER NOT EXISTS { ?region wdt:P31/wdt:P279* ?collectivite . VALUES ?collectivite { wd:Q202216 wd:Q719487 } } # …mais n'est pas un DOM/COM
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" . }
}
```

Try it!

Communes ayant deux valeurs de population au rang principal

(Cette requête ne doit renvoyer aucun résultat : la population la plus récente doit avoir un rang privilégié)

The following query uses these:

Items: commune of France (Q484170)   , commune nouvelle (Q2989454)

Properties: INSEE municipality code (P374)   , population (P1082)   , instance of (P31)   , end time (P582)  
```
SELECT DISTINCT ?commune ?commune_label ?insee (COUNT(?population) AS ?nb)
WHERE {
  ?commune p:P31 ?communeStatement .
  { ?communeStatement ps:P31 wd:Q484170 . } UNION 
  { ?communeStatement ps:P31 wd:Q2989454 . }
  
  OPTIONAL { ?commune rdfs:label ?commune_label FILTER (LANG(?commune_label) = "fr") . }
  FILTER NOT EXISTS { ?communeStatement pq:P582 ?dateFin . }
  
  ?commune wdt:P374 ?insee .
  
  OPTIONAL { ?commune wdt:P1082 ?population . }
} GROUP BY ?commune ?commune_label ?insee HAVING ( ?nb >= 2 ) ORDER BY ?commune
```

Try it!