Wikidata:WikiProject Italy/Toscana WLM

Attività svolte per il concorso WikiLovesMonuments dal 2018. Si fa riferimento per la trascrizione al Manuale per Wikidata-WLM

Queste pagine coordinano anche tutta la mappatura dei beni culturali, oltre le semplice autorizzazioni.

A partire dal 2021 tutte le pagine dei comuni sono state impostate di default, nell'ambito della gestione del lavori di Progetto_Partigiani_Toscani. La tabella sinottica è consultabile qui

Beni per WLM2022

Beni per WLM2021

Beni per WLM2020

Beni per WLM2019

Beni per WLM2018

Attività WLM 2018
monumenti liberati nel 2018
Monumenti liberati in Commons
i numeri di WLM2018 dalla mail di Losa del 1 ottobre 2018

Duplicati

duplicati di AlessioBot

Queries

Query su Comuni

Cliccare sulla freccia blu a sinistra in basso per lanciare la query

Query con tutti i monumenti inseriti nel 2019

#defaultView:Map
SELECT ?item ?itemLabel ?coord
WHERE {
  ?item wdt:P131* wd:Q1273 .
  ?item wdt:P625 ?coord .
  ?item p:P2186 ?wlmst .
  ?wlmst ps:P2186 ?wlmid .
  { ?wlmst pqv:P580 [ wikibase:timeValue ?start ; wikibase:timePrecision ?sprec ] .
    FILTER (
      ( ?sprec >  9 && ?start >= "2018-10-01T00:00:00+00:00"^^xsd:dateTime ) ||
      ( ?sprec < 10 && ?start >= "2019-01-01T00:00:00+00:00"^^xsd:dateTime )
    )
  } UNION
  { ?wlmst pq:P585 ?date .
    FILTER ( ?date < "2019-01-01T00:00:00+00:00"^^xsd:dateTime || ?date >= "2020-01-01T00:00:00+00:00"^^xsd:dateTime )
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}

Try it!

Query con tutti i monumenti partecipanti nel 2019 provvisti o privi di image (P18)

#defaultView:Map
SELECT ?item ?itemLabel ?coord ?img ?layer
WHERE {
  ?item wdt:P131* wd:Q1273 .
  ?item wdt:P625 ?coord .
  OPTIONAL { ?item wdt:P18 ?img . }
  ?item p:P2186 ?wlmst .
  ?wlmst ps:P2186 ?wlmid .
  BIND(IF(BOUND(?img),'img','no img') AS ?layer)
  MINUS {
    ?wlmst pqv:P580 [ wikibase:timeValue ?start ; wikibase:timePrecision ?sprec ] .
    FILTER (
      ( ?sprec >  9 && ?start >= "2019-10-01T00:00:00+00:00"^^xsd:dateTime ) ||
      ( ?sprec < 10 && ?start >= "2020-01-01T00:00:00+00:00"^^xsd:dateTime )
    )
  }
  MINUS {
    ?wlmst pqv:P582 [ wikibase:timeValue ?end ; wikibase:timePrecision ?eprec ] .
    FILTER (
      ( ?eprec >  9 && ?end < "2019-09-01T00:00:00+00:00"^^xsd:dateTime ) ||
      ( ?eprec < 10 && ?end < "2019-01-01T00:00:00+00:00"^^xsd:dateTime )
    )
  }
  MINUS {
    ?wlmst pq:P585 ?date .
    FILTER ( ?date < "2019-01-01T00:00:00+00:00"^^xsd:dateTime || ?date >= "2020-01-01T00:00:00+00:00"^^xsd:dateTime )
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}

Wikidata:WikiProject Italy/Toscana WLM

Contents