Wikidata:WikiProject Neighborhood Public Art in Boston/Queries
| Home | Data Models | Queries | List of Works | List of Artists | Bibliography |
Visualizations edit
Map displaying works with coordinate location (P625) edit
#title: Works of public art in Boston neighborhoods
#defaultView:Map{"markercluster":"true"}
SELECT distinct ?work ?workLabel ?coords ?address
(SAMPLE(?image) AS ?image)
(group_concat(distinct (year(?date)); separator=" or ") as ?year)
(group_concat(distinct ?materialLabel; separator="; ") as ?materials)
(group_concat(distinct ?categoryLabel; separator="; ") as ?categories)
(group_concat(distinct ?creatorLabel; separator="; ") as ?creators)
where {
hint:Query hint:optimizer "None".
?work wdt:P5008 wd:Q108040915;
wdt:P136 wd:Q557141;
wdt:P625 ?coords;
wdt:P31 ?category.
optional{?work wdt:P571 ?date.}
optional{?work wdt:P18 ?image.}
optional{?work wdt:P170 ?creator.}
optional{?work wdt:P6375 ?address.}
optional{?work wdt:P186 ?material.}
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?work rdfs:label ?workLabel.
?category rdfs:label ?categoryLabel.
?creator rdfs:label ?creatorLabel.
?material rdfs:label ?materialLabel
}
} group by ?work ?workLabel ?coords ?address
Graph of connections between items on this WikiProject's focus list edit
#title: Relationships between items on focus list of WikiProject Neighborhood Public Art in Boston
#defaultView:Graph
SELECT ?item1 ?image ?item1Label ?item2 ?image2 ?item2Label ?edgeLabel WHERE {
?item1 wdt:P5008 wd:Q108040915.
?item2 wdt:P5008 wd:Q108040915.
?item1 ?prop ?item2.
?edge ?dummy ?prop ; rdf:type wikibase:Property
OPTIONAL {?item1 wdt:P18 ?image}
OPTIONAL {?item2 wdt:P18 ?image2}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Gallery of people depicted in works of public art in Boston neighborhoods edit
#title: People depicted in works of public art in Boston neighborhoods, by number of works
#defaultView:ImageGrid
select ?depictedPerson ?depictedPersonLabel (sample(?image) as ?personImage) (count(distinct ?work) as ?numberOfWorks) where {
hint:Query hint:optimizer "None".
?work wdt:P5008 wd:Q108040915;
wdt:P136 wd:Q557141;
wdt:P180 ?depictedPerson.
?depictedPerson wdt:P31 wd:Q5.
optional{?depictedPerson wdt:P18 ?image.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?depictedPerson ?depictedPersonLabel
order by desc(?numberOfWorks)
Graph of works of art and people depicted in them edit
#title: Works of public art in Boston neighborhoods and the people they depict
#defaultView:Graph
select ?work ?workImage ?workLabel ?depictedPerson ?personImage ?depictedPersonLabel where {
hint:Query hint:optimizer "None".
?work wdt:P5008 wd:Q108040915;
wdt:P136 wd:Q557141;
wdt:P180 ?depictedPerson.
?depictedPerson wdt:P31 wd:Q5.
optional{?work wdt:P18 ?workImage}
optional{?depictedPerson wdt:P18 ?personImage.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Bubble chart of schools attended by artists on this WikiProject's focus list edit
#title: Schools attended by Boston public artists
#defaultView:BubbleChart
select ?school ?schoolLabel (count(distinct ?artist) as ?numberOfArtists) where {
hint:Query hint:optimizer "None".
?artist wdt:P5008 wd:Q108040915;
wdt:P31 wd:Q5;
wdt:P69 ?school.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?school ?schoolLabel
order by desc(?numberOfArtists)
Graph of Boston neighborhood public art and their creators edit
#title: Works of public art in Boston neighborhoods and their creators
#defaultView:Graph
SELECT DISTINCT ?art ?artLabel ?artImage ?artist ?artistLabel ?artistImage
WHERE
{
# work of art must be part of the Neighborhood Public Art in Boston WikiProject
?art wdt:P5008 wd:Q108040915;
wdt:P136 wd:Q557141;
wdt:P170 ?artist.
optional{?art wdt:P18 ?artImage}
optional{?artist wdt:P18 ?artistImage.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Project maintenance/tracking edit
All items on WikiProject focus list edit
#title: All items on the focus list of WikiProject Neighborhood Public Art in Boston
SELECT DISTINCT ?item ?itemLabel WHERE {
?item wdt:P5008 wd:Q108040915.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
All items used in references for items on WikiProject focus list edit
#title: Wikidata items used as "stated in" references for items on focus list
select distinct ?ref ?refLabel
(group_concat(distinct ?typeLabel; separator="; ") as ?refType)
(count(distinct ?item) as ?num_items)
where {
?item wdt:P5008 wd:Q108040915;
?propertyRel ?statement.
?statement prov:wasDerivedFrom ?refnode.
?refnode pr:P248 ?ref.
?ref wdt:P31 ?type.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?ref rdfs:label ?refLabel.
?type rdfs:label ?typeLabel}
} group by ?ref ?refLabel
order by desc(?num_items)
Artists and their online presence edit
#title: Social media accounts and official websites of Boston public artists
select ?artist ?artistLabel ?instagramURL ?twitterURL ?homepageURL where {
wd:P2003 wdt:P1630 ?instaFormatterURL.
wd:P2002 wdt:P1630 ?twitterFormatterURL.
?artist wdt:P5008 wd:Q108040915;
wdt:P31 wd:Q5.
optional{?artist wdt:P2003 ?instaHandle.}
optional{?artist wdt:P2002 ?twitterHandle.}
optional{?artist wdt:P856 ?homepageURL.}
BIND(IRI(REPLACE(?instaHandle, '^(.+)$', ?instaFormatterURL)) AS ?instagramURL).
BIND(IRI(REPLACE(?twitterHandle, '^(.+)$', ?twitterFormatterURL)) AS ?twitterURL).
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?artistLabel
External tools edit
Histropedia edit
Timeline of public art in the South End, by material and category