Wikidata

User:Pallor/Lekérdezés

< User:Pallor
(Redirected from User:Palotabarát/Lekérdezés)

[1]

János keresztnevűek állampolgárság-jelölés nélkül edit 

SELECT ?item ?itemLabel ?szulet ?hely ?helyLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P31 wd:Q5.
  ?item wdt:P735 wd:Q15075907.
  MINUS { ?item wdt:P27 [] }
  OPTIONAL { ?item wdt:P569 ?szulet. }
  OPTIONAL { ?item wdt:P19 ?hely. }
}  ORDER BY DESC (?szulet)
Try it!

Női nevek állampolgárság nélkül edit

Lásd még: hu:Szerkesztő:Palotabarát/Karbantartás/Nők állampolgárság nélkül 

SELECT ?item ?itemLabel ?born ?occ ?occLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu". }
  VALUES ?givenname { wd:P735 wd:Q19336932 wd:Q269339 wd:Q372399 wd:Q3576224 wd:Q19016266 wd:Q1032733 wd:Q18085213 wd:Q834707 wd:Q14647234 wd:Q20010401 wd:Q25611 wd:Q1030472 wd:Q25377100 wd:Q14702189 wd:Q991960 wd:Q43878 wd:Q19015547 wd:Q770236 wd:Q16422740 wd:Q512586 wd:Q87980870 wd:Q19888144 wd:Q1489904 wd:Q3341713 wd:Q18061822 wd:Q830479 wd:Q512153 wd:Q96176498 wd:Q3409323 wd:Q14647234}.
  ?item wdt:P31 wd:Q5.
  MINUS { ?item wdt:P27 [] }
  OPTIONAL { ?item wdt:P569 ?born. }
  OPTIONAL { ?item wdt:P106 ?occ. }
}
Try it!

Díjazottak állampolgárság nélkül edit 

SELECT ?Jnos ?JnosLabel ?szulet ?szlethely ?szlethelyLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?Jnos wdt:P31 wd:Q5.
  {?Jnos wdt:P166 wd:Q1301832} UNION {?Jnos wdt:P166 wd:Q1179841} UNION {?Jnos wdt:P166 wd:Q1466124} UNION {?Jnos wdt:P166 wd:Q1326184} UNION {?Jnos wdt:P166 wd:Q65218648} UNION {?Jnos wdt:P166 wd:Q55366244} UNION {?Jnos wdt:P166 wd:Q460426} UNION {?Jnos wdt:P166 wd:Q60313830} UNION {?Jnos wdt:P166 wd:Q20439665} UNION {?Jnos wdt:P166 wd:Q1296190}.
  MINUS { ?Jnos wdt:P27 [] }
  OPTIONAL { ?Jnos wdt:P569 ?szulet. }
  OPTIONAL { ?Jnos wdt:P19 ?szlethely. }
}
Try it!

vélhetően magyar állampolgárok szócikk nélkül edit

  • 2020. július 7-én 1390 tétel
  • 2022. július 14-én 2583 tétel
  • 2022. november 18-án 2459 tétel
  • 2023 március 22-én 2403 tétel
SELECT ?item ?itemLabel ?szulid ?szulh ?szulhLabel WHERE {
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
 ?item wdt:P31 wd:Q5.
 {?item wdt:P735 wd:Q16275893} UNION {?item wdt:P735 wd:Q15075907} UNION {?item wdt:P735 wd:Q15813127} UNION {?item wdt:P735 wd:Q15728196} UNION {?item wdt:P735 wd:Q17498051} UNION {?item wdt:P735 wd:Q18142236} UNION {?item wdt:P735 wd:Q956196} UNION {?item wdt:P735 wd:Q942625} UNION {?item wdt:P735 wd:Q1467671} UNION {?item wdt:P735 wd:Q3133296} UNION {?item wdt:P735 wd:Q19018108} UNION {?item wdt:P735 wd:Q15728988} UNION {?item wdt:P735 wd:Q1795260} UNION {?item wdt:P735 wd:Q18177147} UNION {?item wdt:P735 wd:Q2391854}.
 MINUS { ?item wdt:P27 _:b10. }
 FILTER(NOT EXISTS {
 ?wfr schema:about ?item;
 schema:isPartOf <https://hu.wikipedia.org/>.
 })
 OPTIONAL { ?item wdt:P569 ?szulid. }
 OPTIONAL { ?item wdt:P19 ?szulh. }
}
Try it!

magyar állampolgárok utónév nélkül edit

  • 2020. március 19-én 1673 db
  • 2020. május 4-én 1303 db
  • 2020. június 9-én 1235 db
  • 2020. október 27-én 1089
  • 2021. március 17-én 996 db
  • 2021. november 19-én 702 db
  • 2022. május 29-én 1103 db
  • 2022. július 14-én 1156 db
  • 2022. november 18-án 1249 db
  • 2023. január 4. 1171 db
  • 2023. március 22. 1085 db
SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5.
 {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} .
  MINUS { ?item wdt:P735 [] }
}
Try it!

csata dátummal edit 

SELECT ?Id_paradoxon ?Id_paradoxonLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?Id_paradoxon wdt:P585? "1849-06-01T00:00:00Z"^^xsd:dateTime.
  ?Id_paradoxon wdt:P31 wd:Q178561.
}
Try it!


utcák, utak, terek, körutak Budapesten edit 

SELECT ?item ?itemLabel WHERE {
  {?item wdt:P31 wd:Q79007 } UNION {  ?item wdt:P31 wd:Q174782} UNION { ?item wdt:P31 wd:Q34442} UNION { ?item wdt:P31 wd:510662}.
  ?item wdt:P131* wd:Q1781.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

nagyköveti beosztású magyar állampolgárok edit 

SELECT ?nagykovet ?nagykovetLabel ?beosztas ?beosztasLabel WHERE {
  ?nagykovet wdt:P39 ?beosztas .
  ?beosztas wdt:P279* wd:Q121998 .
  ?nagykovet wdt:P27 wd:Q28
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu" }
}
Try it!

múzeumigazgatók világszerte edit 

SELECT ?mzeumigazgat ?hely ?helyLabel ?mzeumigazgatLabel WHERE {
  ?mzeumigazgat p:P39 ?allitas .
  ?allitas ps:P39 ?beosztas .
  OPTIONAL { ?allitas pq:P642 ?hely }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu,en". }
  ?mzeumigazgat wdt:P39 wd:Q22132694.
}
Try it!

díjak a díszdoktor kivételével edit 

SELECT ?dj ?djLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?dj wdt:P31 wd:Q618779.
  ?dj wdt:P17 wd:Q28.
FILTER NOT EXISTS{ ?dj wdt:P279 wd:Q11415564 }  
}
Try it!

Nagykövetek edit

  • 2020. szeptember 25-én 2075
SELECT ?nagykovet ?nagykovetLabel ?beosztas ?beosztasLabel ?hely ?helyLabel WHERE {
  ?nagykovet p:P39 ?allitas .
  ?allitas ps:P39 ?beosztas .
  ?beosztas wdt:P279* wd:Q121998 .
  ?nagykovet wdt:P27 wd:Q28 .
  OPTIONAL { ?allitas pq:P131 ?hely }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu" }
}
Try it!

nagyköveti címek országjelölés nélkül edit 

SELECT ?item ?itemLabel ?country ?countryLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item (wdt:P31*) wd:Q29918328.
  OPTIONAL { ?item wdt:P17 ?country.} 
MINUS { ?item wdt:P17 [] }
}
Try it!

Nagyköveti címek szervezet nélkül edit 

SELECT ?item ?itemLabel ?country ?countryLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  ?item wdt:P31* wd:Q29918328 .
  OPTIONAL { ?item wdt:P17 ?country. }
  MINUS { ?item wdt:P2389 _:b2. }
}
Try it!

konzulátusok és főkonzulátusok a világban edit

Lásd: Wikidata:Wikivoyage/Lists/Consulates

a lekérdezés kódja 
SELECT ?item ?itemLabel ?orszg ?orszgLabel ?kozig ?kozigLabel ?kezel ?kezelLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,hu". }
  { ?item wdt:P31 wd:Q372690. }
  UNION
  { ?item wdt:P31 wd:Q7843791. }
  OPTIONAL { ?item wdt:P17 ?orszg. }
  OPTIONAL { ?item wdt:P131 ?kozig. }
  OPTIONAL { ?item wdt:P137 ?kezel. }
}
Try it!

Minden nagykövetség a világban edit

Ez az oldal felsorolja valamennyit, de nagyon ritkán frissül, és csak 4402-t jelenít meg a 6676-ból. 

SELECT ?item ?itemLabel ?country ?countryLabel ?operator ?operatorLabel ?erv ?ervLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P31 wd:Q3917681.
  OPTIONAL { ?item wdt:P17 ?country. }
  OPTIONAL { ?item wdt:P137 ?operator. }
  OPTIONAL { ?item wdt:P2388 ?erv. }
}
Try it!


kik születtek egy bizonyos napon? edit 

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P569 "1900-01-02T00:00:00Z"^^xsd:dateTime.
}
Try it!

egy év szülöttei edit 

SELECT ?ember ?emberLabel ?szul WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?ember wdt:P31 wd:Q5;
    wdt:P569 ?birth.
  FILTER((?birth >= "1970-01-01"^^xsd:dateTime) && (?birth < "1971-01-01"^^xsd:dateTime))
  OPTIONAL { ?ember wdt:P569 ?szul. }
}
Try it!

egy szakma egy évszázadban élt képviselői edit

A példában a festőmévészek szerepelnek, de csak azok, akiknek van magyar szócikkük. 

SELECT ?item ?itemLabel ?birth ?article WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    ?item wdt:P31 wd:Q5.
 {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}.
  ?item wdt:P106 wd:Q1028181.
  ?item wdt:P569 ?birth;            
    filter (?birth > "1880-01-01"^^xsd:dateTime && ?birth < "1980-01-01"^^xsd:dateTime)
	?article schema:about ?item ;
	         schema:isPartOf <https://hu.wikipedia.org/> .
    
}
Try it!

kétoldalú kapcsolatok edit 

SELECT ?kapcs ?kapcsLabel ?orsz ?orszLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,hu". }
  ?kapcs wdt:P31 wd:Q15221623.
  OPTIONAL { ?kapcs wdt:P17 ?orsz. }
  MINUS { ?kapcs wdt:P17 [] }
}
Try it!

Magyarország összes minisztériuma (a megszűntek is) edit 

SELECT ?item ?itemLabel ?alap ?megsz ?elod ?elodLabel ?utod ?utodLabel ?poz ?pozLabel ?vezet ?vezetLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,hu". }
  ?item wdt:P31 wd:Q52063153.
  OPTIONAL { ?item wdt:P571 ?alap. }
  OPTIONAL { ?item wdt:P576 ?megsz. }
  OPTIONAL { ?item wdt:P1365 ?elod. }
#  OPTIONAL { ?item wdt:P1037 ?vezet. }
  OPTIONAL { ?item wdt:P1366 ?utod. }
  OPTIONAL { ?item wdt:P2388 ?poz. }
}
Try it!

Főleg nyelvi és alapítás/megszűnés ellenőrzéshez ezt ajánlom: 

SELECT ?item ?itemLabel ?itemDescription ?alap ?megsz ?poz ?pozLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  ?item wdt:P31 wd:Q52063153.
  OPTIONAL { ?item wdt:P571 ?alap. }
  OPTIONAL { ?item wdt:P576 ?megsz. }
  OPTIONAL { ?item wdt:P2388 ?poz. }
}
Try it!

halálozási dátum nélkül edit

Lásd: hu:Wikipédia:Magyarország-műhely/Több mint 110 éves magyarok

a lekérdezés kódja 
SELECT ?item ?itemLabel ?article ?szul WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P27 wd:Q28;
    wdt:P569 ?birth.
  MINUS { ?item wdt:P570 []. }
  FILTER(?birth <= "1900-01-01"^^xsd:dateTime)
  FILTER(EXISTS {
    ?article schema:about ?item;
      schema:isPartOf <https://hu.wikipedia.org/>.
  })
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu,en". }
  OPTIONAL { ?item wdt:P569 ?szul. }
}
Try it!

magyarul beszélők állampolgársága edit

számláló arról, hogy akiknél a beszélt nyelvek közül szerepel a Hungarian (Q9067), milyen állampolgárságúak?

a lekérdezés kódja 
SELECT ?country ?countryLabel ?count WHERE { 
	{
		select ?country (COUNT(*) AS ?count) where {
			?item wdt:P1412 wd:Q9067 . 
			?item wdt:P31 wd:Q5 .
			?item wdt:P27 ?country .
		} group by ?country 
	}
	SERVICE wikibase:label {            # ... include the labels
		bd:serviceParam wikibase:language "hu" .
	}
} ORDER BY DESC (?count)
Try it!

Magyar anyanyelvűek beszélt nyelvei edit

Akiknél az native language (P103) Hungarian (Q9067), milyen más nyelvek vannak megadva mint languages spoken, written or signed (P1412)? 

SELECT ?country ?countryLabel ?count WHERE { 
	{
		select ?country (COUNT(*) AS ?count) where {
			?item wdt:P103 wd:Q9067 . 
			?item wdt:P31 wd:Q5 .
			?item wdt:P1412 ?country .
		} group by ?country 
	}
	SERVICE wikibase:label {            # ... include the labels
		bd:serviceParam wikibase:language "hu" .
	}
} ORDER BY DESC (?count)
Try it!

Hiányzó anyanyelvi bejegyzés magyar állampolgárokhoz edit

Olyan magyar állampolgárságúak, ahol meg van adva languages spoken, written or signed (P1412), de nincs megadva native language (P103).

  • 2021. június 11-én beszélt nyelvi tételenként 12610
SELECT ?item ?itemLabel ?nyelv ?nyelvLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  { ?item wdt:P27 wd:Q28. }  UNION  { ?item wdt:P27 wd:Q171150. }  UNION  { ?item wdt:P27 wd:Q655621. }
  ?item wdt:P1412 _:b7.
  MINUS { ?item wdt:P103 _:b8. }
  OPTIONAL { ?item wdt:P1412 ?nyelv. }
}
Try it!

Magyar diplomaták beszélt nyelv nélkül edit

  • 2022. szeptember 12-én 264
SELECT ?item ?itemLabel ?born WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P106 wd:Q193391.
  { ?item wdt:P27 wd:Q28. }  UNION  { ?item wdt:P27 wd:Q171150. }  UNION  { ?item wdt:P27 wd:Q655621. }
  MINUS { ?item wdt:P1412 _:b1. }
  OPTIONAL { ?item wdt:P569 ?born. }
}
Try it!

Magyar diplomaták beszélt nyelvei edit 

SELECT ?country ?countryLabel ?count WHERE { 
	{
		select ?country (COUNT(*) AS ?count) where {
			?item wdt:P106 wd:Q193391 . 
			{ ?item wdt:P27 wd:Q28. }  UNION  { ?item wdt:P27 wd:Q171150. }  UNION  { ?item wdt:P27 wd:Q655621. }
			?item wdt:P1412 ?country .
		} group by ?country 
	}
	SERVICE wikibase:label {            # ... include the labels
		bd:serviceParam wikibase:language "hu" .
	}
} ORDER BY DESC (?count)
Try it!

Nyers utónévstatisztika edit

Nyers lista azokról az utónevekről, melyek magyar állampolgárú személyek adatlapjain fel vannak tüntetve

  • 2020. július 18-án 1330
SELECT ?country ?countryLabel ?count WHERE { 
	{
		select ?country (COUNT(*) AS ?count) where {
			{?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} . 
			?item wdt:P31 wd:Q5 .
			?item wdt:P735 ?country .
		} group by ?country 
	}
	SERVICE wikibase:label {            # ... include the labels
		bd:serviceParam wikibase:language "hu" .
	}
} ORDER BY DESC (?count)
Try it!

Szűrt utónévstatisztika edit

Csak a magyar utónveket számolja össze

  • 2020. július 18-án 1173
  • 2021. május 6. 1317
SELECT ?name ?nameLabel ?count WHERE { 
	{
		SELECT ?name (COUNT(*) AS ?count) WHERE {
			{?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} .
			?item wdt:P31 wd:Q5 .
			?item p:P735 ?nameStatement .
			?nameStatement ps:P735 ?name .
			OPTIONAL { ?nameStatement pq:P407 ?nameLang } .
			FILTER(COALESCE(?nameLang, wd:Q9067) = wd:Q9067) .
		} GROUP BY ?name
	}
	SERVICE wikibase:label {            # ... include the labels
		bd:serviceParam wikibase:language "hu" .
	}
} ORDER BY DESC (?count)
Try it!

Segédlekérdezés az idegen hangzású nevekhez edit 

SELECT ?item ?itemLabel ?langLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  { ?item wdt:P27 wd:Q28. }  UNION  { ?item wdt:P27 wd:Q171150. }  UNION  { ?item wdt:P27 wd:Q655621. }
  ?item wdt:P735 wd:Q11122389;
    p:P735 ?statement.
  ?statement ps:P735 ?nyelv.
  OPTIONAL { ?statement pq:P407 ?lang. }
}
Try it!

Új MNN azonosítóval rendelkezők edit

Régi MNN azonosítók:

  • 2020. február 20-án 136 db
  • 2020. március 18-án 653 db
  • 2020. június 14-én 1284 db
  • 2020. október 22-én 2566 db
  • 2021. január 11-én 3726 db
  • 2021. november 15-én 7410
  • 2022. július 15-én 8616
  • 2023. április 5-én 8842

Az új MNN azonosítók:

  • 2023. április 5-én 405
  • 2023. július 7-én: 1333
  • 2023. november 2-án: 5692
SELECT ?item ?itemLabel ?allamp ?allampLabel ?abcd WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
  wdt:P11621 ?y_22.
  OPTIONAL { ?item wdt:P27 ?allamp. }
  OPTIONAL { ?item wdt:P11621 ?abcd. }
}
Try it!

Régi MNN azonosítók új nélkül edit 

SELECT ?item ?itemLabel ?itemDescription ?abcd ?mel ?mma ?pim WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
    wdt:P6988 ?y_22.
  MINUS { ?item wdt:P11621 _:b9. }
  OPTIONAL { ?item wdt:P6988 ?abcd. }
  OPTIONAL { ?item wdt:P8998 ?mel. }
  OPTIONAL { ?item wdt:P11624 ?mma. }
  OPTIONAL { ?item wdt:P3973 ?pim. }
}
Try it!

MÉL azonosítóval rendelkezők edit

Kontroll lekérdezés a PIM-azonosító nélküli elemekről az állampolgárság és a Hungarian National Namespace person ID (new) (P11621) feltüntetésével

  • 2020. december 30-án 1066 tétel
  • 2021. január 25-án 4574 tétel
  • 2021. március 15-én 4952 tétel
  • 2021. június 26-án 4871 tétel
  • 2021. szeptember 7-én 4264 tétel
  • 2022. március 24-én 3799 tétel
  • 2022. július 15-én 3388 tétel
  • 2022. november 18: 2960 tétel
  • 2023. április 2-án: 2886 tétel
  • 2023. augusztus 10-én 2669 tétel.
  • 2023. szeptember 13-án 2363 tétel.
SELECT ?item ?itemLabel ?allamp ?allampLabel ?abcd WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
  wdt:P8998 ?y_22.
  MINUS { ?item wdt:P3973 [] }
  OPTIONAL { ?item wdt:P27 ?allamp. }
  OPTIONAL { ?item wdt:P11621 ?abcd. }
}
Try it!

MÉL azonosítóval rendelkezők születési hely, állampolgárság és PIM-azonosító nélkül edit 

SELECT ?ember ?emberLabel ?allamp ?allampLabel ?abcd WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?ember wdt:P31 wd:Q5;
  wdt:P8998 ?y_22.
  MINUS { ?ember wdt:P27 [] }
  MINUS { ?ember wdt:P19 [] }
  MINUS { ?ember wdt:P3973 [] }
}
Try it!

Magyarország összes települése MNN azonosítóval edit

A közigazgatási hovatartozással és a hivatalos honlappal: 

SELECT ?item ?itemLabel ?mnnf ?kozig ?kozigLabel ?web ?webLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  { ?item wdt:P31 wd:Q2590631. }  UNION  { ?item wdt:P31 wd:Q13218690. } UNION { ?item wdt:P31 wd:Q851110. }
  OPTIONAL { ?item wdt:P6987 ?mnnf. }
#  OPTIONAL { ?item wdt:P131 ?kozig. }
#  OPTIONAL { ?item wdt:P856 ?web. }
}
Try it!

Magyarország városai a kapcsolódó kategóriáikkal edit 

SELECT ?item ?itemLabel ?fo ?foLabel ?hc ?hcLabel ?kapcs ?kapcsLabel ?szulet ?szuletLabel ?elhunyt ?elhunytLabel ?nyug ?nyugLabel ?filmek ?filmekLabel ?map ?mapLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q13218690.
  OPTIONAL { ?item wdt:P6987 ?mnnf. }
  OPTIONAL { ?item wdt:P910 ?fo. }
  OPTIONAL { ?item wdt:P1792 ?kapcs. }
  OPTIONAL { ?item wdt:P1464 ?szulet. }
  OPTIONAL { ?item wdt:P1465 ?elhunyt. }
  OPTIONAL { ?item wdt:P1791 ?nyug. }
  OPTIONAL { ?item wdt:P1740 ?filmek. }
  OPTIONAL { ?item wdt:P7867 ?map. }
  OPTIONAL { ?item wdt:P10280 ?hc. }
}
Try it!

Új MNNF nélküli települések edit

A Hungarian National Namespace place ID (old) (P6987)-t nem tartalmazó magyar települési adatlapok 

SELECT ?item ?itemLabel ?mnnf ?oldmnn WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  { ?item wdt:P31 wd:Q2590631. }  UNION  { ?item wdt:P31 wd:Q13218690. }
  MINUS { ?item wdt:P11620 [] }
  OPTIONAL { ?item wdt:P6987 ?oldmnn. }
}
Try it!

Csak magyarországi községek: https://w.wiki/7swV

Településrészek, anyaközségek, MNNF azonosítók edit 

SELECT ?item ?itemLabel ?kezd ?eze ?ezeLabel ?mnn ?abcd WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q2983893;
  wdt:P17 wd:Q28;
  p:P31 ?statement.
  ?statement ps:P31 ?beosztas.
  OPTIONAL { ?statement pq:P580 ?kezd. }
  OPTIONAL { ?statement pq:P642 ?eze. }
  OPTIONAL { ?item wdt:P6987 ?mnn. }
  OPTIONAL { ?item wdt:P11620 ?abcd. }
}
Try it!

Települések honlappal és annak nyelvével edit 

SELECT ?item ?lang ?langLabel ?website WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }  
  { ?item wdt:P31 wd:Q2590631 }  UNION  { ?item wdt:P31 wd:Q13218690 }.
  ?item p:P856 ?statement.
  ?statement ps:P856 ?website.
  OPTIONAL { ?statement pq:P407 ?lang. }
}
Try it!

Városok az alapítás dátumával és annak forrásával edit 

SELECT distinct ?item ?itemLabel ?start ?ref ?refLabel  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item p:P31 ?statement .
  ?statement ps:P31 wd:Q13218690.
  OPTIONAL { ?statement pq:P580 ?start. }
  OPTIONAL { ?statement prov:wasDerivedFrom/pr:P248 ?ref . }                        
}
Try it!

Wikidata-lista élettelen dolgokról edit

Köztük van sok település, földrajzi entitás is, meg minden egyéb

  • 2020. november 1. 7292 tétel
  • 2022. november 27. 8078 tétel
SELECT DISTINCT ?item ?itemLabel ?itemDescription (COUNT(?sitelink) AS ?sitelinks) WHERE {
    ?item wdt:P17 wd:Q28 .
    ?sitelink schema:about ?item .  
    MINUS { ?item wdt:P31 wd:Q30612 }
    FILTER NOT EXISTS { ?huwiki schema:about ?item . ?huwiki schema:inLanguage "hu" } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY ?sitelinks
Try it!

PIM-azonosítóval rendelkezők állampolgárság nélkül edit

  • 2020. március 9-én 952 tétel
  • 2020. június 19-én 426 tétel
  • 2021. október 15-én 473 tétel
  • 2022. november 18-án 587 tétel
SELECT ?pim ?pimLabel ?szul ?foglalkozs ?foglalkozsLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?pim wdt:P31 wd:Q5;
    wdt:P3973 ?y_22.
  MINUS { ?pim wdt:P27 _:b2. }
  OPTIONAL { ?pim wdt:P569 ?szul. }
  OPTIONAL { ?pim wdt:P19 ?foglalkozs. }
}
Try it!

PIM-azonosítóval rendelkezők magyar szócikk nélkül edit

Lásd: hu:Szerkesztő:Palotabarát/Segédletek/PIM-azonosítóval rendelkezők névsora

a lekérdezés kódja 
SELECT DISTINCT ?pim ?pimLabel ?szul ?foglalkozs ?foglalkozsLabel ?citizen ?citizenLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?pim wdt:P31 wd:Q5;
    wdt:P3973 ?y_22.
  FILTER(NOT EXISTS {
    ?wfr schema:about ?pim;
      schema:isPartOf <https://hu.wikipedia.org/>.
  })
  OPTIONAL { ?pim wdt:P27 ?citizen. }
  OPTIONAL { ?pim wdt:P19 ?foglalkozs. }
  OPTIONAL { ?pim wdt:P569 ?szul. }
}
Try it!

PIM-azonosítóval rendelkezők születési hely nélkül edit

a lekérdezés feltünteti az NSZL name authority ID (P3133) tulajdonságot is (ha van) 

SELECT ?item ?itemLabel ?oszk ?szulhely ?szulhelyLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
    wdt:P3973 ?y_22.
  MINUS { ?item wdt:P19 _:b2. }
  OPTIONAL { ?item wdt:P3133 ?oszk. }
  OPTIONAL { ?item wdt:P19 ?szulhely. }
}
Try it!

Hibás adat lekérdezése polgármesterekhez... edit

Azok a magyar állampolgárságú személyek, akiknél a beosztásnál nem a mayor (Q2922332), hanem a mayor (Q30185) lett megadva. 

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P39 wd:Q30185.
 {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} .
}
Try it!


...és országgyűlési képviselőkhöz edit

Azok a magyar állampolgárságú személyek, akiknél a beosztásnál nem a member of the National Assembly of Hungary (Q17590876), hanem a member of parliament (Q486839) lett megadva. 

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P39 wd:Q486839.
 {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} .
}
Try it!

Az összes magyar állampolgárságú személy edit

Kilistázza a magyarokat 

SELECT ?item ?itemLabel ?szul ?szulhely ?szulhelyLabel ?csal ?csalLabel ?pim WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P31 wd:Q5;
  {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} .
  OPTIONAL { ?item wdt:P569 ?szul. }
  OPTIONAL { ?item wdt:P19 ?szulhely. }
  OPTIONAL { ?item wdt:P734 ?csal. }
  OPTIONAL { ?item wdt:P3973 ?pim. }
}
Try it!

Ez pedig csak összeszámolja őket 

SELECT (COUNT(DISTINCT ?subject) AS ?subjcount ) 
WHERE
{
     ?subject wdt:P31 wd:Q5 .
    {?subject wdt:P27 wd:Q28} UNION {?subject wdt:P27 wd:Q171150}  UNION {?subject wdt:P27 wd:Q655621} 
}
Try it!

Itt pedig csak a ma is élő személyeket számolja össze (akiknél nincs megadva date of death (P570)) 

SELECT (COUNT(DISTINCT ?ember) AS ?embcount ) 
WHERE {
  ?ember wdt:P31 wd:Q5;
         wdt:P27 wd:Q28.
FILTER NOT EXISTS{ ?ember wdt:P570 ?date }    
}
Try it!

Magyarországi településen született személyek állampolgárság nélkül edit

  • 2021. november 8-án 4638 tétel
  • 2022. március 30-án 4290 tétel
  • 2022. május 12-én 4115 tétel
  • 2023. január 12-én 1079 tétel
#en:Persons born in a Hungarian settlement without citizenship
#hu:magyarországi településen született személyek állampolgárság nélkül
SELECT ?item ?itemLabel ?citizen ?citizenLabel WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P19 ?citizen.
  { ?citizen wdt:P31* wd:Q13218690 . } UNION { ?citizen wdt:P31* wd:Q2590631 . } 
  MINUS { ?item wdt:P27 [] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu" }
}
Try it!

Magyar nyelvterületen is használt utónév viselője állampolgárság nélkül edit

Nagy hátránya a lekérdezésnek, hogy a más nyelvterületen is használt utónevek esetén (pl.: Anna (Q666578) stb.) valamennyi állampolgárság nélküli személyt kilistázza, azokat is, akiknél a magyar állampolgárság fel sem merül.

  • 2021. november 8-án 47846 tétel
SELECT ?item ?itemLabel ?name ?nameLabel WHERE {
  ?item wdt:P735 ?name.
   ?name wdt:P407 wd:Q9067 . 
  MINUS { ?item wdt:P27 [] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu" }
}
Try it!

Magyar állampolgárok, akiknek csak a román Wikipédiában van cikkük edit

Olyan személyek, akiknél az állampolgárság Hungary (Q28), Kingdom of Hungary (Q171150) vagy Principality of Transylvania (Q655621), és a magyar Wikipédiában nincs, de a román Wikipédiában van cikkük. A román Wikipédia magyar interwiki nélküli magyar vonatkozású cikkei listához hasonló, de csak személyeket mutat, és közülük is hiányoznak a határon túli (nem magyar állampolgárságú) emberek. A lekérdezés elkészítésekor 58 tétel volt benne. 

SELECT DISTINCT ?item ?itemLabel ?article ?szul ?citizen ?citizenLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} .
	?article schema:about ?item ;
	         schema:isPartOf <https://ro.wikipedia.org/> .  
  FILTER(NOT EXISTS {
    ?wfr schema:about ?item;
      schema:isPartOf <https://hu.wikipedia.org/>.
  })
  OPTIONAL { ?item wdt:P569 ?szul. }
  OPTIONAL { ?item wdt:P19 ?citizen. }
}
Try it!

Magyar történészek születési hely alapján térképen ábrázolva edit 

#defaultView:Map
SELECT ?arthistorianLabel ?coordinates WHERE {
  ?arthistorian wdt:P31 wd:Q5;
    wdt:P27 wd:Q28;
    wdt:P19 ?birthPlace;
    wdt:P106 wd:Q201788.
  ?birthPlace wdt:P625 ?coordinates.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

MGP-azonosítóval rendelkező matematikusok és fizikusok edit

Azok a matematikusok és fizikusok, akik rendelkeznek Mathematics Genealogy Project ID (P549) tulajdonsággal, az alábbi egyetemek valamelyikén tanultak: BME, ELTE, debreceni, pécsi és szegedi, ám nincs feltüntetve country of citizenship (P27), tehát vélelmezhető, hogy adathiányosak.

  • 2020. december 5-én 346-an voltak.
  • 2021. március 9.: 298.
  • 2022. november: 266
SELECT ?item ?itemLabel ?pim ?mtmt WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P549 ?y_22
  {?item wdt:P69 wd:Q390287} UNION {?item wdt:P69 wd:Q903092} UNION {?item wdt:P69 wd:Q369839} UNION {?item wdt:P69 wd:Q1187444} UNION {?item wdt:P69 wd:Q1186843}.
  MINUS { ?item wdt:P27 [] }
  OPTIONAL { ?item wdt:P3973 ?pim. }
  OPTIONAL { ?item wdt:P2492 ?mtmt. }  
}
Try it!

Személyek extrém hiányos Wikidata elemei edit

lásd még: Petscan

  • Egy tulajdonság szerepelt benne:
  • 2020 december 11.: kb. 200
  • 2021. március 20.: 122
  • 2021. november 24.: 1
  • Két tulajdonság szerepelt benne:
  • 2021 november: kb. 160
  • 2022 május: 84
  • 2022 november: 38
SELECT ?item ?article ?title
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
    ?item wdt:P31 wd:Q5.
	?article schema:about ?item ;
	         schema:isPartOf <https://hu.wikipedia.org/> .
	?article schema:name ?title .
	?item wikibase:sitelinks 1;
	      wikibase:statements 2
}
Try it!

Szűkítés a magyar Wikipédia szócikkeiben edit

Ez a lekérdezés bármit leszűkít azon elemek közül, amelyekhez csatolva van egy szócikk a magyar Wikipédiában. A példalekérdezésben a stonemason (Q328325) foglalkozású személyekre szűkít. 

SELECT DISTINCT ?item ?itemLabel ?article ?szul ?citizen ?citizenLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
# az itt következő sort kell átírni, ha szűkíteni szeretnél valamire 
  ?item wdt:P106 wd:Q328325.
# ami ezután jön, az a magyar Wikipédia szócikkekre való szűkítés
	?article schema:about ?item ;
	         schema:isPartOf <https://hu.wikipedia.org/> .  
# itt még kiír ezt-azt
  OPTIONAL { ?item wdt:P569 ?szul. }
  OPTIONAL { ?item wdt:P19 ?citizen. }
}
Try it!

Címkék és leírások lekérdezése edit 

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
  {?item wdt:P27 wd:Q28} UNION {?item wdt:P27 wd:Q171150}  UNION {?item wdt:P27 wd:Q655621} 
#  wdt:P8998 ?y_22.  
#   ?article schema:about ?item ;
#	        schema:isPartOf <https://hu.wikipedia.org/> .          
#  MINUS { ?item rdfs:label ?hulabel FILTER ( lang(?hulabel) = "eo" ) }
  MINUS { ?item schema:description ?hudescription FILTER ( lang(?hudescription) = "ru" ) }  
}
Try it!

Conor SR azonosítóval rendelkezők szerb leírás nélkül edit

  • 2022. március 24. 1307
  • 2022. szeptember 21. 1298
  • 2022. november 16.: 1285, bg: 254
SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
  wdt:P3973 ?y_23;
  wdt:P8851 ?y_22.  
  MINUS { ?item rdfs:label ?hulabel FILTER ( lang(?hulabel) = "sr" ) }
}
Try it!

Alma maternél feltüntetett tudományos fokozat kiíratása edit 

SELECT ?item ?itemLabel ?egyetem ?egyetemLabel ?sc ?scLabel ?dat WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
  wdt:P106 wd:Q593644.        
  ?item p:P69 ?statement.
  ?statement ps:P69 ?egyetem.
  OPTIONAL { ?statement pq:P512 ?sc. }
  OPTIONAL { ?statement pq:P582 ?dat. }  
}
Try it!

Végzettség időpontja nélküli elemek egyetemre szűkítve edit

A lekérdezés az Eötvös Loránd University (Q390287) végzettjei között keres, az állampolgárság feltüntetésével (hiányának jelzésével). A több alma mater jelzésűek többször szerepelnek.

  • állampolgárság nélkül 2022. április 28-án 769 találat (állampolgársággal 896)
SELECT ?item ?itemLabel ?egyetem ?egyetemLabel ?dat ?cit ?citLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
    wdt:P69 wd:Q390287;
    p:P69 ?statement.
  ?statement ps:P69 ?egyetem.
  MINUS { ?statement pq:P582 [] }  
  OPTIONAL { ?statement pq:P582 ?dat. }
  OPTIONAL { ?item wdt:P27 ?cit. }
}
Try it!

Az ELTE 1930 előtt született végzőseinek alma mater adatai edit 

SELECT DISTINCT ?item ?itemLabel ?dobyear ?dodyear ?datyear ?sc ?scLabel WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu". }
  ?item wdt:P69 wd:Q390287; wdt:P31 wd:Q5.
  ?item p:P69 ?statement.
  ?statement ps:P69 ?egyetem.
  OPTIONAL { ?statement pq:P582 ?dat. } 
      BIND(YEAR(?dat) AS ?datyear) .
  OPTIONAL { ?statement pq:P812 ?sc. } 
  OPTIONAL { ?item wdt:P569 ?dob .
    BIND(YEAR(?dob) AS ?dobyear) .
  }
  OPTIONAL {
    ?item wdt:P570 ?dod .
    BIND(YEAR(?dod) AS ?dodyear) .
  }
  FILTER(!BOUND(?dobyear)|| ?dobyear < 1930) .
}
Try it!

Szakmák hiányzó leírásssal edit 

SELECT ?item ?itemLabel ?field ?fieldLabel ?linkcount WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P31 wd:Q28640.
  ?item wikibase:sitelinks ?linkcount .
  MINUS {
    ?item rdfs:label ?hulabel.
    FILTER((LANG(?hulabel)) = "hu")
  }
  OPTIONAL { ?item wdt:P425 ?field. }
}
Try it!

Ezé edit

Azok a magyarok, akiknek a beosztásában of (P642) minősítő van, amit le kell cserélni.

  • 2023. február 10.: 2239
  • 2023. május 12. 2369
SELECT ?item ?itemLabel ?position ?positionLabel ?sc ?scLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  VALUES ?citizenship { wd:Q28 wd:Q171150 wd:Q655621}.
  ?item wdt:P31 wd:Q5.
  ?item wdt:P27 ?citizenship.
  ?item p:P39 ?statement.
  ?statement ps:P39 ?position.
  ?statement pq:P642 ?sc.
}
Try it!

Főispánok edit

Azok a főispánok, akiknél a position held (P39) tulajdonságnál a konkrét vármegyére vonatkozó elemmel van megadva a pozíció. (Lásd még a Listeria által készített listá.) 

SELECT ?item ?itemLabel ?prize ?prizeLabel ?prizeDate ?offDate WHERE {
  ?item p:P39 ?stmt.
  ?stmt ps:P39 ?prize.
  ?prize wdt:P279 wd:Q29865383.
  ?stmt pq:P580 ?prizeDate.
  ?stmt pq:P582 ?offDate.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu". }
}
Try it!

Jelöltség edit

A jelölő szervezettel és a listában elfoglalt hely sorszámával (egy tulajdonság több hasonló minősítője közül csak az érintettet választja ki: 2019 European Parliament election in Hungary (Q56192576)) 

SELECT ?item ?itemLabel ?sorsz ?jelolLabel ?abcd WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q5;
    wdt:P3602 wd:Q56192576;
    p:P3602 ?statement.
  ?statement ps:P3602 wd:Q56192576.
  OPTIONAL { ?statement pq:P1545 ?sorsz. }
  OPTIONAL { ?statement pq:P1268 ?jelol. }
  OPTIONAL { ?item wdt:P11621 ?abcd. }
}
Try it!

WCE edit

Minden más edit

Muraszombat képigények

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Pallor/Lekérdezés&oldid=2145415248"