Wikidata

Wikidata:Sistema Cultura/Raffinamento

< Wikidata:Sistema Cultura

Alcuni suggerimenti per gli esercizi

Raffinamento manuale da elenchi della regione edit

Istanza edit

NB: Usare le tipologie presenti nel Thesaurus della Biblioteca nazionale. Prima discuterne con Regione

Doppia istanza edit

  • sgarbugliare gli item che sono sia biblioteche che archivi. Potrebbe ancora andare bene per le "biblioteche di archivi"

Coordinate edit 

#Entità in Toscana con import dal Sistema Cultura e senza coordinate
SELECT ?i ?iLabel ?iDescription ?inst ?instLabel
WHERE {
  ?i p:P17 [ps:P17 ?c ; prov:wasDerivedFrom [pr:P248 wd:Q80199870] ] .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  #?inst wdt:P625 ?instcoord .
  MINUS { ?i wdt:P625 ?coord . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
GROUP BY ?i ?iLabel ?iDescription ?inst ?instLabel
Try it!

Indirizzi edit

Date edit

  • verificare con i dati originali che le date siano corrette e modificare a mano le poche last update (P5017) diverse dalla data di creazione.

Inclusione fra elementi edit

  • negli elementi "sevedesi" di archivi comunali riportati con denominazione della biblioteca, migliorare label in inglese e inserire informazione di part of (P361) per interrelazionarli

Frazioni edit

  • Verifica a mano elementi delle frazioni e delle ubicazioni nella colonna "LOCALITA"
  • Nel caso dei musei la colonna contiene erroneamente palazzi (UBICAZIONI) e pure un numero di telefono, quindi è sicuro che va fatta a mano.

Edifici edit

  • Si trovano nella colonna "UBICAZIONE"
    • Villa Smilea Q55674286 piccole modifiche.
    • Palazzo comunale di Bibbiena
    • Palazzo Dragomanni di Castiglion Fiorentino Q77975937 creato ex novo
    • Palazzo Casali di Cortona Q56669140
    • Palazzo Vitellino. Lg.no Pacinotti 44 (probabilmente porzione di Palazzo Vitali)
    • Palazzo Piccolomini di Siena
    • ...

Sito web edit

  • Può essere inserito ma va sempre verificato. Quelli degli archivi sono spesso rotti, quelli del comune e alcuni degli archivi a volte rimandano a siti di ordine generale. Quindi vanno inseriti a mano ai corsi con proprietà official website (P856), si faccia attenzione che deve essere "ufficiale" quindi meglio non usare nessun collegamento che non sia chiaramente riconducibile all'ente in questione (penso al caso di alcuni enti privati, che magari si appoggiano a terzi come talvolta capita nel volontariato).
  • nei musei c'è SITOWEB e PAGINAWEB, non facciamo distinzione, se ci sono entrambi deviderà lo studente se conosce l'istituzione.

Numero Fax edit

  • in teoria potevamo metterlo essendo uno solo, la proprietà è fax number (P2900), tuttavia è scontato che molti siano dismessi quindi è relegato a lavoro manuale da parte di chi è dell'ente.

Telefono edit

  • Il primo contatto telefonico è inserito, il secondo può essere inserito a mano ai corsi
  • verificare mancanze di trattino con questa query
#Entità in Toscana con import dal Sistema Cultura e più di un numero di telefono
SELECT ?i ?iLabel ?iDescription ?inst ?instLabel (count(?tel) AS ?num)
WHERE {
  ?i p:P17 [ps:P17 ?c ; prov:wasDerivedFrom [pr:P248 wd:Q80199870] ] .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  #?inst wdt:P625 ?instcoord .
  ?i wdt:P1329 ?tel .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
GROUP BY ?i ?iLabel ?iDescription ?inst ?instLabel
HAVING(?num > 1)
Try it!

Sezione distaccata degli archivi edit

  • L'archivio di Pescia è sezione distaccata dell'Archivio di Pistoia vedi qui

Data di chiusura edit

Lavori tramite query edit

Unioni archivi edit

Nel gennaio 2020 sono stati importati da Archives Portal Europe (Q15427386) 507 archivi in Tuscany (Q1273), dotati di country (P17), located in the administrative territorial entity (P131), street address (P6375) (spesso più imprecisa del Sistema Cultura, es. manca il numero civico), official website (P856) (sito del SAN) e Archives Portal Europe ID (P7764); manca coordinate location (P625). L'etichetta non coincide con quella del Sistema Cultura, quindi nella gran parte dei casi sarà necessaria un'unione manuale. --Epìdosis 17:59, 13 February 2020 (UTC)[reply] 

#Archivi in Toscana - solo import PEA
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel ?instcoord ?pea
WHERE {
  ?i wdt:P31 wd:Q166118 .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  ?i wdt:P7764 ?pea .
  OPTIONAL { ?i wdt:P625 ?coord . }
  BIND(IF(BOUND(?coord),'archiv','comune') AS ?layer)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
Try it!

In molti di questi casi i pochi duplicati (indirizzi) sembrano fontati con uso di "reference url", vanno quindi convertiti in un formato più corretto ove possibile e aggiunti come seconda reference prima di rimuoverli. esempio

Query per gli archivi potenzialmente duplicati: 

#Archivi in Toscana - tutti
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel ?instcoord ?indir ?pea
WHERE {
  ?i wdt:P31 wd:Q166118 .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  #?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P6375 ?indir . }
  OPTIONAL { ?i wdt:P7764 ?pea . }
  OPTIONAL { ?i wdt:P625 ?coord . }
  BIND(IF(BOUND(?coord),'archiv','comune') AS ?layer)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?instLabel
Try it!

Query per gli archivi con più di un indirizzo: 

#Archivi in Toscana con più di un indirizzo
SELECT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel (count(?ind) AS ?num) ?pea
WHERE {
  ?i wdt:P31 wd:Q166118 .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  #?inst wdt:P625 ?instcoord .
  ?i wdt:P7764 ?pea .
  OPTIONAL { ?i wdt:P6375 ?ind . }
  OPTIONAL { ?i wdt:P625 ?coord . }
  BIND(IF(BOUND(?coord),'archiv','comune') AS ?layer)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
GROUP BY ?i ?iLabel ?iDescription ?coord ?inst ?instLabel ?pea
HAVING(?num > 1)
ORDER BY(?pea)
Try it!

Query per gli archivi dell'import PEA con "Biblioteca" nell'etichetta: 

#Archivi in Toscana con "Biblioteca" nell'etichetta
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel ?instcoord ?pea
WHERE {
  ?i wdt:P31 wd:Q166118 .
  ?i rdfs:label ?iLabel .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  ?i wdt:P7764 ?pea .
  OPTIONAL { ?i wdt:P625 ?coord . }
  BIND(IF(BOUND(?coord),'archiv','comune') AS ?layer)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it". }
  FILTER(LANG(?iLabel) = "en").
  FILTER(CONTAINS(?iLabel,"Biblioteca")).
}
Try it!

Raffinamento biblioteche edit 

#Biblioteche in Toscana con ISIL uguale a PEA presente in un altro elemento
SELECT ?i ?iLabel ?cod ?i2 ?i2Label {
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?coord . }
  BIND(IF(BOUND(?coord),'biblio','comune') AS ?layer)
  ?i wdt:P791 ?cod .
  ?i2 wdt:P7764 ?cod .
  FILTER(STR(?i)<STR(?i2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?cod
Try it! 
#Biblioteche in Toscana con "*omun*" nell'etichetta
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel ?instcoord ?pea
WHERE {
  ?i wdt:P31 wd:Q7075 .
  ?i rdfs:label ?iLabel .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?coord . }
  BIND(IF(BOUND(?coord),'biblio','comune') AS ?layer)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  FILTER(LANG(?iLabel) = "it").
  FILTER(CONTAINS(?iLabel,"omun")).
}
Try it!

Altre parole da cercare: "liceo", "convento", "museo", "scuola", "ragazzi". 

#Biblioteche in Toscana con edificio
SELECT DISTINCT ?i ?iLabel ?iDescription ?ed ?edLabel ?edDescription
WHERE {
  ?i wdt:P31 wd:Q7075 .
  ?i (wdt:P131)* wd:Q1273 . 
  ?i wdt:P276 ?ed .
  ?ed wdt:P31/wdt:P279* wd:Q41176 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
Try it!

Altro lavoro manuale di complemento edit

Azioni che migliorano l'elemento ma non sono basate sui metadati del Sistema Cultura

Inserimento ID di complemento edit

Dedicazione edit

Lavoro sugli elementi di preparazione all'import edit

Elementi uniti prima dell'import edit

Elementi riordinati preparando l'import edit

Elementi creati preparando l'import edit

Elementi uniti verificando l'import edit

Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata:Sistema_Cultura/Raffinamento&oldid=1184596913"