Wikidata:WikiProject Performing arts/Data structure/Data modelling issues

This page contains an overview of the data modelling issues on Wikidata encountered in the area of the performing arts. Diverging modelling approaches are documented as much as possible in form of SPARQL queries. The overview serves as a basis for community discussions about how to approach the data modelling issues. The modelling approaches retained will then serve as a basis for more user friendly documentation of data modelling practices and for maintenance lists.

For a full list of issues that were identified in the context of data ingests, see the following Google Doc.

For a list of issues that were identified as part of CAPACOA's Wikidata project, see this Google Doc.

For Issues regarding Performing Arts Organizations there is a specific projectpage: Wikidata:WikiProject_Performing_arts/Data_structure/Data_modelling_issues/organizations

Items confounding architectural structures and organizations

Description of the issue

Many Wikidata items confound architectural structures (buildings, facilities, venues, performance halls) and organizations. In other words, they are stated to be both an instance of a building/venue and an instance of an organization. This issue is commonly known as “conflation”. Items having this issue may display one or several of the following characteristics:

• The presence of several instance of (P31) claims that relate both to architectural structures and organizations;
• The presence of properties that relate to the architectural structure and to the organization;
• The presence of external identifiers that relate to architectural structures and to organizations.
• The presence of interwiki links pointing to Wikipedia articles that are equally conflated (also known as “compound Wikipedia articles”).

Conflated items can present several structural challenges:

• Some statements may apply to either entity.
  • For example, inception (P571) could refer either to the date when an organization was founded or to the date when construction for a building began.
  • official name (P1448) could designate either the name of the building or that of the organization.
• The building and the organization may change names at different points in time.
• A building may be operated by different organizations over its lifetime.
• An organization may occupy different buildings over the course of its existence.
• External identifiers associated with distinct organization entities or building entities can get incorrectly matched in Wikidata.
• Conflated items can also prevent data reuse (a conflated item may trigger constraints violation or fail to pass shape validation).

Rationale to resolve the issue

An architectural structure and an organization are two distinct entities with different characteristics and independent timelines. Conflating these entities into a single item can create several structural issues and make the data less suited for reusability.

Therefore, conflated items should be split into separate items for the architectural structure(s) and the organization(s), following the guidance below.

Example: Teatro alla Scala

• La Scala (Q5471) – the opera house, the theatre venue, the building
• Fondazione Teatro alla Scala (Q54820121) – the opera company, the organization
• Orchestra of the Teatro alla Scala, Milan (Q913873) – part of (P361)Fondazione Teatro alla Scala (Q54820121) (the opera company, not the opera house)
• operator (P137) – the property linking the building to the opera company that operates it
• architect (P84) – a property relating to the building
• musical conductor (P3300) – a property relating to the orchestra of the opera company (and not to the building)
• artistic director (P8938) – a property relating to the opera company (and not to the theatre venue), not to be confounded with art director (P3174)
• MusicBrainz place ID – external identifier relating to the building
• Library of Congress authority ID (instance of CorporateName) – an external identifier relating to the opera company (and not to the building)
• GND ID (Organisation) – an external identifier relating to the opera company (and not to the building)
• GND ID (Geografikum) – an external identifier relating to the building.

Remarks / Observations

• An opera company may change its name over time or it may be replaced by a new company altogether. Depending on how the historicization of the company name (or the successive companies) is handled, this may cause issues when ingesting data from external databases that do not reflect these changes (i.e. all entries relating to the opera company may point to "La Scala" or similar). A similar issue exists with regard to the entries in authority files. Most of them treat the given company as one entity, even if its name has changed over time. Therefore, we should avoid creating a new item for each name change in a corporate body. Use official name (P1448) instead with start time/end time qualifiers.

Guidance for splitting a conflated Wikidata item

Wikidata and links with Wikipedia

Example 1: version comparison in Wikidata

Example 1: redirect page on Dutch Wikipedia

Example 1: redirect page on English Wikipedia

Example 1: intentional sitelink to redirect

• The disentanglement (or splitting) of conflated Wikidata items requires carefully sorting out external identifiers so that they can be accurately matched either to the organization item or to the building item. These external identifiers should not be blindly matched to Wikidata items simply based on their names.
  • While authority files such as VIAF, ISNI and GND are most likely to hold records for names of organizations, they may also hold records for names of places. Links to authority files should be validated with regard to the class of the item. For example, GND has distinct normative data for organizations (Normdaten: Organisationen) and geographical features (Normdaten: Geografika).
  • Some external reference databases (authority files) do not specify whether they are referencing an organization or an architectural structure (example). These external identifiers may be qualified with mapping relation type (P4390)close match (Q39893184) to indicate that they are not an exact match.
• The splitting of a Wikidata item involves sorting sitelinks in order to determine which Wikidata item should be linked to which Wikipedia article(s). This is important to ensure connectivity both between different Wikimedia projects and between Wikipedia language versions. Depending on the main focus of each article, the various articles (in different languages) that originally pointed to the same conflated Wikidata item may, in the future, point to different Wikidata items. As a consequence, some interlanguage links between Wikipedias may be broken. When sorting sitelinks, the ideal situation is to:
  1. Ensure that each Wikipedia article links to the Wikidata item that is the main focus of the article.
  2. Ensure that each Wikidata item links to a Wikipedia page, even when there is a single Wikipedia article covering multiple topics. Although a Wikipedia article page cannot be sitelinked from more than one Wikidata item, this problem can be solved with an intentional sitelink to redirect (Q70894304). The Wikidata item that corresponds to the main focus of the Wikipedia article covering multiple topics should have a normal sitelink to this article page. The Wikidata item that corresponds to a secondary topic in Wikipedia article covering multiple topics should have an intentional sitelink to redirect (Q70894304) pointing to the same article page. Here's how to proceed:
     1. Create a redirect Wikipedia page for the item that is a secondary topic in the Wikipedia page covering multiple topics (see Wikipedia:How_to_make_a_redirect);
     2. Replace "Name of article" with the name of the the Wikipedia page covering multiple topics;
     3. Insert the R with Wikidata item template to inform users of this Wikipedia that the redirect has structural utility (the template is available in multiple languages – make sure to use the template that corresponds to the Wikipedia language version that you are currently editing);
     4. Click "Publish page".
     5. In the Wikidata item corresponding to the secondary topic, insert a Wikipedia sitelink to the redirect page you just created;
     6. Select the intentional sitelink to redirect (Q70894304) badge to notify users that this sitelink is a redirect;
     7. Click "Publish".

• • Example 1: Fieldworks (Q33100242) was listed as both instance of (P31)theatre building (Q24354) and instance of (P31)theatrical troupe (Q742421). This was a clear example of a conflated item, as the former referred to a venue and the latter referred to an organisation. There was no sitelink to any Wikipedia article on this item. Another Wikidata item about Fieldworks existed that was clearly about the organisation and not about the venue, namely Fieldworks vzw (Q33830417). This item did have sitelinks to Wikipedia articles that had the organisation as their main topic. Thus, statements related to the organisation had to be moved to this organisation item in order to make the original conflated Wikidata item conceptually clear as an item exclusively about the venue. After that, an intentional sitelink to newly created redirect pages on Dutch and English Wikipedia had to be placed on the Wikidata venue item. Depending on the Wikipedia language version, a different template was used on the redirect pages:
    • For English Wikipedia, use the R with Wikidata item template.
    • For Dutch Wikipedia, use the Wikidata-doorverwijzing template.
  • Example 2: Theatre troupe Toneelstudio 50 - Arca (Q42274529) was a predecessor of Arca Theatre (Q33100599). The Dutch Wikipedia article has Arca Theatre (Q33100599) as its main topic, but covers both time periods in history in one article. This makes sense from an encyclopedic point of view, but not so much from a Wikidata point of view. In order to maintain optimal connectivity between Wikidata items and Wikipedia content, a Wikipedia redirect page was created for Toneelstudio 50 - Arca (Q42274529). On its Wikidata page, an intentional sitelink to redirect was placed instead of a normal sitelink.

Wikipedia redirect page

intentional sitelink to redirect

• Making sitelinks to specific subsections of an article, e.g. https://en.wikipedia.org/wiki/Fieldworks_vzw#Productions is not allowed (see here).
• For more detailed information on how to manage links to Wikipedia articles, see Help: Sitelinks and more specifically Sitelinks to redirects.

Links with Wikimedia Commons

• The splitting of a Wikidata item may also require sorting out links with Wikimedia Commons. Wikimedia Commons is more likely to hold images representing buildings than images of organizations, but it is better to verify the content of Commons categories and galleries before making a decision on a link with Commons.
  • If a category doesn’t have a clear focus and holds mixed content representing both the building and the organization, then it may be necessary to split it into two distinct categories at the same time as correcting Wikidata and Wikipedia conflations.
  • If necessary, Commons category (P373) and Commons gallery (P935) statements should be moved to the Wikidata item that most closely matches the focus of the category or gallery.
  • The sitelinks to Commons should be updated to match these statements. If there is a Commons category (P373) or Commons gallery (P935) statement but no sitelink, a sitelink should be added. Sitelinks are more important than P373/P935 because they are bidirectional and they are used to power infoboxes. Sitelinks to Commons are found under the “Multilingual sites” heading, at the bottom of Wikidata items.
  • Wikipedia articles may include manual links to Commons categories. Those sitelinks should be edited or removed if necessary.

This modelling issue was discussed in the Project chat in December 2021. You can read it at: Wikidata:Project_chat/Archive/2021/12#Could_a_new_constraint_help_dealing_with_conflation_issues? Read more:

• Help:Conflation
• Help:Split_an_item

SPARQL Queries

List of theatres (venues), with their various type statements (in descending order of the number of types)

Maintenance tasks:

• Remove any instance of (P31) statements that refer to an organization. Create a separate item for the organization (sometimes you may want to proceed the other way round, creating a new item for the theatre building; you may also inspect the list of reverse statements to see to which type incoming statements predominantly refer to).
• Remove any instance of (P31) statements that refer to a superclass of any of the other types. Example: drive-in theater (Q786922) is a subclass of outdoor cinema (Q1454553), which is in turn a subclass of movie theater (Q41253); thus items of the type drive-in theater (Q786922) do not require another instance of (P31) statement referring to movie theater (Q41253).

SELECT   ?item 
         ?itemLabel
         (replace(group_concat(distinct ?type;separator="; "), "http://www.wikidata.org/entity/", "") as ?types)  #Strip the path in order to get only the Q-number.
         (group_concat(distinct ?typeLabel_en;separator="; ") as ?typeLabels_en)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P31 ?type.
  OPTIONAL { ?item wdt:P31/rdfs:label ?typeLabel_en . FILTER (lang(?typeLabel_en) = "en") }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
group by ?item                          #List all the variables for which the values are not concatenated!
         ?itemLabel
order by desc (COUNT(?type))

Try it!

List of items for performing arts buildings which are at the same time defined as organizations

Maintenance tasks:

• Remove any instance of (P31) statements that refer to an organization. Create a separate item for the organization (sometimes you may want to proceed the other way round, creating a new item for the theatre building; you may also inspect the list of reverse statements to see to which type incoming statements predominantly refer to).

SELECT DISTINCT ?item ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q57660343.
  ?item wdt:P31/wdt:P279* wd:Q43229. hint:Prior hint:gearing "forward".
  MINUS 
  {
      ?item wdt:P31/wdt:P279* wd:Q41253. # Excluding movie theatres
      }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Note: The following query pulls a list of performing arts buildings which are at the same time defined as performing arts group (Q105815710).

SELECT   ?item ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q57660343.
  ?item wdt:P31/wdt:P279* wd:Q105815710. hint:Prior hint:gearing "forward".
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

• Query count as of 29 November, 2021: 2790.

List of items with both a Flanders Arts Institute organization ID and a Flanders Arts Institute venue ID

Issue is documented at the following page: [[1]]

List of properties used on theatre (venue) items

To be used to identify problematic properties used in combination with theatre venues (e.g. properties relating to organizations).

SELECT ?property ?propertyLabel ?count WITH {
  SELECT ?property (COUNT(DISTINCT ?statement) AS ?count) WHERE {
    ?item wdt:P31/wdt:P279* wd:Q24354;
          ?p ?statement.
    ?property a wikibase:Property;
              wikibase:claim ?p.
    FILTER(?property != wd:P31)
  }
  GROUP BY ?property
  ORDER BY DESC(?count)
  LIMIT 1000
} AS %results WHERE {
  INCLUDE %results.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de-CH,en,fr-CH,it-CH,en-US,en". }
}
ORDER BY DESC(?count)

Try it!

List of theatre (venue) items with a VIAF identifier

Many (but not all) VIAF identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P214 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a GND identifier

Many (but not all) GND identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P227 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a Library of Congress identifier

Many (but probably not all) LoC identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P244 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a BnF identifier

Many (but probably not all) BnF identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P268 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a SUDOC identifier

Many (but probably not all) SUDOC identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P269 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with an Open Corporates identifier

All Open Corporates identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P1320 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a field of work (P101) statement

All field of work (P101) statements should be removed from the venue items. They may be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P101 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a X username (P2002) statement

All X username (P2002) statements should be removed from the venue items. They may be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P2002 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a Facebook username (P2013) statement

All Facebook username (P2013) statements should be removed from the venue items. They may be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P2013 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a award received (P166) statement

Most award received (P166) statements should probably be removed from the venue items and be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P166 ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a director / manager (P1037) statement

Issue is documented on the following page: [[2]]

SPARQL Queries specifically adapted for Switzerland

List of theatres (venues), with their various type statements (in descending order of the number of types)

Maintenance tasks:

• Remove any instance of (P31) statements that refer to an organization. Create a separate item for the organization (sometimes you may want to proceed the other way round, creating a new item for the theatre building; you may also inspect the list of reverse statements to see to which type incoming statements predominantly refer to).
• Remove any instance of (P31) statements that refer to a superclass of any of the other types. Example: drive-in theater (Q786922) is a subclass of outdoor cinema (Q1454553), which is in turn a subclass of movie theater (Q41253); thus items of the type drive-in theater (Q786922) do not require another instance of (P31) statement referring to movie theater (Q41253).

SELECT   ?item 
         ?itemLabel
         ?countryLabel
         (replace(group_concat(distinct ?type;separator="; "), "http://www.wikidata.org/entity/", "") as ?types)  #Strip the path in order to get only the Q-number.
         (group_concat(distinct ?typeLabel_en;separator="; ") as ?typeLabels_en)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P31 ?type.
  ?item wdt:P17 wd:Q39.
  OPTIONAL { ?item wdt:P31/rdfs:label ?typeLabel_en . FILTER (lang(?typeLabel_en) = "en") }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
group by ?item                          #List all the variables for which the values are not concatenated!
         ?itemLabel
         ?countryLabel
order by desc (COUNT(?type))

Try it!

List of items for performing arts buildings which are at the same time defined as organizations

Maintenance tasks:

• Remove any instance of (P31) statements that refer to an organization. Create a separate item for the organization (sometimes you may want to proceed the other way round, creating a new item for the theatre building; you may also inspect the list of reverse statements to see to which type incoming statements predominantly refer to).

SELECT   ?item ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q57660343.
  ?item wdt:P31/wdt:P279* wd:Q43229.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of properties used on theatre (venue) items

To be used to identify problematic properties used in combination with theatre venues (e.g. properties relating to organizations).

SELECT ?property ?propertyLabel ?count WITH {
  SELECT ?property (COUNT(DISTINCT ?statement) AS ?count) WHERE {
    ?item wdt:P31/wdt:P279* wd:Q24354;
          wdt:P17 wd:Q39;
          ?p ?statement.
    ?property a wikibase:Property;
              wikibase:claim ?p.
    FILTER(?property != wd:P31)
  }
  GROUP BY ?property
  ORDER BY DESC(?count)
  LIMIT 1000
} AS %results WHERE {
  INCLUDE %results.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de-CH,en,fr-CH,it-CH,en-US,en". }
}
ORDER BY DESC(?count)

Try it!

List of theatre (venue) items with a VIAF identifier

Many (but not all) VIAF identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P214 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a GND identifier

Many (but not all) GND identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P227 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a Library of Congress identifier

Many (but probably not all) LoC identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P244 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a BnF identifier

Many (but probably not all) BnF identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P268 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a SUDOC identifier

Many (but probably not all) SUDOC identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P269 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with an Open Corporates identifier

All Open Corporates identifiers relate to corporate bodies and should be removed from the venue items (create separate items for the corporate bodies).

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P1320 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a field of work (P101) statement

All field of work (P101) statements should be removed from the venue items. They may be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P101 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a X username (P2002) statement

All X username (P2002) statements should be removed from the venue items. They may be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P2002 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a Facebook username (P2013) statement

All Facebook username (P2013) statements should be removed from the venue items. They may be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P2013 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

List of theatre (venue) items with a award received (P166) statement

Most award received (P166) statements should probably be removed from the venue items and be applied to the related corporate body items instead.

SELECT   ?item 
         ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q24354.
  ?item wdt:P166 ?value.
  ?item wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Modelling world premieres

Description of the issue

Different modelling approaches have been used to describe world premieres:

• Benvenuto Cellini (Q277846) uses various qualifiers on the date of first performance (P1191) statement of the work item to indicate the location, a performer, and some cast members of the world premiere.
• Liberté provisoire (Q51203738) uses a separate item to describe the theatre production corresponding to the world premiere. The premiere type is expressed in a premiere type (P4634) statement, which can be used to describe different premiere types (world premiere, language premiere, country premiere). The link to the play is provided by a based on (P144) statement.

Proposed rationale to resolve the issue

The first modelling approach is less onerous when it comes to describing just a few characteristics of the world premiere. The second approach, in contrast, is much more versatile when it comes to adding a lot of information about the specific theatre production. We therefore suggest that date of first performance (P1191) and location of first performance (P4647) statements may be used on work items to provide some minimal information about the world premiere. However, whenever further information is to be provided about the world premiere, a separate item is to be created for the first production of the play or even for its very first performance.

SPARQL Queries

Plays with location (P276) or cast member (P161) qualifiers on the date of first performance (P1191) statement

Proposed maintenance task: Use location of first performance (P4647) to indicate the location of the world premiere. If further information about the world premiere is provided, create a separate item for the first production of the play and provide it there. date of first performance (P1191) statements should not have any qualifiers.

SELECT DISTINCT ?item ?itemLabel
WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q25379;
        p:P1191 [
          pq:P161|pq:P276 ?value  
        ].
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Plays with a related performing arts production that has a premiere type (P4634) statement

The query illustrates the proposed approach for modelling world premieres and other premiere types.

SELECT DISTINCT ?play ?playLabel ?production ?premiereTypeLabel
WHERE {
  ?play (wdt:P31/wdt:P279*) wd:Q25379.
  ?production wdt:P144 ?play;
              wdt:P31/wdt:P279* wd:Q43099500;
              wdt:P4634 ?premiereType.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!