Touam

Welcome to Wikidata, Touam!

Wikidata is a free knowledge base that you can edit! It can be read and edited by humans and machines alike and you can go to any item page now and add to this ever-growing database!

Need some help getting started? Here are some pages you can familiarize yourself with:

Introduction – An introduction to the project.
Wikidata tours – Interactive tutorials to show you how Wikidata works.
Community portal – The portal for community members.
User options – including the 'Babel' extension, to set your language preferences.
Contents – The main help page for editing and using the site.
Project chat – Discussions about the project.
Tools – A collection of user-developed tools to allow for easier completion of some tasks.

Please remember to sign your messages on talk pages by typing four tildes (~~~~); this will automatically insert your username and the date.

If you have any questions, don't hesitate to ask on Project chat. If you want to try out editing, you can use the sandbox to try. Once again, welcome, and I hope you quickly feel comfortable here, and become an active editor for Wikidata.

Best regards! Liuxinyu970226 (talk) 12:20, 31 July 2017 (UTC)Reply

Carte des sorcières07:49, 8 April 2018 (UTC)

Latest comment: 6 years ago7 comments2 people in discussion

Coucou Touam, sais-tu comment rajouter des liens langues (de-en-es) et le lien vers les éléments wikidata à notre carte interactive? Les fichiers sont là :https://fr.wikipedia.org/wiki/Discussion_Projet:Les_sans_pagEs/Carte_des_sorcières_notoires#Mise_à_jour_de_la_carte_interractive Moi j'ai essayé mais je n'y arrive pas, et 0x010C.

j'ai géolocalisé les lieux de décès des sorcières condamnées et cela commence à donner un beau résultat!

Next step: la time line? Peut.on améliorer sa présentation, voir en faire un wikishoot me?Nattes à chat (talk) 07:50, 8 April 2018 (UTC)Reply

Je vais regarder. --Touam (talk) 07:51, 8 April 2018 (UTC)Reply

Hello bon alors voilà une requête qui renvoie les éventuels liens de-en-es-fr dans une colonne de table, je ne sais pas si ça correspond à ta demande (j'espère) ? :

SELECT
  ?item
  ?itemLabel
  ?deathPlaceLabel
  (concat(str(geof:latitude(?coords)), ',', str(geof:longitude(?coords))) as ?latlng)
  (if(?gender = wd:Q6581072, '#993300', '#009933') as ?color)
  (if(BOUND(?link), 'circle', '') as ?symbol)
  (if(BOUND(?link), concat('[[', substr(str(?link),31,500),  '|', ?itemLabel, ']]'), ?itemLabel) as ?title)
  (concat('décès en ', str(YEAR(?death)), ' à ', ?deathPlaceLabel, '\n\n', if(BOUND(?image), concat('[[File:', substr(str(?image), 52, 500), '|200px]]'), '')) as ?description)
  ('1000' as ?randomise)
  ?linkfr
  ?linkde
  ?linken
  ?linkes
WHERE {
  { ?item wdt:P1399 wd:Q259745. }
  UNION
  { ?item wdt:P1595 wd:Q259745. }
  ?item wdt:P20 ?deathPlace.
  ?deathPlace wdt:P625 ?coords.
  OPTIONAL { ?item wdt:P21 ?gender. }
  OPTIONAL { ?item wdt:P570 ?death. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL {
    ?linkfr schema:about ?item .
    ?linkfr schema:isPartOf <https://fr.wikipedia.org/> .
  }
  OPTIONAL {
    ?linkde schema:about ?item .
    ?linkde schema:isPartOf <https://de.wikipedia.org/> .
  }  
  OPTIONAL {
    ?linken schema:about ?item .
    ?linken schema:isPartOf <https://en.wikipedia.org/> .
  }
  OPTIONAL {
    ?linkes schema:about ?item .
    ?linkes schema:isPartOf <https://es.wikipedia.org/> .
  }  
}

Try it!

@Nattes à chat: J'ai repris la requête que j'ai trouvée à fr:Discussion_Projet:Les_sans_pagEs/Carte_des_sorcières_notoires#Mise_à_jour_de_la_carte_interractive sans trop comprendre tous les tenants et aboutissants, c'est pour ça que je ne suis pas allé jusqu'à modifier la carte elle même, que je ne reprends que la requête. Dans l'ensemble ça serait plus facile pour moi si on avait un suivi sur le problème spécifique de cette requête et de wikidata, je m'étonne que la requête choisie renvoie par exemple toujours des cas comme Esmeralda (Q661491) (une sorcière immaginée par Victor Hugo !?) malgré que j'en ai déjà parlé, mais peut-être y a-t-il une discussion ailleurs, et aussi j'aurais aimé une réponse sur ma petite réflexion à User:Touam# Tentative d'examen de la situation des sorcières sur wikidata car ça m'aide de savoir ce que vous pensez ; mais bon je sais bien que rien n'est simple, je vois toujours que vous faites un travail formidable, et peut être est-ce seulement un problème de notification ? Bon, bref, c'est juste pour dire que, attention, pour les requêtes informatiques, contrairement à ce que certains pensent de l'informatique, le dialogue humain est important :-) --Touam (talk) 09:51, 8 April 2018 (UTC)Reply

Bonsoir @Touam:, pardon de ne pas avoir répondu à ta demande plus tôt! Sache que j'ai toutefois utulisé la requête que tu avais faites pour compléter la liste et géolocaliser tout ce qui était déjà sur wikidata grâce à ton travail. Je ne suis pas du tout une spécialiste des requêtes, et le problème c'est que je ne sais pas par exemple comment intégrer une requête dans l'outil qui nous sert à mettre à jour la carte, car c'est @0x010C: qui a tout fait! J'ai juste compris qu'il y a un bot qui lance la requête d'un coté sur https://fr.wikipedia.org/wiki/Projet:Les_sans_pagEs/Carte_des_sorcières_notoires/carte/wikidata_list et qu'ensuite on copie colle le résultat mais sans les bouts wikidate sur la page réservée à la carte. LA carte ensuite se met à jour toute seule. Le mieux c'est que tu essaies je crois… Bon cela a l'air de marcher effectivement. Ce qui serait génial c'est qu'on puisse se servir de la géolocalisation soit du lieu de résidence soit d'inculpation de la personne, car sinon celles qui sont condamnées mais pas exécutées n'apparaissent pas dans la carte. Est-ce possible?

Coucou jeme suis lancée, et je viens d'essayer de copier coller ta requête à la place de celle de 0x010C, mais on a plus aucun lien vars les articles wikipedia, même pas ceux en Français (qui apparaissent avec un point blanc). Hum hum. Que manque-t-il? Nattes à chat (talk) 20:14, 8 April 2018 (UTC)Reply

Ps j'ai tout enlevé pour le moment parce qu'on a déjà publié dans l'espace principal… Bonne soirée!Nattes à chat (talk) 20:15, 8 April 2018 (UTC)Reply

Je viens de me rendre compte que 1) j'ai modifié ta Pu pour répondre (désolée) et 2) que je n'aurais pas pu répondre avant d'avoir wikidaté toute la semaine. Merci beaucoup pour ton boulot (il m'a beaucoup servi) la requête m'a permis de géolocaliser on n'avait que quelques sorcières qui se courraint après voici deux semaines. Nattes à chat (talk) 21:32, 8 April 2018 (UTC)Reply

Aucun souci pour ma PU, le jour où il y aura plus que ça comme problème... Bon je me suis remis sur la question du sujet du problème, je te tiens au courant :-). --Touam (talk) 04:57, 9 April 2018 (UTC)Reply

Réponses de Nattes à chat

À la recherche des sorcières

Latest comment: 6 years ago6 comments2 people in discussion

Tentative d'examen de la situation des sorcières sur wikidata

Les impatients peuvent tout de suite aller voir #Tentative de résumé de la tentative d'examen.

Il s'agit d'examiner comment les sorcières sont présentées sur wikidata, et comment il est possible d'y faire des recherches sur elles. N'étant pas un grand connaisseur de wikidata, je tatonne la plupart du temps, et il se peut que je passe à coté de trucs importants.

Je fais cet essai dans l'inspiration de w:fr:Projet:Les sans pagEs/Carte des sorcières notoires

L'idée générale de la recherche est de trouver les femmes condamnées pour sorcellerie.

Les femmes

Pour des raisons qui m'échappent, les woman (Q467) ne sont pas des femmes sur wikidata, mais des human (Q5) female (Q6581072) ; sans doute pour les mêmes raisons que les "handicapés" deviennent des "personnes en situation de handicap", bon. Sur wikidata, Mona Lisa (Q12418) représente bien une femme, mais Angela Merkel (Q567) est un être humain de sexe féminin, bien.

=> OMG!! Je ne savais pas!Nattes à chat (talk) 21:07, 8 April 2018 (UTC)Reply

La sorcellerie

Pour ce qui est de la sorcellerie, c'est un peu subtil. witchcraft (Q259745) est un élément de wikidata, qui pourrait être central dans cet examen. Malheureusement (ou heureusement je ne sais pas), cet élément est associé au mot anglais "witchcraft", qui semble vouloir dire "sorcellerie", qui est une sous-classe de sorcery (Q9198102), qui n'a pas vraiment de traduction française, ou qui aurait pu avoir "sorcellerie" comme traduction. Donc, en français, sur wikidata, il y a en fait 2 "sorcellerie", et il est mieux de prendre "sorcery", qui inclut aussi des pratiques telles que la necromancy (Q337935). Peut-être serait-il encore mieux de prendre le niveau encore supérieur à sorcery, à savoir black magic (Q690768), je ne sais pas.

À noter que sur wikidata il existe la occupation (P106) de witch (Q1616828), mais occupation ne veut pas dire condamnation, et de toutes façons l'immense majorité des femmes condamnées pour sorcellerie n'ont jamais été sorcières à ma connaissance. Donc je n'ai pas retenu cette propriété.

=> Exact pour l'occupation, et en plus je viens de lire Les batailles Nocturnes de Carlo Ginzburg qui montre que les "sorciers" ne se définissent pas forcément comme tels à la base, ce concept de sorcière est fabriqué depuis le au Moyen Age. Il y a aussi un truc qui s'appelle "chasse aux sorcières" et "procès des sorcières" je ne m'en suis aperçu qu'à la fin et il faudrait que je repasse partout pour l'ajouter aux éléments… Il y a aussi des éléments créés pour des procès comme celui du Ban de la Roche.Nattes à chat (talk) 21:28, 8 April 2018 (UTC)Reply

La condamnation

La notion de condamnation se trouve pour ce cas à convicted of (P1399). Elle peut avoir comme Help:Qualifiers/fr une point in time (P585), comme dans le cas d'une condamnation de Lionel Messi (Q615), malheureusement dans le cas des sorcières ça n'est pour l'instant jamais employé. Dans leur cas il est probable que la date de leur condamnation corresponde à la date de leur mort, voilà pourquoi la date of death (P570) est employée.

Il existe aussi des cas où la personne n'est pas du tout déclarée comme sorcière dans wikidata, ni même condamnée, alors qu'elle l'a été. C'est le cas par exemple de Elisabeth Plainacher (Q88208). Une possibilité pour les trouver est de retenir les femmes dont la cause of death (P509) est le death by burning (Q468455). Mais cette approche donne des faux-positifs, par exemple Saint Afra (Q114845), qui est une martyre chrétienne.

=> surtout que toutes ne emurent pas sur le bûcher, et même en général elles meurent d'autre chose avant: strangulation, décapitation, et c'est ensuite leur corps qui est brûlé, sauf en Allemagne qui les a beaucoup soit disant brûlées vives (une historienne m'a dit que ce n'est pas possible, en général les personnes sur un bûcher meurent asphyxiées et je dois vérifier cela).Nattes à chat (talk) 21:06, 8 April 2018 (UTC)Reply

Il est possible de faire l'union entre convicted of (P1399) et charge (P1595) ; cependant, condamné pour devrait suffire, car, d'après la proposition votée, le sens wikidata de condamné pour est forcément pour un crime ; en français de chez moi, on peut être condamné pour un simple vol, mais sur wikidata, non. Il existe quand même quelques personnes sur wikidata inculpées, mais pas condamnées, pour sorcellerie (mais tout de même condamnées à la peine de mort), telle Jehenne Noël Axy (Q50909741).

=> je suis tombée sur plein de cas aussi où les personnes meurent en prison suite aux tortures (pas condamnées), se suicident (pas condamnées) donc je pense qu'inculpée est aussi une donnée à intégrer si on veut avoir toutes les personnes victimes de la chasse aux sorcières.Nattes à chat (talk) 21:06, 8 April 2018 (UTC)Reply

@Nattes à chat: Je reste un peu interrogatif. Sur le principe, on risque d'élargir énormément les cas de sorcellerie. Si on commence à enregistrer toutes les personnes mortes en prison suite à des tortures pour des malédictions diverses on n'a malheureusement pas fini. Accuser quelqu'un sous la torture de sorcellerie est pratiquement général : l'accusation de n'importe quoi fait partie de la torture. Pratiquement tous les noirs sont considérés comme des sorciers par des blancs colonialistes qui se croient en danger. J'ai fait divers tests sur wikidata, et pour l'instant je n'ai trouvé aucune personne "inculpée de sorcellerie" qui ne soit pas aussi "condamnée pour sorcellerie". J'ai aussi regardé par rapport à la liste sur wikipédia, des cas qui me semble entrer dans ta catégorie, et tous sont également "condamné pour sorcellerie"... mais peut-être y a-t-il des erreurs dans wikidata ? Par exemple María de Zozaya (Q16932435) décrite dans la liste comme "Inculpée de sorcellerie, elle meurt en prison sans avoir avoué quoi que ce soit lors des procès de sorcellerie en Pays Basque" est quand même désignée comme condamnée sur wikidata. Sur les cas que tu connais, pourrais-tu en donner 3 ou 4 précisément ? En tous les cas, pour l'instant, rajouter une requête sur l'inculpation ne renverrait aucun élément nouveau. J'ai l'impression que, dans la sorcellerie, il y a d'un coté une pratique de condamnation légale d'ordre administratif suite à un procès, mais il y a souvent aussi une dimension délirante des accusateurs, une sorte d'emballement ? Je ne sais pas si ça se qualifie ? Ou peut-être que je me trompe... --Touam (talk) 10:41, 10 April 2018 (UTC)Reply

La situation

Concernant la question du lieu, c'est la plus difficile et la plus mal renseignée. Dans l'idéal, il me semble, ça pourrait être un qualificateur de la propriété convicted of (P1399). Mais ça n'est jamais le cas dans la situation actuelle. On dispose souvent de place of death (P20), ce qui "tombe" malheureusement bien pour les sorcières ; voir par exemple Gwen ferch Ellis (Q18914804), mais cette information est loin d'être toujours présente. Si elle est présente, elle l'est sous la forme d'un élément wikidata, et de là on a les coordonnées pour affichage sur une carte.

La date

C'est comme pour la situation, on "profite" de ce que l'exécution de la condamnation est immédiate - du moins on le suppose - pour utiliser la date of death (P570) comme date. Cette donnée est très souvent présente. Dans l'idéal, il faudrait utiliser une date de la condamnation, qui pourrait être un qualificateur de la condamnation. À réfléchir.

Tentative de résumé de la tentative d'examen

Dans la situation actuelle, une requête sur human (Q5) (nature), female (Q6581072) (sexe ou genre), sorcery (Q9198102) (condamné pour ça ou dérivé) renvoie 80% (estimation à la louche) des sorcières déjà enregistrée sur wikidata. Je n'ai jamais repéré de faux positifs, mais il y a pas mal de vrai négatifs, c'est à dire des femmes enregistrées sur wikidata mais dont la condamnation pour sorcellerie n'est pas explicitement (explicitement du point de vue de cette étude) mentionnée sur wikidata. Par exemple il n'est mentionné que une condamnation au bûcher.

Par rapport à la liste présentée à w:fr:Projet:Les sans pagEs/Carte des sorcières notoires#Liste de sorcières les manques sont très importants. La plupart ne sont pas entrés sur wikidata.

Il serait donc important d'enregistrer cette liste sur wikidata, et de donner plus de rigueur à l'enregistrement des sorcières, même déjà présentes.

=> En cours! il y avait aussi des éléments de ta requête non géolocalisés, et donc j'ai tenté de le faire, mais le souci que j'ai c'est que c'est facile pour les condamnées à cause de l'immédiateté de l'exécution après la condamnation, qui elle vient en principe d'un registre légal et est donc … localisées. !

Attention que je n'ai aucune idée des critères d'admissibilité sur wikidata.

Pour y enregistrer ces personnes sous la forme d'éléments, je propose :

human (Q5) (nature), female (Q6581072) (sexe ou genre)
convicted of (P1399) est je pense la notion centrale. Il serait merveilleux qu'elle puisse être datée, située et sourcée.
witchcraft (Q259745) je propose, mais n'étant pas un fin connaisseur, peut être des notions comme sorcery (Q9198102), necromancy (Q337935), black magic (Q690768) et leurs dérivées seraient mieux. Tant qu'on fait la requête sur sorcery (Q9198102) on peut être assez libres de détailler ; on pourrait aussi la faire sans doute à partir de black magic (Q690768). À réfléchir.
Pour la situation il faut prendre garde que la nationnalité de la personne (ou du moins la notion équivalente à l'époque) se donne par country of citizenship (P27), tandis que la situation d'un tribunal se donne par country (P17).
Il n'est pas possible et non pertinent pour wikidata à mon avis d'entrer la partie "description". Toutefois il serait important de qualifier la personne autrement que comme "condamnée pour sorcellerie", pour faciliter l'étude et leurs relations avec leur contexte ; par exemple leur métier, leurs parents, leur habitation, leur religion ou confession, etc.
Peut-être serait-il juste de faire une évaluation de la notion occupation (P106) de witch (Q1616828), par rapport à la convicted of (P1399). Peut-être y a-t-il eu des sorcières non condamnées ?

=> oui! Il y en a qui ont été lynchées par la foule, qui a les a parfois condamnées lors de simulacres de jugement. AMHA elles sont victimes aussi de la chasse aux sorcières, ont été assassinées et pas condamnées…

=> => sorcery ah ben zut, j'ai tout mis sous sorcellerie... Nattes à chat (talk) 21:02, 8 April 2018 (UTC)Reply

requête large

Merci à Wikidata:Request a query#wd:Q468455 (death by burning) or wd:Q337935 (necromancy) !

SELECT ?iteme ?itemeLabel ?condamnationLabel ?decesLabel WHERE {
  ?iteme wdt:P31 wd:Q5.
  ?iteme wdt:P21 wd:Q6581072.
  #sorcellerie
  OPTIONAL {
    ?iteme wdt:P1399 wd:Q259745.
    ?iteme wdt:P1399 ?condamnation.
  }
  #nécromancie
  OPTIONAL {
    ?iteme wdt:P1399 wd:Q337935.
    ?iteme wdt:P1399 ?condamnation.
  }
  #bucher
  OPTIONAL {
    ?iteme wdt:P509 wd:Q468455.
    ?iteme wdt:P509 ?deces.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], fr". }
  FILTER((BOUND(?deces))|| (BOUND(?condamnation)))
}

Try it!

requête stricte

SELECT ?iteme ?itemeLabel ?condamnationpourLabel ?condamnationLabel ?mort
WHERE {
  ?iteme wdt:P31 wd:Q5.
  ?iteme wdt:P21 wd:Q6581072.
# condamnée pour "sorcery" ou sous-classe
  ?iteme wdt:P1399/wdt:P279* wd:Q9198102.
  ?iteme wdt:P1399 ?condamnationpour.
  
  OPTIONAL { ?iteme wdt:P1596 ?condamnation . }
  OPTIONAL { ?iteme wdt:P570 ?mort . }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], fr, en". }
}

Try it!

Requetes diverses

Pour mémoire une première requête avec des liens interlangue:

SELECT
  ?item
  ?itemLabel
  ?deathPlaceLabel
  (concat(str(geof:latitude(?coords)), ',', str(geof:longitude(?coords))) as ?latlng)
  (if(?gender = wd:Q6581072, '#993300', '#009933') as ?color)
  (if(BOUND(?linkfr), 'circle', '') as ?symbol)
  (if(BOUND(?linkfr), concat('[[', substr(str(?linkfr),31,500),  '|', ?itemLabel, ']]'), ?itemLabel) 
   as ?title)
  (concat(
    'décès en ', 
    str(YEAR(?death)), 
    ' à ', 
    ?deathPlaceLabel, 
    '\n\n', 
    if(BOUND(?image), concat('[[File:', substr(str(?image), 52, 500), '|200px]]'), ''),
    if (BOUND(?linken), concat(' [[:en:', substr(str(?linken),31,500),  '|(en)]]'), ''),
    if (BOUND(?linkde), concat(' [[:de:', substr(str(?linkde),31,500),  '|(de)]]'), ''),
    if (BOUND(?linkes), concat(' [[:es:', substr(str(?linkes),31,500),  '|(es)]]'), '')
  ) 
   as ?description)
  ('1000' as ?randomise)
  ?linkfr
  ?linkde
  ?linken
  ?linkes
WHERE {
  { ?item wdt:P1399 wd:Q259745. }
  UNION
  { ?item wdt:P1595 wd:Q259745. }
  ?item wdt:P20 ?deathPlace.
  ?deathPlace wdt:P625 ?coords.
  OPTIONAL { ?item wdt:P21 ?gender. }
  OPTIONAL { ?item wdt:P570 ?death. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL {
    ?linkfr schema:about ?item .
    ?linkfr schema:isPartOf <https://fr.wikipedia.org/> .
  }
  OPTIONAL {
    ?linkde schema:about ?item .
    ?linkde schema:isPartOf <https://de.wikipedia.org/> .
  }  
  OPTIONAL {
    ?linken schema:about ?item .
    ?linken schema:isPartOf <https://en.wikipedia.org/> .
  }
  OPTIONAL {
    ?linkes schema:about ?item .
    ?linkes schema:isPartOf <https://es.wikipedia.org/> .
  }  
}

Try it!

supers trucs avec Help:Extension:Kartographer

m:Help:Extension:Kartographer

Supers trucs avec wikidata

Wikidata driven timeline avec Christine de Pizan.

Vive les fotedortografes

SELECT ?item ?itemLabel WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q1984758.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}

Try it!

Une vision ?

SELECT ?item ?itemLabel WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q1682108.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" }
}

Try it!

Ouf !!!

PRATIQUE

Vive geolocator !

Add topic