Wikidata:WikiProject Digital projects of museums/DigAMus Award
Welcome | Digital projects of museums | DigAMus Award | Members |
Datamodel visualization
editGraph
editCreated with draw.io (Q59339175), diagram editor, at https://app.diagrams.net/
- Link to interactive DigAMus datamodel
- Preview screenshot:
Notes
edit- ... add description here ...
- The document is up to date, which includes DigAMus awards from the 2020 and 2021.
Related Projects
editLinks to properties used for awards
edit
ToDo's
editDescribe process of contributing to DigAMus Website, > crowdsourcing process for "reference" of instance of should be clear.
Not done
edit- Add German translation
Doing…
edit- ...
Done
edit- Add DigAMus Award - initial structure
- Add DigAMus Award - Wikidata items
- Add DigAMus Award - Wikidata props
- Add DigAMus Award - Wikidata querys
Withdrawn and reason (discussion link)
edit- ...
Proposals for querys
edit- ...
DigAMus Award - Wikidata items
editDigAMus Award used items
editItem | Main relationship(s) | Description |
---|---|---|
DigAMus Awards (Q106748908) | instance of (P31)museum award (Q93333476) main subject (P921)digital museum project (Q106778540) |
Annual award ceremony for the best digital projects of museums. |
museum award (Q93333476) | subclass of (P279)cultural prize (Q15383322) | award given to a museum |
digital museum project (Q106778540) | subclass of (P279)digital project (Q106777964) | digital project of a museum |
Awards (part of DigAMus Award) used items
editIndividual DigAMus awards | Main relationship(s) | Description |
---|---|---|
DigAMus Award - Podcasts (Q106750737) | part of (P361)DigAMus Awards (Q106748908) | "Podcasts" award for museums digital projects |
DigAMus Award - Apps & Games (Q106762468) | part of (P361)DigAMus Awards (Q106748908) | "Apps & Games" award for museums digital projects |
DigAMus Award - Inklusion & Integration (Q106762500) | part of (P361)DigAMus Awards (Q106748908) | "Inclusion & Integration" award for museums digital projects |
DigAMus Award - Website or Online Exhibition (Q106762510) | part of (P361)DigAMus Awards (Q106748908) | This includes all those projects that are accessible via a website or are designed similarly to a website, e.g. virtual tours, digitorials or even Mozilla Hubs. |
DigAMus Award - Social Media Actions (Q106762529) | part of (P361)DigAMus Awards (Q106748908) | "Social Media Actions" award for museums digital projects |
DigAMus Award - Small budget (Q106762534) | part of (P361)DigAMus Awards (Q106748908) | "Small budget" award for digital projects of museums |
DigAMus Award - Audience Award (Q106762538) | part of (P361)DigAMus Awards (Q106748908) | "Audience Award" for digital projects of museums |
DigAMus Award - Hybrid offer (Q108899914) | part of (P361)DigAMus Awards (Q106748908) | Award for offerings that combine online and offline offerings or digital and analog methods, e.g. an app combined with analog elements in the exhibition space, or digital co-curation elements combined with analog workshops. |
DigAMus Award - Wikidata properties
editDigAMus Award used props
editUsed props | e.g. Wikidata item(s) | or Wikidata data type | Property description |
---|---|---|---|
instance of (P31) | annual event (Q11483816) museum award (Q93333476) award ceremony (Q4504495) group of awards (Q107655869) |
that class of which this subject is a particular example and member; different from P279 (subclass of); for example: K2 is an instance of mountain; volcano is a subclass of mountain (and an instance of volcanic landform) | |
subclass of (P279) | museum award (Q93333476) | this item is a subclass (subset) of that item; all instances of this item are instances of that item; different from P31 (instance of), e.g.: K2 is an instance of mountain; volcano is a subclass of mountain (and an instance of volcanic landform) | |
inception (P571) | Point in time | time when an entity begins to exist; for date of official opening use P1619 | |
country (P17) | Germany (Q183) | sovereign state that this item is in (not to be used for human beings) | |
main subject (P921) | digital museum project (Q106778540) | primary topic of a work (see also P180: depicts) | |
official website (P856) | URL | URL of the official page of an item (current or former). Usage: If a listed URL no longer points to the official website, do not remove it, but see the "Hijacked or dead websites" section of the Talk page | |
described at URL (P973) | URL | item is described at the following URL | |
has part(s) (P527) | DigAMus Award - Podcasts (Q106750737) DigAMus Award - Apps & Games (Q106762468) DigAMus Award - Inklusion & Integration (Q106762500) DigAMus Award - Website or Online Exhibition (Q106762510) DigAMus Award - Social Media Actions (Q106762529) DigAMus Award - Small budget (Q106762534) DigAMus Award - Audience Award (Q106762538) DigAMus Award - Hybrid offer (Q108899914) |
part of this subject; inverse property of "part of" (P361). See also "has parts of the class" (P2670). |
DigAMus Award used identifier props
edit- data type External identifier
Identifier prop | Property description |
---|---|
X username (P2002) | this item's username on X (formerly Twitter); do not include the “@” symbol |
YouTube video ID (P1651) | identifier of a video on YouTube; qualify trailers with "object has role" (P3831)="trailer" (Q622550). For channels, use P2397; for playlists, use P4300 |
Awards (part of DigAMus Award) used props
editUsed properties | Wikidata item(s) | or Wikidata data type | Property description |
---|---|---|---|
instance of (P31) | museum award (Q93333476) | that class of which this subject is a particular example and member; different from P279 (subclass of); for example: K2 is an instance of mountain; volcano is a subclass of mountain (and an instance of volcanic landform) | |
part of (P361) | DigAMus Awards (Q106748908) | object of which the subject is a part (if this subject is already part of object A which is a part of object B, then please only make the subject part of object A), inverse property of "has part" (P527, see also "has parts of the class" (P2670)) | |
awarded for period (P4566) | Point in time | period during which the achievement must have been made to be eligible for an award |
Props to reference DigAMus awards
edit- Properties used by Wikidata items that reference DigAMus awards.
Used properties | Property description | Derived props - inverse property label item (Q65932995) | inverse property (P1696) |
---|---|---|---|
award received (P166) | award or recognition received by a person, organization or creative work | award received by (Q66796038) | - |
participant in (P1344) | event in which a person or organization was/is a participant; inverse of P710 or P1923 | has participant (Q97971204) | participant (P710) |
nominated for (P1411) | award nomination received by a person, organisation or creative work (inspired from "award received" (Property:P166)) | award nominee (Q93874767) | nominee (P2453) |
has part(s) (P527) | part of this subject; inverse property of "part of" (P361). See also "has parts of the class" (P2670). | part of (Q66305721) | part of (P361) |
Properties/qualifiers for ...
editReferences
editProperty | e.g. Wikidata item(s) | or Wikidata data type | Property Description |
---|---|---|---|
stated in (P248) | ... | Item | "to be used in the references field to refer to the information document or database in which a claim is made; for qualifiers use P805; for the type of document in which a claim is made use P3865" |
reference URL (P854) | URL | "should be used for Internet URLs as references. Use "Wikimedia import URL" (P4656) for imports from WMF sites" | |
retrieved (P813) | Point in time | "date or point in time that information was retrieved from a database or website (for use in online sources)" | |
page(s) (P304) | String | "page number of source referenced for statement. Note "column(s)" (P3903) and "folio(s)" (P7416) for other numbering systems" |
URLs
editUsed props | e.g. Wikidata item(s) | or Wikidata data type | Property description |
---|---|---|---|
language of work or name (P407) | German (Q188) | language associated with this creative work (such as books, shows, songs, broadcasts or websites) or a name (for persons use "native language" (P103) and "languages spoken, written or signed" (P1412)) | |
retrieved (P813) | Point in time | date or point in time that information was retrieved from a database or website (for use in online sources) |
Identifier props
edit- used for DigAMus Award
Used props | Property description |
---|---|
start time (P580) | time an entity begins to exist or a statement starts being valid |
number of subscribers (P3744) | number of subscribers for subscription-based companies, e.g. telecommunication companies, newspapers, pay-TV channels, software, etc. |
X numeric user ID (P6552) | numeric identifier for a user on X; use as qualifier for P2002 "X username" |
language of work or name (P407) | language associated with this creative work (such as books, shows, songs, broadcasts or websites) or a name (for persons use "native language" (P103) and "languages spoken, written or signed" (P1412)) |
title (P1476) | published name of a work, such as a newspaper article, a literary work, piece of music, a website, or a performance work |
number of viewers/listeners (P5436) | number of viewers of a television or broadcasting program; web traffic on websites |
publication date (P577) | date or point in time when a work was first published or released |
duration (P2047) | length of time of an event or process |
point in time (P585) | date something took place, existed or a statement was true; for providing time use the "refine date" property (P4241) |
Querys
editAwards part of DigiAMus Award and awarded for period
editSELECT
(?awards AS ?Wikidata_Award_Item)
(?awardsLabel AS ?Award_Name)
(GROUP_CONCAT(YEAR(?awardedForPeriod) ; separator=", ") AS ?awarded_in_years)
WHERE
{
?awards wdt:P361 wd:Q106748908;
wdt:P4566 ?awardedForPeriod.
SERVICE wikibase:label {
bd:serviceParam wikibase:language "de,en".
?awards rdfs:label ?awardsLabel.
}
}
GROUP BY ?awards ?awardsLabel ?awarded_in_years
ORDER BY ?awardsLabel
Projects instance of digital museum project
edit- de: Projekte, die ein digitales Museums Projekt sind
SELECT
(?project AS ?Project_Wd_item_link)
(?projectLabel AS ?Project_name)
WHERE
{
?project wdt:P31 wd:Q106778540.
SERVICE wikibase:label {
bd:serviceParam wikibase:language "de,en".
?project rdfs:label ?projectLabel.
}
}
ORDER BY ?projectLabel
Projects participated in one of DigAMus awards and related year
edit- de: Projekte, die an einen der DigiAMus Awards teilgenommen haben, und das dazugehörige Jahr
# #151 (2023-02-14), 2021 #41, 2020 #111
# info: project Q107168829 participated in 2020 and 2021
SELECT
(?project AS ?Project_Wd_item_link)
(?projectLabel AS ?Project_name)
(GROUP_CONCAT(DISTINCT YEAR(?awardYear); SEPARATOR = ", ") AS ?participated_in_years)
WHERE {
?project (p:P1344|p:P166|p:P1411) ?awardStatement.
?awardStatement (ps:P1344|ps:P166|ps:P1411) ?award;
pq:P585 ?awardYear.
# FILTER((YEAR(?awardYear)) = 2020 ) # filter by year
?award wdt:P361 wd:Q106748908. # part of DigAMus Awards
SERVICE wikibase:label {
bd:serviceParam wikibase:language "de,en".
?project rdfs:label ?projectLabel.
}
}
GROUP BY ?project ?projectLabel
ORDER BY (?participated_in_years) (?Project_name)
Projects that have won one of the DigAMus awards of the respective year
edit- de: Projekte, die einen der DigAMus-Awards des jeweiligen Jahres gewonnen haben
SELECT
(?awardLabel AS ?Award_won)
(YEAR(?awardYear) AS ?Award_year)
(?project AS ?Project_Wd_item_link)
(?projectLabel AS ?Project_name)
WHERE
{
?project p:P166 ?awardStatement.
?awardStatement ps:P166 ?award.
?award wdt:P361 wd:Q106748908.
?awardStatement pq:P585 ?awardYear.
SERVICE wikibase:label {
bd:serviceParam wikibase:language "de,en".
?project rdfs:label ?projectLabel.
?award rdfs:label ?awardLabel.
}
}
ORDER BY ?awardReceivedLabel ?awardYear
Projects nominated for one of the DigAMus awards of the respective year
edit- de: Projekte, die für einen der DigAMus-Awards des jeweiligen Jahres nominiert sind
SELECT
(?awardLabel AS ?Award_nomination)
(YEAR(?awardYear) AS ?Award_year)
(?project AS ?Project_Wd_item_link)
(?projectLabel AS ?Project_name)
WHERE
{
?project p:P1411 ?awardStatement.
?awardStatement ps:P1411 ?award.
?award wdt:P361 wd:Q106748908.
?awardStatement pq:P585 ?awardYear.
SERVICE wikibase:label {
bd:serviceParam wikibase:language "de,en".
?project rdfs:label ?projectLabel.
?award rdfs:label ?awardLabel.
}
}
ORDER BY ?awardNominatedLabel ?awardYear ?projectLabel
Projects participated in one of the DigAMus awards of the respective year
edit- de: Projekte, die für einen der DigAMus-Awards des jeweiligen Jahres teilgenommen haben
SELECT
(?awardLabel AS ?Award_participant_in)
(YEAR(?awardYear) AS ?Award_year)
(?project AS ?Project_Wd_item_link)
(?projectLabel AS ?Project_name)
WHERE
{
?project p:P1344 ?awardStatement.
?awardStatement ps:P1344 ?award.
?award wdt:P361 wd:Q106748908.
?awardStatement pq:P585 ?awardYear.
SERVICE wikibase:label {
bd:serviceParam wikibase:language "de,en".
?project rdfs:label ?projectLabel.
?award rdfs:label ?awardLabel.
}
}
ORDER BY ?awardLabel ?awardYear ?projectLabel
Projects and museums in context
edit- de: Projekte im Kontext mit den Museen
#defaultView:Graph
SELECT ?nodeFrom ?nodeFromLabel ?nodeImage ?rgb ?edgeLabel ?nodeTo ?nodeToLabel ?nodeToImage
WHERE
{
{
SELECT
(?project AS ?nodeFrom)
(?projectImage AS ?nodeFromImage)
("2e86c1" AS ?rgb)
("award received" AS ?edgeLabel)
(?award AS ?nodeTo)
(?awardImage AS ?nodeToImage)
WHERE
{
?project p:P166 ?awardStatement.
?awardStatement ps:P166 ?award.
?award wdt:P361 wd:Q106748908.
OPTIONAL { ?project wdt:P18 ?projectImage. }
OPTIONAL { ?award wdt:P18 ?awardImage. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
}
UNION
{
SELECT
(?project AS ?nodeFrom)
(?projectImage AS ?nodeFromImage)
("2e86c1" AS ?rgb)
("creator" AS ?edgeLabel)
(?creator AS ?nodeTo)
(?creatorImage AS ?nodeToImage)
WHERE
{
?project p:P166 ?awardStatement.
?awardStatement ps:P166 ?award.
?award wdt:P361 wd:Q106748908.
?project wdt:P170 ?creator.
OPTIONAL { ?creator wdt:P18 ?creatorImage. }
OPTIONAL { ?project wdt:P18 ?projectImage. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
}
UNION
{
SELECT
(?award AS ?nodeFrom)
(?awardImage AS ?nodeFromImage)
("ec7063" AS ?rgb)
("part of" AS ?edgeLabel)
(wd:Q106748908 AS ?nodeTo)
(?digamusAwardImage AS ?nodeToImage)
WHERE
{
?project p:P166 ?awardStatement.
?awardStatement ps:P166 ?award.
?award wdt:P361 wd:Q106748908.
OPTIONAL { ?award wdt:P18 ?awardImage. }
OPTIONAL { wd:Q106748908 wdt:P18 ?digamusAwardImage. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
}
UNION
{
SELECT
(?project AS ?nodeFrom)
(?projectImage AS ?nodeFromImage)
("2ecc71" AS ?rgb)
("nominated" AS ?edgeLabel)
(?award AS ?nodeTo)
(?awardImage AS ?nodeToImage)
WHERE
{
?project p:P1411 ?awardStatement.
FILTER ( NOT EXISTS { ?project wdt:P166 [] } )
?awardStatement ps:P1411 ?award.
?award wdt:P361 wd:Q106748908.
OPTIONAL { ?project wdt:P18 ?projectImage. }
OPTIONAL { ?award wdt:P18 ?awardImage. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
}
UNION
{
SELECT
(?project AS ?nodeFrom)
(?projectImage AS ?nodeFromImage)
("2ecc71" AS ?rgb)
("creator" AS ?edgeLabel)
(?creator AS ?nodeTo)
(?creatorImage AS ?nodeToImage)
WHERE
{
?project p:P1411 ?awardStatement.
FILTER ( NOT EXISTS { ?project wdt:P166 [] } )
?awardStatement ps:P1411 ?award.
?award wdt:P361 wd:Q106748908.
?project wdt:P170 ?creator.
OPTIONAL { ?creator wdt:P18 ?creatorImage. }
OPTIONAL { ?project wdt:P18 ?projectImage. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
Sources
edit- ...