Wikidata:WikiProject France/Administrations

Cette page explore les administrations publiques en France.

Les administrations publiques en France sont des organisations. Pour les décrire, il faut se référer au projet Organisations.

Sur la French Wikipedia (Q8447), les informations sur les administrations publiques françaises peuvent être importées avec l'Infobox Organisation2.

Voir aussi Wikidata:WikiProject Govdirectory/France.

Qu'est-ce qu'une administration publique française ?

The following query uses these:

Items: public administration (Q31728)   , France (Q142)

Properties: instance of (P31)   , subclass of (P279)   , country (P17)  
```
SELECT (COUNT(?item) as ?count) 
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  ?item (wdt:P31/(wdt:P279*)) wd:Q31728;
    wdt:P17 wd:Q142.}
```

Try it!

Identification des administrations publiques

Les administrations françaises peuvent être identifiées comme des administrations publiques (public administration (Q31728)) situées en France :

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  ?item (wdt:P31/(wdt:P279*)) wd:Q31728;
    wdt:P17 wd:Q142.
}
ORDER BY ?itemLabel

Try it!

On peut aussi identifier les éléments dont la nature est une sous classe de public administration of France (Q2824642) :

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  ?item (wdt:P31/(wdt:P279*)) wd:Q2824642.
}
ORDER BY (?itemLabel)

Try it!

Administrations d'État

Les administrations d'État sont identifiées sur Wikidata, soit comme des filiales (has subsidiary (P355)), soit comme des parties (has part(s) (P527)) de Government of France (Q1450662).

SELECT DISTINCT ?item ?itemLabel WHERE {
  wd:Q1450662 ((wdt:P355*)/(wdt:P527*)) ?item.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY (?itemLabel)

Try it!

Résumé

SELECT ?label ?count
WITH {
  SELECT DISTINCT (COUNT(?item) as ?count) WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q2824642.
  }
} AS %sub
WITH {
   SELECT DISTINCT (COUNT(?item) AS ?count) WHERE { 
    ?item (wdt:P31/(wdt:P279*)) wd:Q31728;
      wdt:P17 wd:Q142.
   } 
} AS %all
WITH {
  SELECT (COUNT(?item) as ?count) WHERE {
    wd:Q1450662 ((wdt:P355*)/(wdt:P527*)) ?item.
  }
} AS %etat
WHERE { 
  {
  INCLUDE %all
  BIND("Aministrations publiques en France" as ?label) 
  }
  UNION 
  {
  INCLUDE %sub    
  BIND("Aministrations publiques françaises" as ?label) 
  }
  UNION 
  {
  INCLUDE %etat    
  BIND("Administrations d'Etat" as ?label) 
  }
}
ORDER BY DESC(?count)

Try it!

Propriétés

Propriétés générales

Nature de l'élément instance of (P31)

Hiérarchie des sous classes d'administration publique française

#defaultView:Tree
SELECT ?root ?rootLabel 
        ?level1 ?level1Label 
        ?level2 ?level2Label  
        ?level3 ?level3Label 
        ?level4 ?level4Label 
        ?level5 ?level5Label 
        ?level6 ?level6Label 
        ?level7 ?level7Label 
        ?level8 ?level8Label 
        ?level9 ?level9Label 
  WHERE {
  BIND(wd:Q2824642 AS ?super)
  ?level1 wdt:P279 ?super.
  OPTIONAL {
    ?level2 wdt:P279 ?level1. 
    OPTIONAL {
      ?level3 wdt:P279 ?level2.
          OPTIONAL {
            ?level4 wdt:P279 ?level3.
            OPTIONAL {
              ?level5 wdt:P279 ?level4.
              OPTIONAL {
                ?level6 wdt:P279 ?level5.
                OPTIONAL {
                  ?level7 wdt:P279 ?level6.
                  OPTIONAL {
                    ?level8 wdt:P279 ?level7.
                      OPTIONAL {
                      ?level9 wdt:P279 ?level8.
                     }
                   }
                 }
               }
             }
          }
      }
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!

Pays souverain country (P17)

Toutes les administrations françaises devraient avoir comme valeur de country (P17) doit être France (Q142).

Liste des administrations d'État sans valeur de P17

SELECT ?item ?itemLabel WHERE {
  wd:Q1450662 ((wdt:P355*)/(wdt:P527*)) ?item.
  FILTER(NOT EXISTS { ?item wdt:P17 ?country. })
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY (?itemLabel)

Try it!

Autres propriétés générales

headquarters location (P159)
parent organization (P749)
has subsidiary (P355)
part of (P361)
has part(s) (P527)
director / manager (P1037) avec start time (P580) et end time (P582). On peut utiliser l'annuaire du service public pour trouver le nom du dirigeant et le site jorfsearch pour retrouver les dates de nomination dans le journal officiel.
- liste des dirigeants
official website (P856)
external data available at URL (P1325) pour les portails open data

Wikidata:WikiProject France/Administrations

Contents

Qu'est-ce qu'une administration publique française ?

Identification des administrations publiques

Administrations d'État

Résumé

Propriétés

Propriétés générales

Nature de l'élément instance of (P31)

Hiérarchie des sous classes d'administration publique française

Pays souverain country (P17)

Liste des administrations d'État sans valeur de P17

Autres propriétés générales

Identifiants