Wikidata:WikiProject Indonesia/Kueri

WikiProject Indonesia

Beranda

Diskusi

Kegiatan

Topik

Kueri

Halaman ini diperuntukkan bagi kueri-kueri maupun permintaan kueri terhadap butir-butir bertopik Indonesia. Lihat pula halaman Wikidata:SPARQL query service/queries serta Wikidata:SPARQL query service/queries/examples untuk contoh-contoh kueri lainnya.

Punya kueri-kueri menarik lainnya? Silakan +topik baru.

Ingin membuat permintaan kueri tertentu? Silakan sampaikan di halaman pembicaraan.

Perpustakaan di Indonesia

#defaultView:Map
SELECT ?item ?itemLabel ?geo
WHERE 
{
  ?item wdt:P31 wd:Q7075;
        wdt:P17 wd:Q252;
        wdt:P625 ?geo;
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id,en". }
}

Try it!

Daerah administratif

Provinsi

https://w.wiki/WgM

Pernyataan yang digunakan adalah instance of (P31) bernilai province of Indonesia (Q5098). Kueri juga dilakukan terhadap coordinate location (P625) dan OpenStreetMap relation ID (P402).

SELECT ?Jakarta ?JakartaLabel ?coordinate_location ?OSM_relation_ID WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  ?Jakarta wdt:P31 wd:Q5098.
  OPTIONAL { ?Jakarta wdt:P625 ?coordinate_location. }
  OPTIONAL { ?Jakarta wdt:P402 ?OSM_relation_ID. }
}
LIMIT 100

Try it!

Kabupaten dan kota

Keseluruhan

https://w.wiki/hzW

Kueri dibuat terhadap second-level administrative country subdivision in Indonesia (Q12479774).

SELECT ?Butir ?ButirLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  ?Butir (wdt:P31/(wdt:P279*)) wd:Q12479774.

}
LIMIT 700

Try it!

Untuk daerah tertentu, silakan ganti Q12479774 dengan butir lain seperti:

• Kabupaten saja: regency of Indonesia (Q3191695)
• Kota saja: city of Indonesia (Q3199141)

Kasus untuk DKI Jakarta

DKI Jakarta tidak memiliki kabupaten maupun kota namun memiliki administrative regency of Indonesia (Q11127777) dan administrative city of Indonesia (Q4272761). Untuk menambahkan kedua butir dengan nilai-nilai tersebut, gunakan kueri berikut.

https://w.wiki/h$s

# seluruh kabupaten dan kabupaten administratif
SELECT distinct ?Butir ?ButirLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  {
    {?Butir wdt:P31 wd:Q3191695.}
    UNION
    {?Butir wdt:P31 wd:Q11127777.}
  }
}

Try it!

Gunakan administrative city of Indonesia (Q4272761) untuk kota administratif.

Provinsi tertentu

Contoh yang dipakai di sini adalah North Sumatra (Q2140): https://w.wiki/hzp

SELECT ?Butir ?ButirLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  ?Butir (wdt:P31/(wdt:P279*)) wd:Q12479774.
  ?Butir wdt:P131 wd:Q2140.
}
LIMIT 100

Try it!

Kecamatan

Kueri dilakukan terhadap third-level administrative country subdivision in Indonesia (Q26262476): https://w.wiki/i7x. Disarankan menggunakan limit karena jumlah kecamatan yang banyak mungkin akan memperlambat komputer Anda ketika kueri diproses.

SELECT ?Butir ?ButirLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  ?Butir (wdt:P31/(wdt:P279*)) wd:Q26262476;
}
LIMIT 300

Try it!

Untuk daerah tertentu, dapat menambahkan located in the administrative territorial entity (P131) dengan nilai yaitu butir provinsi atau kabupaten/kota. Contoh berikut ini untuk Daerah Istimewa Yogyakarta (Q3741).

SELECT distinct ?Butir ?ButirLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  ?Butir (wdt:P31/(wdt:P279*)) wd:Q26262476.
  ?Butir (wdt:P131/(wdt:P131+)) wd:Q3741.
}

Try it!

Perhatikan bahwa distinct digunakan untuk membuat butir-butir pada hasil hanya muncul satu kali. Hal ini terkait penggunaan notasi + untuk membuat kueri mudah diganti antara provinsi dan kabupaten/kota serta terkait beberapa butir yang memiliki nilai located in the administrative territorial entity (P131) lebih dari satu yaitu kabupatennya dan provinsinya.

Kelurahan, desa, dan daerah setingkat lainnya

Kueri serupa dengan kecamatan, namun diganti dengan fourth-level administrative division in Indonesia (Q2225692).

SELECT distinct ?Butir ?ButirLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
  ?Butir wdt:P31/wdt:P279* wd:Q2225692.
  ?Butir wdt:P131/wdt:P131+ wd:Q3741.
}
LIMIT 100

Try it!

Perhatikan bahwa ada peluang tidak seluruh daerah kelurahan/desa/setingkatnya muncul pada hasil karena suatu butir bisa menggunakan nilai village (Q532) yang merupakan definisi desa secara umum. Nilai yang seharusnya digunakan pada suatu butir mengenai desa/kelurahan/daerah setingkat lainnya adalah subkelas-subkelas dari fourth-level administrative division in Indonesia (Q2225692) di antaranya seperti kelurahan (Q965568), village in Indonesia (Q26211545), gampong (Q4285979), kampung of Papua (Q12488913), pekon (Q19944049), kampung (Q12488911), nagari (Q882149), dan Q97202782. Kemungkinan masih ada jenis daerah setingkat desa lainnya yang belum didaftarkan sebagai subkelas dari Q2225692.

Anggota DPR Jabatan Periode 2019-2024

Kueri dibawah ini digunakan untuk menampilkan anggota-anggota DPR dalam jabatan periode 2019-2024. Kueri dibuat terhadap Member of the People's Representative Council of Indonesia (Q21328632).

SELECT ?anggotaDPR ?anggotaDPRLabel ?awalMenjabat ?daerahPemilihanLabel
WHERE 
{
  ?anggotaDPR wdt:P39 wd:Q21328632. 
  ?anggotaDPR p:P39[ps:P39 wd:Q21328632;
                          pq:P580 ?awalMenjabat;
                          pq:P768 ?daerahPemilihan;].
  FILTER(YEAR(?awalMenjabat)>=2019)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
}ORDER BY ?anggotaDPRLabel

Try it!

Jumlah Anggota DPR Jabatan Periode 2019-2024 untuk Setiap Daerah Pemilihan

Kueri ini digunakan untuk menampilkan jumlah anggota DPR jabatan periode 2019-2024 di dalam setiap daerah pemilihan. Kueri dibuat terhadap Member of the People's Representative Council of Indonesia (Q21328632).

SELECT ?daerahPemilihanLabel (COUNT(?anggotaDPR) AS ?anggota)
WHERE 
{
  ?anggotaDPR wdt:P39 wd:Q21328632. 
  ?anggotaDPR p:P39[ps:P39 wd:Q21328632;
                          pq:P580 ?awalMenjabat;
                          pq:P768 ?daerahPemilihan;].
  FILTER(YEAR(?awalMenjabat)>=2019)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id". }
}
GROUP BY ?daerahPemilihanLabel
ORDER BY ?daerahPemilihanLabel

Try it!

Indonesian Legislative Election

#defaultView:Timeline
SELECT ?pemilu ?pemiluLabel ?waktu
WHERE {
  ?pemilu wdt:P31 wd:Q24567296;
          wdt:P17 wd:Q252;
          wdt:P585 ?waktu.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "id,en". }
}
ORDER BY ASC(?waktu)

Try it!

Population of countries sharing a border with Indonesia

#defaultView:LineChart
SELECT ?country ?year ?population ?countryLabel WHERE {
  {
    SELECT ?country ?year (AVG(?population) AS ?population) WHERE {
      {
        SELECT ?country (str(YEAR(?date)) AS ?year) ?population WHERE {
          ?country wdt:P47 wd:Q252;   # shares border with Indonesia
                   p:P1082 ?populationStatement.
          ?populationStatement ps:P1082 ?population;
                               pq:P585 ?date.
        }
      }
    }
    GROUP BY ?country ?year
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Items that are only exist in Indonesian Wikipedia

SELECT ?item ?title ?article WHERE {
  ?item wikibase:sitelinks 1;
        ^schema:about ?article .
  ?article schema:isPartOf <https://id.wikipedia.org/>; schema:name ?title .
  MINUS { ?item wdt:P31 wd:Q4167836 }
}

Try it!

72528 results

Thanks Matěj Suchánek.

Leksem Indonesia

Indonesian nouns (noun (Q1084))

SELECT ?l ?lemma WHERE {
  ?l a ontolex:LexicalEntry ; dct:language wd:Q9240 ; wikibase:lexicalCategory wd:Q1084 ; wikibase:lemma ?lemma .
}

Try it!

Indonesian verbs (verb (Q24905))

SELECT ?l ?lemma WHERE {
  ?l a ontolex:LexicalEntry ; dct:language wd:Q9240 ; wikibase:lexicalCategory wd:Q24905 ; wikibase:lemma ?lemma .
}

Try it!

Indonesian adjectives (adjective (Q34698))

SELECT ?l ?lemma WHERE {
  ?l a ontolex:LexicalEntry ; dct:language wd:Q9240 ; wikibase:lexicalCategory wd:Q34698 ; wikibase:lemma ?lemma .
}

Try it!

Get all existing Indonesian lexemes

The following query uses these:

• Items: Indonesian (Q9240)   

  SELECT ?lexeme ?lemma ?category ?categoryLabel WHERE {
    ?lexeme dct:language wd:Q9240; 
            wikibase:lemma ?lemma;
            wikibase:lexicalCategory ?category;
            wikibase:lemma [].
    FILTER(LANG(?lemma) = "id")
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ml". }
  }
  ORDER BY ?categoryLabel ?lemma
  LIMIT 100
  

Try it!

Ordered by newest to oldest creation time

The following query uses these:

• Items: Indonesian (Q9240)   

  SELECT ?lno ?lexeme ?lemma ?category ?categoryLabel WHERE {
    ?lexeme dct:language wd:Q9240; 
            wikibase:lemma ?lemma;
            wikibase:lexicalCategory ?category .
    FILTER(LANG(?lemma) = "id")
    BIND(xsd:integer(substr(str(?lexeme), 33)) as ?lno)
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ml". }
  }
  ORDER BY DESC(?lno)
  LIMIT 100
  

Try it!

Uses date last modified

The following query uses these:

• Items: Indonesian (Q9240)   

  SELECT ?lexeme ?lemma ?modified
  WHERE {
     ?lexeme dct:language wd:Q9240; wikibase:lemma ?lemma; schema:dateModified ?modified.
  }
  ORDER BY DESC(?modified)
  LIMIT 100
  

Try it!

Get the count of lexemes in Indonesian belonging to different lexical categories

The following query uses these:

• Items: Indonesian (Q9240)   

  SELECT ?category ?categoryLabel (count(?category) as ?count) WHERE {
    ?lexeme dct:language wd:Q9240; 
            wikibase:lexicalCategory ?category;
            wikibase:lemma [].
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ml". }
  }
  GROUP BY ?category ?categoryLabel
  ORDER BY ?count
  

Try it!

Daftar tokoh Indonesia yang ditulis sebagai telah meninggal di Wikipedia namun tidak memiliki pernyataan date of death (P570)

• Dikueri menggunakan PetScan -> Lihat