Wikidata talk:Events/AAFSaintÉ19

Wikidata en pratique

Ouvrir un compte professionnel Wikidata

Il est très recommandé d'ouvrir un compte Wikidata (voir marche à suivre) pour contribuer.

Si vous disposez déjà d'un compte Wikipédia/Wikimedia, alors vous pourrez utiliser celui-ci sans en créer un nouveau.

Les contributions aux projets Wikimedia ne peuvent qu'être individuelles. Un compte par institution n'est pas souhaité. Par contre, il est tout à fait admis de disposer de deux comptes : l'un profesionnel et l'autre privé. Pour votre compte professionnel, nous vous déconseillons de mettre le nom de votre institution dedans. Disposer d'un pseudo profesionnel neutre vous permettra de le conserver même si vous changez d'institution.

Modifier les préférences

Une fois votre compte créé, il y a des outils qui vont vous faciliter la vie et que vous devez aller spécifier dans vos préférences pour en disposer de l'accès.

• Resonator est une interface de consultation de base pour Wikidata. Vous pouvez disposer d'un lien direct vers celle-ci depuis le menu à gauche de n'importe quel élément Wikidata en cochant cette fonctionalité parmi les gadgets. Il faut donc aller dans vos préférences (en haut à droite de la page une fois loggé), puis se rendre à l'onglet "Gadget" et enfin cocher sous "outils pour Wikidata" la 18e option à savoir "Reasonator: Ajoute un lien à Reasonator sur chaque élément". Ne pas oublier de cliquer sur "Enregistrer les préférences" après modification de celles-ci.
• DuplicateReferences est un outil qui vous permettra de copier/coller en un simple clic les références que vous avez donné à une déclaration dans d'autres sur la même page. Il faut donc aller dans vos préférences (en haut à droite de la page une fois loggé), puis se rendre à l'onglet "Gadget" et enfin cocher sous "outils pour Wikidata" la 26e option à savoir "DuplicateReferences: Ajoute un lien pour copier les références et les ajouter aux autres déclarations d'un même élément". Ne pas oublier de cliquer sur "Enregistrer les préférences" après modification de celles-ci.
  Utilisation:

1. ajouter une référence;
2. rafraîchir la page;
3. ouvrir la référence voulue;
4. cliquer sur l'indication "copier";
5. cliquer sur "coller la référence" face sur les endroits où l'on souhaite copier la référence sans ouvrir la partie référence de ces dernières.

• currentDate est un outil qui génère directement la date du jour lorsque vous choissisez le propriété retrieved (P813). Il faut donc aller dans vos préférences (en haut à droite de la page une fois loggé), puis se rendre à l'onglet "Gadget" et enfin cocher sous "outils pour Wikidata" la 30e option à savoir "currentDate: Automatically adds the date of today while using the property date de consultation (P813)". Ne pas oublier de cliquer sur "Enregistrer les préférences" après modification de celles-ci.
• EasyQuery, qui permet de rapidement créer des requêtes pour des éléments semblables a celui considère (et de passer par une navigation graphique a partir de cet élément).
• The Brown Tool, qui permet d'ajouter automatiquement une déclaration pré-enregistrée. Explication pour l'installation sur la page WikiTools Edit Item (c'est juste un copier-coller d'une phrase). Pour l'utilisation il suffit d'enregistrer sa déclaration pré-définie ex:P485 Q2860507 pour Archivé par les Archives départementales des Yvelines.

Créer un nouvel élément Wikidata

Voir le tutoriel pour éditer un élément et suivre la liste des propriétés recommandées.

BnF to Wikidata : outil récemmment mis en place pour importer automatiquement les données d'autorité du catalogue de la BNF. Voir en ligne.

IdRef to Wikidata : outil similaire au premier permettant d'importer automatiquement les données d'autorité du SUDOC, Voir en ligne.

Ajouter une nouvelle déclaration à un élément Wikidata

Voir le tutoriel pour éditer une déclaration

Ajouter une propriété "archivé par" pour un élément

Le principe est assez simple.

Une institution qui conserve des archives souhaite habituellement donner une bonne visibilité à ses collections. Cela fait partie souvent de ses missions. La base de données en ligne Wikidata est un très bon moyen pour le faire et elle offre un moyen assez simple d'y parvenir.

Il suffit d'ajouter un lien entre un élément représentant une personne et celui représentant l'institution qui conserve ses archives. Cela se réalise le plus aisément au moyen de la propriété archives at (P485).

Plusieurs institutions en ont déjà compris l'intérêt (voir la liste plus bas).

Voici une rapide explication de comment faire :

• Recommandation : ouvrir un compte Wikidata (voir partie dédiée).
• Point de départ : L'institution dont on cherche à mettre en valeur les collections doit disposer d'un élément qui la représente dans Wikidata. Il faut donc faire une première recherche dans Wikidata (comme pour situation A plus bas) et créer cet élément s'il n'existe pas (voir situation B plus bas) en suivant la liste des propriétés suggérées.
• Situation A : on cherche (voir marche à suivre) et trouve sur Wikidata une notice d'un personne physique ou morale dont l'institution qui nous intéresse conserve les archives. Elle peut alors ajouter une déclaration (voir marche à suivre) dont la propriété serait archives at (P485) et suivre les bonnes pratiques pour l'utilisation de cette propriété.
• Situation B : la personne physique ou morale dont on souhaiterait signaler l'existence des archives dans l'institution de notre choix n'existe pas dans Wikidata. Il faut alors:
  1. créer un nouvel élément qui la représente (voir marche à suivre);
  2. puis lui ajouter une déclaration dont la propriété serait archives at (P485) (voir situation A).

Pour aller plus loin : il est possible d'introduire des modifications en masse dans Wikidata (voir partie dédiée).

Imports de masse

Il y a plusieurs moyens de faire des imports de masse dans Wikidata. Nous en présentons quelques uns ici :

• via CSV avec Quickstament

Tableur structuré en vue d'un import dans Wikidata via Quickstatement 2

Fichier CSV structuré en vue d'un import dans Wikidata via Quickstatement 2

Si l'élément personne existe déjà alors, on peut préparer un fichier CSV et l'importer au travers de l'application Quickstatement (version 2) (voir marche à suivre attention pas tout à fait à jour en particulier sur les imports CSV).

Le formatage devra être identique à l'exemple présent dans les images ci-jointes.

Le fichier CSV doit être ouvert dans un éditeur de texte simple, puis copié dans l'interface de saisie prévue pour cela.

Attention : il est nécessaire d'être loggé pour cela (en haut à droite dans l'interface de saisie).

• OpenRefine

OpenRefine qui permet pour la situation A de vérifier si des autorités sont déjà présentes dans Wikidata (voir tutoriel (en anglais)) et pour la situation B d'introduire une nouvelle propriété de façon automatisée dans une liste d'éléments (voir tutoriel (en anglais)).

• à partir d'un fichier XML-EAC

Réflexions en cours (voir page dédiée).

Pourquoi les archivistes devraient utiliser Wikidata ?

Nos ateliers vous proposent de partir de deux hypothèses :

1. Les archivistes devraient utiliser Wikidata ;
2. Les archivistes devraient pouvoir utiliser Wikidata dans le cadre de leur travail salarié.

Nous allons tenter de développer un peu ici nos arguments.

Vis-à-vis des missions

L'utilisation de Wikidata peut soutenir les archivistes dans les missions suivantes :

Collecte

• Archives privées. Dans le cadre de la collecte d'archives privées, Wikidata peut offrir un outil de veille très puissant. Voir à ce propos certaines requêtes SPARQL adaptées à ce sujet.
• Archives publiques. Wikidata peut offir là aussi un outil de veille sur l'historique des transformations institutionnelles (changement de nom des services, etc.).

Description

• Partage des autorités. La question du partage des notices d'autorité est un "serpent de mer" dans le monde des institutions patrimoniales. Nous avançons que les outils Wikimedia seraient une solution à cette question et en particulier Wikidata. Les gains en terme de mutualisation des efforts sur les autorités disposant d'une certaine notoriété est fantastique et inégalable car il introduit l'élément décrit dans un réseau de relations plus vastes. Voir à ce propos les recommandations sur la description de notices d'autorité concernant les archives dans Wikidata.
• Contrôle qualité. Entreprendre un projet d'import de données dans Wikidata est une façon très stimulante de relire ses données. Cela ne manquera pas d'en faire apparaître les erreurs ou les manques. Ce travail a donc aussi des vertus en terme de contrôle qualité.
• Formation continue. L'import de données provenant d'inventaires d'archives dans Wikidata permet de se familiariser avec les principes des données ouvertes liées qui sont au coeur de la nouvelle norme de description Records in Contexts.

Diffusion

C'est l'aspect le plus évident.

• Visibilité. Les plateformes Wikimedia sont parmi les 10 sites internet les plus consultés au monde. Il semble évident que l'impact en terme de diffusion est dès lors massif si on les utilise. Par ailleurs, S'il existe près de 300 Wikipedia (un par langue), il n'existe qu'une Wikidata (vu qu'elle est multilingue). En ce sens, l'utilisation de Wikidata permet de garantir un rapport effort/résultat très bon. Voir l'exemple de l'utilisation de la propriété "archivé par" pour cela.
• Recherche. Le langage de requête SPARQL (voir l'introduction ci-dessous) permet d'effectuer, en particulier sur les autorités, des recherches d'une précision jamais atteinte par les moteurs de recherches des institutions patrimoniales.

Valorisation

Disposer de données exposées en RDF et interrogeables via le langage SPARQL permet de disposer d'une base de réutilisation infinie de ces dernières. L'utilisation de Wikidata permet d'atteindre cela à moindre coût. Les exemples de réutilisation de ces données sont nombreux et vont se multiplier encore assurément.
On peut citer les exemples de :

• Reasonator qui est l'interface de consultation par défaut de Wikidata.
• Crotos pour les oeuvres d'art;
• Astrolabe Explorer;
• Wikidata Card Game Generator;
• ou encore le très bon article de Beat Estermann sur le sujet (en anglais) "How Wikidata Is Solving Its Chicken-or-Egg-Problem in the Field of Cultural Heritage.

Vis-à-vis du travail salarié

Wikidata pourrait être reconnu comme un outil de travail pour les archivistes par leur direction.

L'enrichissement collectif est profitable à tous, c'est pourquoi les institutions patrimoniales publiques ont intérêt à encourager la participations de leurs agents dans le cadre de leurs activités salariés car cela corresponderait à leurs missions.

Plusieurs exemples d'archivistes utilisant les outils Wikimedia dans le cadre de leurs travaux salariés existent, en Suisse entre autres. En France, les Archives nationales (Q182542), ou encore les Departmental archives of Hérault (Q19606442) sont partenaires de Wikimedia France (Q8423370), et vont même accueillir des Wikipédiens en résidence. Mais la participation des services d'archives peut tout aussi bien se faire hors cadre de convention. Le travail d'enrichissement d'une base telle que Wikidata doit être envisagé comme une partie du travail scientifique et de promotion des fonds dont les archivistes sont en charge.

Pour aller plus loin, on peut aussi se référer à certaines analyses (dont un billet du blog de calimaq) sur le rôle de l'État vis-à-vis du commun numérique.

SPARQL (introduction)

SPARQL, quoi ?

SPARQL est le langage qu'il faut utiliser si on veut faire des recherches enrichies dans Wikidata.

Il s'agit d'un langage de requête (interrogation, mais aussi modification) qui n'est pas spécifique à Wikidata, mais adapté aux base de données RDF (c'est-à-dire contenant des données organisées sous forme de triplet "sujet prédicat objet" qui établissent des graphes). C'est l'équivalent du langage SQL pour les bases de données classiques.

Même si ce langage est très puissant, on peut très bien commencer par en faire une utilisation très simple. Toutefois comme tout langage de requête, il est très sensible à la syntaxe. Une faute minime peut faire échouer la recherche. Par ailleurs, l'autre grand difficulté avec SPARQL c'est qu'il faut bien connaître la structuration des données dans la (ou les) base de données interrogées.

Une interface adaptée à Wikidata

Heureusement, les équipes de Wikimedia ont choisi d'utiliser une interface de rédaction de requête SPARQL (basée sur le logiciel libre Blazegraph) qu'ils ont adaptée spécifiquement à Wikibase (le logiciel qui fait fonctionner Wikidata) et qui dispose de beaucoup d'aide à la rédaction. Cette interface s'appelle Wikidata Query Service (WDQS).

L'interface est accessible par le menu à gauche de l'interface Wikidata sous le nom de "Query Service" (voir en ligne).

Cette interface de recherche est très riche. Nous vous renvoyons à la documentation complète à son sujet qui comporte aussi des guides pour débuter.

Pour notre part, nous allons vous donner ici un bref retour d'expérience dont nous avons tiré quelques conseils pour débuter l'apprentissage de SPARQL.

Quelques tutoriels

Quelques références précieuses:

• La video d'introduction (en anglais) publiée en 2018 par Ijon.
• L'ouvrage en français Q61897319 qui base ses exemples justement sur Wikidata et les requêtes SPARQL au sein du WDQS.

Et si on se lançait ?

Voici quelques conseils pour se lancer dans le rédaction de requête :

1. Partir toujours d'une première requête proposée parmi les exemples donnés dans le menu "Exemples" en haut de l'interface WDQS (par exemple celle sur les chats). Cela donne une base propre et ajoute une ligne ("SERVICE wikibase:label"(...)) pour spécifier la langue d'affichage des résultats qui sera par défaut celle utilisée par votre navigateur.
2. Renoncer au panneau gauche intitulé "Assistant de requête" en le repliant grâce à la petite croix en haut à droite de ce panneau. C'est un conseil qui vient de la vidéo de Ijon. Ce mode de travail en WYSIWYG ne vous permettra pas de comprendre le langage et donc d'avoir le plaisir d'imaginer de nouvelles requêtes.
3. Toujours essayer d'écrire (au moyen de phrase commençant par # pour que cela ne soit pas confondu avec les termes de la requête) ce que l'on essaie de faire. C'est un bon moyen de voir où ça commence à clocher.
4. copier/coller et adapter des requêtes déjà existantes. Vous en trouverez une série ici même adaptées au contexte archivistique, mais il en existe sinon de nombreuses accessibles en suivant le boutton "Aide" puis "Exemples de requêtes" en haut de l'interface WDQS. Une recherche par Ctrl+F dans la page avec une fonction ou un thème sera très efficace.
5. Dans WDQS, les erreurs possibles sont princiaplement de deux ordres : une erreur de syntaxe qui sera tout de suite signalée ou un timeout, c'est-à-dire une limite de temps définie au-delà de laquelle la requête adressée est rejetée (environ une minute). Les timeout proviennent du fait que les données sont nombreuses dans Wikidata. Il est donc très important de rédiger sa requête en partant de la relation renvoyant le plus petit nombre de données possible. Par exemple, on évitera de partir d'une recherche formulée comme "trouve tous les être humain qui dispose d'une propriété xy ". Il y a plus de 4 millions d'entité "être humain" dans Wikidata (voir statistiques). Le moteur de recherche n'aura pas le temps d'en faire le tour avant que le timeout ne soit écoulé. Il faut donc reformulé en disant "trouve tous les éléments disposant de la relation xy" et il est souvent pas nécessaire de préciser qu'il s'agit d'être humain puisque cette relation ne peut être attachée qu'à eux.
6. En cas d'échec, ne pas hésiter à demander de l'aide sur la page de demande de requête. Elle est accessible en suivant le bouton "Aide" puis "Demande de requête" en haut de l'interface WDQS. Les personnes réagissent vite (maximum 24 heures). Ce service est là pour ça donc pas hésiter à y recourir. Les personnes qui répondent ont d'habitude commencé l'apprentissage SPARQL en demandant des requêtes sur cette même page. Pour garantir d'avoir des réponses rapidement nous vous donnons les conseils suivants :
   • il vaut mieux formuler la demande en anglais (mais un anglais très élémentaire est tout à fait accepté);
   • nous conseillons de donner dans la demande un exemple de la requête qui ne fonctionne pas. Pour afficher la requête dans le demande, il faut l'intégrer dans ces balises {{SPARQL|query= votre requête copiée depuis WDQS }};
   • pour remercier les personnes qui vous ont aidé, il faut les avertir en utilisant les balises suivantes {{ping|pseudo de la personne qui a répondu}};
   • ne pas oublier de signer vos demandes ou réponses grâce au bouton fait pour cela (voir page d'aide à ce sujet);
   • on peut toujours aller lire la syntaxe d'anciennes demandes sur la page "Exemples de requêtes" pour s'en inspirer. Il suffit pour cela de cliquer sur le bouton "modifier" puis "annuler" pour être sûr de n'avoir rien changé par inadvertance.

Pourquoi pas vous ?

L'apprentissage SPARQL passe par beaucoup d'essais/erreurs. Cela peut prendre du temps mais cela en vaut largement la peine, car le nombre d'informations accessibles par ce biais est fantastique.

Si certains archivistes comme nous y sont arrivés, c'est certainement à votre portée !

D'ici au Forum de Saint-Étienne, nous pouvons aussi vous apporter une aide à distance. N'hésitez donc pas à nous transmettre vos demandes à info@glamwiki2019.ch.

SPARQL (exemples de requêtes)

Liste des grandes communes de France avec l'indication de l'institution qui conserve leurs archives

#Les grandes communes de France avec l'institution qui conservent leurs archives.
SELECT DISTINCT ?item ?itemLabel ?pop ?archives ?archivesLabel
WHERE  
{
  ?item wdt:P31/wdt:P279* wd:Q484170;
        wdt:P1376 ?capital;
        wdt:P1082 ?pop.
  FILTER (?pop > 50000)
  OPTIONAL {?item wdt:P485 ?archives.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
ORDER BY DESC (?pop)

Try it!

Liste des institutions

Liste des institutions, connues de Wikidata, qui conservent des archives en France

Relevés :

• 169 (11.03.2019)
• 202 (24.03.2019)
• 206 (01.04.2019)

#Lister tous les éléments connus de Wikidata qui sont des institutions qui conservent des archives
#Et dont le pays de localisation est la France.
#Afficher la commune de localisation si elle est précisée.
#Regrouper les communes s'il en a plusieurs en les séparant par une virgule.
#Présenter par ordre alphabétique de titre de l'institution (les majuscules venant avant les minuscules qui viennent avant les caractères accentués)
SELECT ?item ?itemLabel (GROUP_CONCAT(DISTINCT(?LieuLabel); separator=", ") as ?Lieux)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q166118;
        wdt:P17 wd:Q142.
    OPTIONAL {?item wdt:P131 ?Lieu;
      OPTIONAL {?Lieu rdfs:label ?LieuLabel. filter(lang(?LieuLabel)="fr") }       
             }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".}
}
GROUP BY ?item ?itemLabel
ORDER BY ?itemLabel

Try it!

Requête augmentée en présentant leur site internet et leur compte Twitter s'ils sont précisés.

#Lister tous les éléments connus de Wikidata qui sont des institutions qui conservent des archives
#Et dont le pays de localisation est la France.
#Afficher la commune de localisation si elle est précisée.
#Afficher le compte Twitter et le site internet s'ils sont précisés.
#Regrouper les communes s'il en a plusieurs en les séparant par une virgule.
#Présenter par ordre alphabétique de titre de l'institution (les majuscules venant avant les minuscules qui viennent avant les caractères accentués)
SELECT ?item ?itemLabel ?twitter ?siteweb (GROUP_CONCAT(DISTINCT(?LieuLabel); separator=", ") as ?Lieux)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q166118;
        wdt:P17 wd:Q142.
    OPTIONAL {?item wdt:P2002 ?twitter .}
    OPTIONAL {?item wdt:P856 ?siteweb .}
    OPTIONAL {?item wdt:P131 ?Lieu;
      OPTIONAL {?Lieu rdfs:label ?LieuLabel. filter(lang(?LieuLabel)="fr") }       
             .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".}
}
GROUP BY ?item ?itemLabel ?twitter ?siteweb
ORDER BY ?itemLabel

Try it!

Liste des institutions, connues de Wikidata, qui conservent des archives en France avec le nombre d'éléments dans Wikidata référencés (archivé par) vers elles

SELECT ?institution ?institutionLabel (COUNT(distinct ?item) AS ?total) (GROUP_CONCAT(DISTINCT(?LieuLabel); separator=", ") as ?Lieux) 
WHERE 
{
  ?institution wdt:P31/wdt:P279* wd:Q166118;
               wdt:P17 wd:Q142.
  OPTIONAL {?institution wdt:P131 ?Lieu.
    OPTIONAL {?Lieu rdfs:label ??LieuLabel. filter(lang(?LieuLabel)="fr") }       
           }
  OPTIONAL {
      ?item wdt:P485 ?institution .
           }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".}        
} 
group by ?institution ?institutionLabel
ORDER BY DESC (?total) ?institutionLabel

Try it!

Liste des institutions, connues de Wikidata, qui conservent des archives en France avec le nombre d'éléments dans Wikidata référencés (archivé par) vers elles et qui disposent de moins de 5 éléments référencés

Relevés (le but étant que la liste soit vide au 31 mars 2019) :

• 12.03.2019 : 165 institutions
• 24.03.2019 : 166 institutions
• 26.03.2019 : 142 institutions
• 29.03.2019 : 85 institutions
• 01.04.2019 : 69 institutions

SELECT ?institution ?institutionLabel (COUNT(distinct ?item) AS ?total) (GROUP_CONCAT(DISTINCT(?LieuLabel); separator=", ") as ?Lieux) 
WHERE 
{
  ?institution wdt:P31/wdt:P279* wd:Q166118;
               wdt:P17 wd:Q142.
  OPTIONAL {?institution wdt:P131 ?Lieu.
    OPTIONAL {?Lieu rdfs:label ??LieuLabel. filter(lang(?LieuLabel)="fr") }       
           }
  OPTIONAL {
      ?item wdt:P485 ?institution .
           }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".}        
} 
group by ?institution ?institutionLabel
HAVING (?total < 5)
ORDER BY DESC (?total) ?institutionLabel

Try it!

Version complétée avec la mention du département, la population du département, les identifiants Twitter et le site internet.

SELECT ?institution ?institutionLabel (GROUP_CONCAT(DISTINCT ?twitter; separator=", ") as ?twit) (COUNT(distinct (?item)) AS ?total) (GROUP_CONCAT(DISTINCT(?LieuLabel); separator=", ") as ?Lieux) (GROUP_CONCAT(DISTINCT(?departementLabel); separator=", ") as ?departements)
WHERE 
{
  ?institution wdt:P31/wdt:P279* wd:Q166118;
               wdt:P17 wd:Q142.
    OPTIONAL {?institution wdt:P2002 ?twitter .}
  OPTIONAL {
    ?institution wdt:P131 ?Lieu.
    OPTIONAL {?Lieu rdfs:label ?LieuLabel. filter(lang(?LieuLabel)="fr") }
    ?Lieu wdt:P131 ?departement.
    ?departement wdt:P31 wd:Q6465.
    OPTIONAL {?departement rdfs:label ?departementLabel. filter(lang(?departementLabel)="fr") }
           }
  OPTIONAL {
      ?item wdt:P485 ?institution .
           }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".}        
} 
group by ?institution ?institutionLabel ?lieux ?departements
HAVING (?total < 5)
ORDER BY ?institution

Try it!

Liste des éléments

Liste des éléments dont les documents sont "archivés par" une institution donnée

#afficher tous les éléments (ID, Label, Description), connus de Wikidata, qui dipose de la propriété "archivé par" (P485) pour une institution donnée.
#classer ces derniers par genre ou sexe puis par ordre alphabéthique de Description puis de Label.
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?genreLabel
WHERE {
    ?item wdt:P485 wd:Q2860505. #élément archivé par une institution donnée
  OPTIONAL {?item wdt:P21 ?genre.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,de,nl,en". }
}
ORDER BY ?genreLabel ?itemDescription ?itemLabel

Try it!

Liste complétée par les référentiels (numéro d'inventaire):

#afficher tous les éléments (ID, Label, Description, référentiels), connus de Wikidata, qui dipose de la propriété "archivé par" (P485) pour une institution donnée.
#regouper tous les référentiels dans une même cellule.
#classer les éléments trouvés par genre ou sexe puis par ordre alphabéthique de Description et de Label.
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?genreLabel (GROUP_CONCAT(DISTINCT(?referentiel); separator=", ") as ?referentiels)
WHERE {
    ?item wdt:P485 wd:Q2860505. #élément archivé par une institution donnée
  OPTIONAL {?item wdt:P21 ?genre.}
  OPTIONAL {?item p:P485 ?statement. 
            ?statement ps:P485 ?archives. #option avoir déposé ses archives dans une institution
            OPTIONAL {?statement pq:P217 ?referentiel.} #option avoir pour qualificatif un numéro d'inventaire.
           }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,de,nl,en". }
}
GROUP BY ?item ?itemLabel ?itemDescription ?genreLabel ?referentiels
ORDER BY ?genreLabel ?itemDescription ?itemLabel

Try it!

Autre exemple (merci aux AD des Yvelines) avec les références (URL de la référence, date de consultation):

SELECT DISTINCT ?item ?itemLabel ?itemDescription ?DecritAURL ?NumeroInv ?reference ?date

WHERE {

  ?item wdt:P485 wd:Q2860507.#Les items qui sont archivés par l'institution définie

   OPTIONAL {?item p:P485 ?Institution.#Les items qui ont pour valeur archivés par l'institution définie

     OPTIONAL {?Institution pq:P973 ?DecritAURL; pq:P217 ?NumeroInv.} #Dont l'institution définie peut avoir un qualificatif Décrit à l'URL, Numero d'inventaire

          }

   OPTIONAL {?item p:P485 [ prov:wasDerivedFrom [ pr:P854 ?reference ; pr:P813 ?date ] ] .}#Dont l'institution définie peut avoir une URL de référence, une date de consultation

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

}

Try it!

Classement des institutions

Classement des institutions (dans le monde) par nombre d'éléments "archivés par" elles

#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution
#afficher le pays où est situé l'institution.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel ?paysLabel (COUNT(?item) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution .
  OPTIONAL {?institution wdt:P17 ?pays .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?institution ?institutionLabel ?paysLabel
ORDER BY DESC (?total)

Try it!

Classement des institutions (en France) par nombre d'éléments "archivés par" elles

#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution française
#afficher le lieu où est située l'institution.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel ?lieuLabel (COUNT(?item) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution . #les éléments doivent disposé de la propriété "archivé par" qui renvoie à une institution.
  ?institution wdt:P17 wd:Q142; #l'institution doit être localisée en France
               wdt:P131 ?lieu. #localisation administrative de l'institution
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?institution ?institutionLabel ?lieuLabel
ORDER BY DESC (?total) ?lieuLabel

Try it!

Nouvelle formulation (07.04.2020) qui fusionne les localisations.

#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution française
#afficher le lieu où est située l'institution.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel (GROUP_CONCAT(DISTINCT(?lieuLabel); separator=", ") as ?lieuxLabel) (COUNT(DISTINCT ?item) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution . #les éléments doivent disposé de la propriété "archivé par" qui renvoie à une institution.
  ?institution wdt:P17 wd:Q142; #l'institution doit être localisée en France
               wdt:P131 ?lieu. #localisation administrative de l'institution
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". 
                          ?institution rdfs:label ?institutionLabel.
                          ?lieu rdfs:label ?lieuLabel.}
}
GROUP BY ?institution ?institutionLabel
ORDER BY DESC (?total)

Try it!

Classement des institutions (en France) par nombre d'éléments "archivés par" elles (avec le compteur remis à zéro au 11.03.2019)

#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution française
#introduire un correctif en déduisant le nombre trouvé le 11.03.2019 pour remettre tous les compteurs à zéro.
#afficher le lieu où est située l'institution.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel ?lieuLabel (COUNT(?item) - COALESCE(?subtrahend, 0) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution . #les éléments doivent disposé de la propriété "archivé par" qui renvoie à une institution.
  ?institution wdt:P17 wd:Q142; #l'institution doit être localisée en France
               wdt:P131 ?lieu. #localisation administrative de l'institution
  
  OPTIONAL {
    VALUES (?institution ?subtrahend) {
      (wd:Q182542 593)(wd:Q2860505 113)(wd:Q193563 3)(wd:Q16303821 3)(wd:Q3152115 3)(wd:Q2860516 2)(wd:Q838691 2)(wd:Q273461 2)(wd:Q20670712 1)(wd:Q3075420 1)(wd:Q19833040 1)
      (wd:Q2901309 1)(wd:Q2948151 1)(wd:Q19606447 1)(wd:Q19606436 1)(wd:Q16010742 1)(wd:Q19606442 94)(wd:Q19606454 1)(wd:Q30218775 1)(wd:Q19606460 1)(wd:Q47524704 1)
      (wd:Q1492436 1)(wd:Q2717848 1)(wd:Q18785452 1)(wd:Q2860474 1)(wd:Q2860557 1)(wd:Q2860461 1)(wd:Q1328440 1)(wd:Q2860498 1)(wd:Q202660 1)(wd:Q18213967 1)
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?institution ?institutionLabel ?lieuLabel ?subtrahend
ORDER BY DESC (?total) ?institutionLabel

Try it!

Classement des institutions (en France) par nombre d'éléments (de genre ou sexe féminin) "archivés par" elles

Attention, la déclaration de genre ou de sexe féminin contient parfois la valeur féminin (Q1775415) ce qui est erronée

#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution
#Le pays de rattachement de l'institution doit être la France.
#Les éléments doivent être de genre ou de sexe féminin.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel ?LieuLabel (COUNT(?item) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution;
        wdt:P21 wd:Q6581072.
  ?institution wdt:P17 wd:Q142.
  OPTIONAL {?institution wdt:P131 ?Lieu.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?institution ?institutionLabel ?LieuLabel
ORDER BY DESC (?total)

Try it!

Classement des institutions (en France) par nombre d'éléments (de genre ou sexe féminin) "archivés par" elles (compteurs remis à zéro le 11.03.3019)

#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution
#remettre les nombres à zéro à la date du 11.03.2019.
#Le pays de rattachement de l'institution doit être la France.
#Regrouper les différents lieux
#Les éléments doivent être de genre ou de sexe féminin.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel (GROUP_CONCAT(DISTINCT(?LieuLabel); separator=", ") as ?Lieux) (COUNT(?item) - COALESCE(?subtrahend, 0) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution;
        wdt:P21 wd:Q6581072.
  ?institution wdt:P17 wd:Q142.
  OPTIONAL {
    ?institution wdt:P131 ?Lieu.
     OPTIONAL {?Lieu rdfs:label ?LieuLabel. filter(lang(?LieuLabel)="fr")}
  }
  OPTIONAL {
    VALUES (?institution ?subtrahend) {
      (wd:Q182542 23)(wd:Q2860505 16)(wd:Q838691 2)(wd:Q2901309 1)(wd:Q16010742 1)
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?institution ?institutionLabel ?Lieux ?subtrahend
ORDER BY DESC (?total)

Try it!

Classement des pays

Classement des pays par le nombre d'éléments "archivés par" leurs institutions

#chercher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution
#additionner les résultats par pays
#classer les pays par ordre de nombre d'éléments décroissant.
SELECT ?paysLabel (COUNT(?item) AS ?total)
WHERE 
{
  ?item wdt:P485 ?institution .
  OPTIONAL {?institution wdt:P17 ?pays .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?paysLabel
ORDER BY DESC (?total)

Try it!

Classement des pays par le nombre d'éléments (de sexe ou genre féminin) "archivés par" leurs institutions

SELECT ?country ?countryLabel (COUNT(?item) AS ?total) ?pop
WHERE 
{ 
  ?item wdt:P485 ?institution;
        wdt:P21 wd:Q6581072.
  ?institution wdt:P17 ?country.
  OPTIONAL {?country wdt:P1082 ?pop.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?country ?countryLabel ?pop
ORDER BY DESC (?total)

Try it!

Listes archives, genre et domaine public

1

# liste des personnes, connues de Wikidata, de sexe ou genre féminin nées ou mortes dans un périmètre géographique défini
# qui sont mortes il y a plus de 70 ans (->oeuvres dans le domaine public)
# avec l'affichage de l'institution qui conserve leurs archives
SELECT DISTINCT ?personne ?personneLabel ?personneDescription ?mort ?archives ?archivesLabel
WHERE 
{
  ?personne wdt:P19/wdt:P131*|wdt:P20/wdt:P131* wd:Q3240.#lieu de naissance ou de mort dans un périmètre défini
  ?personne wdt:P21 wd:Q6581072. #de sexe ou genre féminin
  ?personne wdt:P570 ?mort 
  FILTER (year(?mort) < 1948).#morte avant 1948 (2019-71 ans)
  OPTIONAL {?personne wdt:P485 ?archives .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".}
}
ORDER BY ?mort

Try it!

2

# liste des personnes, connues de Wikidata, de sexe ou genre féminin nées ou mortes dans un périmètre géographique défini
# qui sont mortes il y a plus de 70 ans (->oeuvres dans le domaine public)
# avec l'affichage de l'institution qui conserve leurs archives et la référence correspondante.
SELECT DISTINCT ?personne ?personneLabel ?personneDescription ?mort ?archives ?archivesLabel ?inventaire
WHERE 
{
  ?personne wdt:P19/wdt:P131*|wdt:P20/wdt:P131* wd:Q3240.#lieu de naissance ou de mort dans un périmètre défini
  ?personne wdt:P21 wd:Q6581072. #de sexe ou genre féminin
  ?personne wdt:P570 ?mort 
  FILTER (year(?mort) < 1948).#morte avant 1948 (2019-71 ans)
    OPTIONAL {?personne p:P485 ?statement. 
            ?statement ps:P485 ?archives. #option avoir déposé ses archives dans une institution
            OPTIONAL {?statement pq:P217 ?inventaire.} #option avoir pour qualificatif un numéro d'inventaire.
           }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".}
}
ORDER BY ?mort

Try it!

3

# liste des personnes, connues de Wikidata, de sexe ou genre féminin nées ou mortes dans un périmètre géographique défini
# qui sont mortes il y a plus de 70 ans (->oeuvres dans le domaine public)
# avec l'affichage de l'institution qui conserve leurs archives et de leur page Wikipédia en français si elle existe
SELECT DISTINCT ?personne ?personneLabel ?personneDescription ?mort ?archives ?archivesLabel ?articleFr
WHERE 
{
  ?personne wdt:P19/wdt:P131*|wdt:P20/wdt:P131* wd:Q12771.#lieu de naissance ou de mort dans un périmètre défini
  ?personne wdt:P21 wd:Q6581072. #de sexe ou genre féminin
  ?personne wdt:P570 ?mort 
  FILTER (year(?mort) < 1948).#morte avant 1948 (2019-71 ans)
  OPTIONAL {?personne wdt:P485 ?archives .}
  OPTIONAL {
    ?articleFr schema:about ?personne.
    ?articleFr schema:isPartOf <https://fr.wikipedia.org/>.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".}
}
ORDER BY ?mort

Try it!

Liste archives réalisateur film / institution

#Afficher les instutions gardiennes des archives de tous les personnes connues de Wikidata
#qui ont eu pour occupation réalisatrice de film
#sont nées dans les années 20
#ne sont pas mortes
#dont un des films a reçu une distinction à Cannes.
SELECT DISTINCT ?item ?itemLabel ?naissance ?archives ?archivesLabel ?archivesDescription ?filmLabel ?recompenseLabel 
{
  ?item wdt:P106 wd:Q2526255; #un élément dont l'une des occupations est d'être un réalisateur.
        wdt:P569 ?naissance. #date de naissance
  OPTIONAL {?item wdt:P485 ?archives.} #option avoir déposé ses archives dans une institution
  OPTIONAL {?item wdt:P570 ?mort.} #option qu'il ait une date de mort
  FILTER (year(?naissance) > 1920).#être né après 1920
  FILTER (year(?naissance) < 1930).#être né avant 1930
  FILTER (!BOUND(?mort)).#ne pas disposer d'une date de mort
  ?film wdt:P166 ?recompense. #un film ayant reçu une récompense.
  ?film wdt:P57 ?item. #que ce film aille été réalisé par l'élément recherché plus haut.
  ?recompense wdt:P31 wd:Q28444913. #que la récompense soit attribuée par le Festival de Cannes.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en,de,it". }
}
ORDER BY DESC(?archivesLabel) #trier par ordre décroissant de titre d'institution

Try it!

Exemples de requêtes sur du contenu

Liste des participants au Prix de Lausanne (Q673014)

#Participants Prix de Lausanne avec leur nationalité et leur employeur

SELECT ?item ?itemLabel ?citizenshipLabel ?employerLabel  # affiche les résultats de ces labels (en langage id Q ou en langage humain si on ajoute Label au label), on peut aussi préciser ici les item

WHERE
{
	# on trouve dans l'ordre Item Property Value Stop
	?item wdt:P31 wd:Q5 .  # ajouter instance of human
      { ?item wdt:P1344 wd:Q673014 . } # participant à Prix de Lausanne
    UNION
      { ?item wdt:P2522 wd:Q673014 . } # victoire à Prix de Lausanne
	
	OPTIONAL { ?item wdt:P27 ?citizenship } .   # quelle que soit la nationalité, si pas d'Optional, ne s'affiche que si la nationalité est remplie
  	OPTIONAL { ?item wdt:P108 ?employer } .   # afficher l'employeur si connu
	
	SERVICE wikibase:label { bd:serviceParam wikibase:language "es, fr, en, [AUTO_Language]" . } # affiche résultats d'abord en espagnol, puis en français, si non en anglais
}

Try it!

# Informations privées sur les participants au Prix de Lausanne

SELECT ?item ?itemLabel ?genreLabel ?dateofbirthLabel ?dateofdeath ?spouseLabel  # affiche les résultats de ces labels (en langage id Q ou en langage humain si on ajoute Label au label), on peut aussi préciser ici les item

WHERE
{
	# Item Property Value Stop
	?item wdt:P31 wd:Q5 .  # ajouter instance of human
      { ?item wdt:P1344 wd:Q673014 . } # participant à Prix de Lausanne
    UNION
      { ?item wdt:P2522 wd:Q673014 . } # victoire à Prix de Lausanne
	?item wdt:P21 ?genre
	OPTIONAL { ?item wdt:P569 ?dateofbirth } .
  	OPTIONAL { ?item wdt:P570 ?dateofdeath } .
    OPTIONAL { ?item wdt:P26 ?spouse } .   
	
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, en, [AUTO_Language]" . } # affiche résultats d'abord en espagnol, puis en français, si non en anglais
}

Try it!

Carte avec la provenance des participants au Prix de Lausanne (Q673014)

#Provenance des participants au Prix de Lausanne, avec images des danseurs
#defaultView:Map
SELECT ?item ?itemLabel ?citizenshipLabel ?coord ?image WHERE {
  ?item wdt:P31 wd:Q5.
  { ?item wdt:P1344 wd:Q673014. }
  UNION
  { ?item wdt:P2522 wd:Q673014. }
  ?item wdt:P27 ?citizenship.
  ?citizenship wdt:P625 ?coord.
  ?item wdt:P18 ?image.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, [AUTO_LANGUAGE]". }
}

Try it!

Graphique avec la provenance des participants au Prix de Lausanne (Q673014)

#Participants Prix de Lausanne selon leur nationalité, affichage des pays en croate

#defaultView:BubbleChart
SELECT ?citizenshipLabel (COUNT(DISTINCT ?participant) AS ?count) WHERE {
  ?participant wdt:P31 wd:Q5.
  ?participant wdt:P1344 wd:Q673014.
  ?participant wdt:P27 ?citizenship.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hr,fr". }
}
GROUP BY ?citizenshipLabel
ORDER BY DESC(?count)

Try it!

Exemple d'un projet exploitant les données de Wikidata et les images de Wikimedia Commons

• Images des lauréats du Prix de Lausanne (Q673014) sur une ligne du temps : http://histropedia.com/timeline/zgpxtpg9bg0t/Prix-de-Lausanne-winners