Wikidata

User:Mzaki/P1114

< User:Mzaki

quantity (P1114)の用法の整理をしたい。すごい大変そうだけど。

本来quantity (P1114)は項目のインスタンスの総数を表すプロパティなのだが、そこから逸脱した用法がかなり多く存在している。また修飾子としての利用の方がはるかに多い。

in main statement

edit

entity types

edit

Wikibase property (Q29934218)は除外されている。プロパティに対しては、number of records (P4876)を使うことになっている。外部識別子に対して考える場合、意味論上quantity (P1114)が間違っているわけではないと思うが、完全性の統計などはnumber of records (P4876)を使って算出される。

  • MeSH descriptor ID (P486)quantity (P1114)29,524
#title:Properties using P1114
SELECT ?prop ?propLabel ?num WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?prop a wikibase:Property.
  ?prop wdt:P1114 ?num.
}
LIMIT 1000
Properties using P1114

units

edit

単位は必要ないはず。計数基準はcriterion used (P1013)で表現するべき。計数対象はhas part(s) of the class (P2670)やhas part(s) (P527)にquantity (P1114)で修飾する形で表現するべき。ほかにも修飾子で表現すべきところを単位で表現しているものはありそう。 

#title:P1114 statements with units
SELECT ?item ?itemLabel ?st ?val ?unit ?unitLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item p:P1114 ?st.
  ?st psv:P1114 ?v.
  ?v wikibase:quantityAmount ?val.
  ?v wikibase:quantityUnit ?unit.
  FILTER( ?unit != wd:Q199 )
}
ORDER BY ?item
LIMIT 1000
P1114 statements with units

list of qualifiers

edit

quantity (P1114)に対して使われている修飾子の統計: 

#title:Qualifiers for P1114
SELECT DISTINCT ?qual ?qualLabel ?count ?sample ?isAllowed ?isRequired {
  {
    SELECT ?qual (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?statement) AS ?sample) {
      hint:Query hint:optimizer "None" .
      ?item p:P1114 ?statement .
      ?statement ?pq_qual ?pq_obj .
      ?qual wikibase:qualifier ?pq_qual .
    } GROUP BY ?qual
  } .
  OPTIONAL { wd:P1114 p:P2302 [ pq:P2306 ?qual ; ps:P2302 wd:Q21510851 ] . BIND("y" as ?isAllowed) }
  OPTIONAL { wd:P1114 p:P2302 [ pq:P2306 ?qual ; ps:P2302 wd:Q21510856 ] . BIND("y" as ?isRequired ) }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?count) ASC(?qualLabel)
Qualifiers for P1114

用法が明瞭で検討が不要のもの（誤用がないとは限らない）

statement is subject of (P805)

edit

statement is subject of (P805)の本来の用法は、statementと等価な項目へのリンクを提供することであり、statementの解釈には影響がない（statement is subject of (P805)instance of (P31)non-restrictive qualifier (Q61719274)なので）。

Title ID Data type Description Examples Inverse
statement is subject ofP805Item(qualifying) item that describes the relation identified in this statementBarack Obama <statement is subject of> presidency of Barack Obamamain subject
#title:breakdown of P1114 statements qualified with P805
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P1114 ?st .
      ?st pq:P805 ?obj .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
breakdown of P1114 statements qualified with P805 
#title:all usages of P1114 statements qualified with P805
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P805 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P805 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P805

criterion used (P1013)

edit

criterion used (P1013)は

Title ID Data type Description Examples Inverse
criterion usedP1013Itemcriterion: property by which a distinction or classification is madenorth <criterion used> direction-
#title:P1114 statements qualified with P1013
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P1114 ?st .
      ?st pq:P1013 ?obj .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
P1114 statements qualified with P1013

大部分はQ106497152のような感じでユダヤ人関連の統計データの分類基準として使っている。（たぶん1ユーザー） 

#title:some usages of P1114 statements qualified with P1013
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P1013 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P1013 AS ?qual)
  MINUS{ ?item wdt:P31/wdt:P279* wd:Q12483. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
some usages of P1114 statements qualified with P1013

of (P642)

edit

of (P642)は

Title ID Data type Description Examples Inverse
ofP642Item(This property is being deprecated, see details at WD:P642) qualifier stating that a statement applies within the scope of a particular item→ Property talk:P642-
#title:P1114 statements qualified with P642
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P1114 ?st .
      ?st pq:P642 ?obj .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
P1114 statements qualified with P642

electric vehicle charging station (Q2140665)

edit

electric vehicle charging station (Q2140665)の項目で使われている。 

#title:P1114 statements for class Q2140665 qualified with P642
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item wdt:P279 wd:Q2140665 .
      ?item p:P1114 ?st .
      ?st pq:P642 ?obj .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
P1114 statements for class Q2140665 qualified with P642

2通りの使用法が混在している。

electric vehicle charging station (Q2140665)以外

edit 
#title:some usages of P1114 statements qualified with P642
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P642 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P642 AS ?qual)
  MINUS{ ?item wdt:P279 wd:Q2140665. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
some usages of P1114 statements qualified with P642

applies to part (P518)

edit

applies to part (P518)は

Title ID Data type Description Examples Inverse
applies to partP518Itempart, aspect, or form of the item to which the claim appliesLady with an Ermine <applies to part> painting support-
#title:P1114 statements qualified with P518
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P1114 ?st .
      ?st pq:P518 ?obj .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
P1114 statements qualified with P518

rolling stock class (Q811704)

edit

rolling stock class (Q811704)の項目で使われている。 

#title:P1114 statements for class Q811704 qualified with P518
SELECT ?item ?itemLabel ?obj ?objLabel ?st WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q811704;
    p:P1114 ?st.
  ?st pq:P518 ?obj.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY ?item
P1114 statements for class Q811704 qualified with P518

rolling stock class (Q811704)以外

edit 
#title:some usages of P1114 statements qualified with P518
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P518 ?qual_value.
  MINUS { ?item wdt:P31/wdt:P279* wd:Q811704. }
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P518 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?item
some usages of P1114 statements qualified with P518

valid in place (P3005)

edit
Title ID Data type Description Examples Inverse
valid in placeP3005Itemplace where a statement is validstadion <valid in place> Delphi-
#title:all usages of P1114 statements qualified with P3005
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P3005 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P3005 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P3005

現状、基本的にはステートメントの値が項目のインスタンスの数になっている。

excluding (P1011) & including (P1012)

edit

この2つはインスタンスの数を数える時の条件として使われているのが自然な用法。

Title ID Data type Description Examples Inverse
excludingP1011Itemexception: usually used as a qualifierBritish Islands <excluding> Republic of Ireland-
includingP1012Itemusually used as a qualifier2015 San Bernardino shooting <including> suspect-

たとえばcounty of Maryland (Q13410464)に対して、

quantity (P1114)
  23 edit
excluding (P1011) independent city (Q1266818)
Baltimore (Q5092)
0 references
add reference
  24 edit
including (P1012) independent city (Q1266818)
Baltimore (Q5092)
0 references
add reference


add value

それ以外に、

sourcing circumstances (P1480) & nature of statement (P5102)

edit

この2つの用法には混乱がある。経緯として先にsourcing circumstances (P1480)があり、そこからnature of statement (P5102)が分かれた。Wikidata:Property_proposal/nature_of_statementによれば、sourcing circumstances (P1480)は情報源についての状況であり、nature of statement (P5102)はステートメントについての状況。

Title ID Data type Description Examples Inverse
sourcing circumstancesP1480Itemsourcing circumstance: qualification of the truth or accuracy of a source: circa (Q5727902), near (Q21818619), presumably (Q18122778), etc.gas lighting <sourcing circumstances> circa-
nature of statementP5102Item(qualifier only) the underlying circumstances of this statementVermont <nature of statement> hypothesis-
#title:all usages of P1114 statements qualified with P1480
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P1480 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P1480 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P1480 
#title:all usages of P1114 statements qualified with P5102
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P5102 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P5102 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P5102

lower limit (P5447) & upper limit (P5448)

edit

この2つのqualifierはもともとreference value (P5446)で「範囲」型を実現するためのギミックとして導入されている。他のプロパティで使うこともできるが、「範囲」の表現でないなら別の表現のほうが望ましいような気がする。

Title ID Data type Description Examples Inverse
lower limitP5447Quantitylower limit of a range or an interval; (qualifier) used with a dummy value which specifies the type of the range or intervalred blood cell count <lower limit> 4.35 trillion cells per litre-
upper limitP5448Quantityupper limit of a range or an interval; (qualifier) used with a dummy value which specifies the type of the range or intervalred blood cell count <upper limit> 5.55 trillion cells per litre-
#title:all usages of P1114 statements qualified with P5447
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P5447 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P5447 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P5447

たとえばfriends of the paralytic man (Q114804902)に対して

quantity (P1114)
  unknown value edit
lower limit (P5447) 5
0 references
add reference


add value

これは以下のようにも表現できる。

quantity (P1114)
  5 edit
nature of statement (P5102) minimum (Q10585806)
0 references
add reference


add value

determination method (P459)

edit

これは具体的な手法（「○○法」）であるべきで、estimation (Q791801)とかestimate (Q37113960)というような値はnature of statement (P5102)の方が適切な気がする。

Title ID Data type Description Examples Inverse
determination methodP459Itemdetermination method: how a value is determined, or the standard by which it is declaredInterchange Bad Neuenahr-Ahrweiler <determination method> Normalhöhennull-
#title:all usages of P1114 statements qualified with P459
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P459 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P459 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P459

country (P17)

edit

これは疑わしい用法。一般的な制約的修飾子としてはvalid in place (P3005)の方が適切だと思われる。

Title ID Data type Description Examples Inverse
countryP17Itemcountry: sovereign state that this item is in (not to be used for human beings)Wusung Radio Tower <country> People's Republic of China-
#title:all usages of P1114 statements qualified with P17
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P17 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P17 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P17

has characteristic (P1552)

edit
Title ID Data type Description Examples Inverse
has characteristicP1552Itemquality: inherent or distinguishing quality or feature of the entity. Use a more specific property when possiblehuman <has characteristic> gender-
#title:all usages of P1114 statements qualified with P1552
SELECT ?item ?itemLabel ?prop ?propLabel ?value ?qual ?qualLabel ?qual_value ?qual_valueLabel ?statement WHERE {
  ?item p:P1114 ?statement.
  ?statement ps:P1114 ?value;
    pq:P1552 ?qual_value.
  BIND(wd:P1114 AS ?prop)
  BIND(wd:P1552 AS ?qual)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
all usages of P1114 statements qualified with P1552

その他

edit


as qualifier

edit

修飾子としてquantity (P1114)を使っているプロパティの統計: 

#title:List of properties qualified with P1114
SELECT ?prop ?propLabel ?count ?sample WHERE {
  {
    SELECT ?prop (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) WHERE {
      hint:Query hint:optimizer "None".
      ?st pq:P1114 ?val.
      ?item ?p ?st.
      ?prop wikibase:claim ?p.
    }
    GROUP BY ?prop
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC (?count) (?propLabel)
List of properties qualified with P1114

quantity (P1114)で修飾されているhas part(s) (P527)の値: 

#title:P527 statements qualified with P1114
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P527 ?st .
      ?st ps:P527 ?obj .
      ?st pq:P1114 ?val .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
P527 statements qualified with P1114


quantity (P1114)で修飾されているhas part(s) of the class (P2670)の値: 

#title:P2670 statements qualified with P1114
SELECT ?obj ?objLabel ?count ?sample {
  {
    SELECT ?obj  (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P2670 ?st .
      ?st ps:P2670 ?obj .
      ?st pq:P1114 ?val .
    } GROUP BY ?obj
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?objLabel)
P2670 statements qualified with P1114

as reference

edit

出典としてquantity (P1114)を使っているステートメントの一覧: 

#title:List of statements with references having P1114
SELECT ?st ?prop ?propLabel ?val WHERE {
  hint:Query hint:optimizer "None".
  ?refnode pr:P1114 ?val.
  ?st prov:wasDerivedFrom ?refnode .
  BIND(wd:P1114 AS ?prop)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
List of statements with references having P1114

関連プロパティ

edit

greater than (P5135) & less than (P5136)

edit
Main page: User:Mzaki/P5135

項目間の比較のためのプロパティ。2つの項目間に何らかの大小関係があるときに、その2者を結びつける。大小関係のあるパラメータをcriterion used (P1013)で修飾して示す。ただし、修飾子として使える局面もあることはある。

Title ID Data type Description Examples Inverse
greater thanP5135Itemgreater than: instances of the item have a greater value than corresponding instances of the object, for the given measureem dash <greater than> en dashless than
less thanP5136Itemless than: instances of the item have a lesser value than corresponding instances of the object, for the given measureaerostat <less than> airgreater than

lower limit (P5447) & upper limit (P5448)

edit

もともとはreference value (P5446)で「範囲」型を実現するためのギミックとして提唱されているが、数量型のプロパティの最大値最小値を表現する修飾子だと一般化して考える事はできそう。

Title ID Data type Description Examples Inverse
lower limitP5447Quantitylower limit of a range or an interval; (qualifier) used with a dummy value which specifies the type of the range or intervalred blood cell count <lower limit> 4.35 trillion cells per litre-
upper limitP5448Quantityupper limit of a range or an interval; (qualifier) used with a dummy value which specifies the type of the range or intervalred blood cell count <upper limit> 5.55 trillion cells per litre-

maximum value (P2312) & minimum value (P2313)

edit

プロパティ制約のための修飾子であり、Wikibase item (Q29934200)には使用できない。

Title ID Data type Description Examples Inverse
maximum valueP2312Quantitymaximum: qualifier to define a property constraint in combination with P2302. "no value" can be used to specify no upper boundrange constraint <maximum value> 1,234-
minimum valueP2313Quantityminimum: qualifier to define a property constraint in combination with P2302range constraint <minimum value> 0-

class (Q18204)の移行

edit

quantity (P1114) + statement is subject of (P805)=>class (Q18204)を、has part(s) of the class (P2670)=>class (Q18204) + quantity (P1114)に移行したい。

共起する全てのプロパティ: 

#title:Qualifier and reference properies used in P1114 statements qualified with P805:Q18204
SELECT ?prop ?propLabel ?count ?sample {
  {
    SELECT ?prop (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item p:P1114 ?st .
      ?st pq:P805 wd:Q18204 .
      {
        ?st ?pq ?pq_val .
        ?prop wikibase:qualifier ?pq .
      } UNION {
        ?st prov:wasDerivedFrom ?refnode .
        ?refnode ?pr ?pr_val .
        ?prop wikibase:reference ?pr .
      }
    } GROUP BY ?prop
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?propLabel)
Qualifier and reference properies used in P1114 statements qualified with P805:Q18204

electrical connector (Q2119531)の移行

edit

quantity (P1114) + of (P642)=>Combined Charging System Type 2 connector (Q66024992),CHAdeMO connector (Q66024981),Type 2 connector (Q2335519),Schuko (Q1123613)を、connector (P2935) + quantity (P1114)に移行したい。

共起する全てのプロパティ: 

#title:Qualifier and reference properies used in P1114 statements for class Q2140665 qualified by P642 with class Q2119531
SELECT ?prop ?propLabel ?count ?sample {
  {
    SELECT ?prop (COUNT(DISTINCT ?item) AS ?count) (SAMPLE(?st) AS ?sample) {
      ?item wdt:P279 wd:Q2140665 .
      ?item p:P1114 ?st .
      ?st pq:P642 ?obj .
      ?obj wdt:P279+ wd:Q2119531 .
      {
        ?st ?pq ?pq_val .
        ?prop wikibase:qualifier ?pq .
      } UNION {
        ?st prov:wasDerivedFrom ?refnode .
        ?refnode ?pr ?pr_val .
        ?prop wikibase:reference ?pr .
      }
    } GROUP BY ?prop
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
}
ORDER BY DESC(?count) ASC(?propLabel)
Qualifier and reference properies used in P1114 statements for class Q2140665 qualified by P642 with class Q2119531
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Mzaki/P1114&oldid=2063124945"