Wikidata

Wikidata:WikiProject Sustainable Development

The Sustainable Development Goals were the theme of Wikimania 2019 but the engagement of Wikimedians goes back much further and continues in multiple ways

About

edit

WikiProject Sustainable Development (Q56507949) is concerned with curating information about sustainable development (Q131201) and related topics. We are just getting started, and you are most welcome to join in.

Items

edit

Sustainable Development Goal Target (Q56724848) items should be connected to their Sustainable Development Goal (Q53580881) counterparts as facet of (P1269). Example:

The same goes for Sustainable Development Goal Indicator (Q56726345) and Sustainable Development Goal Target (Q56724848), example:

Properties

edit

General

edit

External identifiers

edit

Queries

edit

Line chart of Human Development Index over time for a set of countries

edit

The following query uses these:

  • Properties: instance of (P31)     , Human Development Index (P1081)     , point in time (P585)     
    #defaultView:LineChart
# The following implementation was inspired by the code here: https://stackoverflow.com/questions/49066390/how-to-get-only-the-most-recent-value-from-a-wikidata-property
# Read https://en.wikipedia.org/wiki/Human_Development_Index for more on the Human Development Index.

SELECT ?year ?hdiValue ?country ?countryLabel WHERE {
  ?country wdt:P31 wd:Q6256.
  OPTIONAL {
    ?country p:P1081 ?hdi.
    ?hdi pq:P585 ?hdiDate.
    ?hdi ps:P1081 ?hdiValue.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  BIND(STR(YEAR(?hdiDate)) AS ?year).
  FILTER (?country IN (wd:Q33, wd:Q30, wd:Q148, wd:Q668, wd:Q851, wd:Q159, wd:Q20, wd:Q929))
}
Try it!

List of Sustainable Development Goals

edit

The following query uses these:

  • Properties: part of (P361)     
    SELECT ?item ?label ?itemDescription
WHERE {
  ?item wdt:P361 wd:Q7649586.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?item rdfs:label ?label.
  }
}
Try it!

Fields of work of the Sustainable Development Goals

edit
  • to do

List of Sustainable Development Goal Targets

edit

The following query uses these:

  • Properties: instance of (P31)     
    SELECT ?item ?label ?itemDescription
WHERE {
  ?item wdt:P31 wd:Q56724848.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". ?item rdfs:label ?label.}
}
ORDER BY (?label)
Try it!

Ordered List of Sustainable Development Goal Targets

edit

The following query uses these:

  • Properties: has part(s) (P527)     , series ordinal (P1545)     
    SELECT ?goal ?goalLabel ?serial ?goalDescription
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  wd:Q7649586 p:P527 ?goal_statement.
  ?goal_statement ps:P527 ?goal.
  OPTIONAL {
    ?goal_statement pq:P1545 ?serial.
  }
}
Order by xsd:integer(?serial)
Try it!

List of Sustainable Development Goal Indicators

edit

The following query uses these:

  • Properties: instance of (P31)     
    SELECT ?item ?label ?itemDescription
WHERE {
  ?item wdt:P31 wd:Q56726345.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?item rdfs:label ?label.
  }
}
Try it!

List of Sustainable Development Goals, their targets and indicators

edit

The following query uses these:

  • Properties: instance of (P31)     , facet of (P1269)     , part of (P361)     , series ordinal (P1545)     
    SELECT ?goalLabel ?goal ?targetLabel ?target ?indicatorLabel ?indicator WHERE {
  ?indicator wdt:P31 wd:Q56726345;
             wdt:P1269 ?target .
  ?target wdt:P1269 ?goal.
  ?goal p:P361 ?part.
  ?part ps:P361 wd:Q7649586;
        pq:P1545 ?order .
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . 
  }
}
ORDER BY ASC (xsd:integer(?order))
Try it!

Sustainable Development Goals and their topics

edit

The following query uses these:

Features: Graph (Q24515287)     

#defaultView:Graph
SELECT ?item ?label ?_image ?topic ?topicLabel WHERE {
  ?item wdt:P361 wd:Q7649586.
  OPTIONAL {?item wdt:P921 ?topic.}.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
  
OPTIONAL { ?item wdt:P18 ?_image. }
}
LIMIT 100
Try it!

Organizations working on topics of the SDGs

edit

See discussion for more info

The following query uses these:

Try it!

Organizations whose field of work is any SDGs

edit

See discussion for more info

The following query uses these:

  • Properties: instance of (P31)     , field of work (P101)     
    SELECT ?subjectLabel ?sdgLabel
WHERE {
  ?sdg wdt:P31 wd:Q53580881.
  ?subject wdt:P101 ?sdg.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
}
Try it!

Participants

edit

The participants listed below can be notified using the following template in discussions:
{{Ping project|Sustainable Development}}

Wikimania

edit

Note that Wikimania 2019 (Q48010913) had the SDG's as its theme.[1]

See also

edit

References

edit
  1. ↑ https://wikimediafoundation.org/2019/02/27/a-theme-for-wikimania-2019-wikimedia-and-advancing-the-sustainable-development-goals/
Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata:WikiProject_Sustainable_Development&oldid=1201588418"