Wikidata

Mnamihdk

Joined 17 March 2018
Babel user information
ja-N この利用者は日本語を母語としています。
en-2 This user has intermediate knowledge of English.
Users by language

日本国内の図書館データ edit

https://www.wikidata.org/wiki/Wikidata:WikiProject_Libraries/Japan


Code4Lib JAPAN によるデータ整備履歴　(2019.9〜) edit

Ryuuji Yoshimoto 22:11 まだ十分ではありませんが、 https://www.wikidata.org/wiki/Wikidata:WikiProject_Libraries/Japan こちらに、今回の会期中に僕がやったことはまとめてみました。 22:12 市立図書館でもISILがついていないものがあるため、ISILがすべて含まれていない可能性がありそうです。次はISILの補完をするといいのかもしれません

Library system (Q28324850)にISILが登録されているケースがありました。Library systemは複数の図書館を管理する組織として定義されているため、ISILは管理化にある個別の図書館に紐づくように修正しました (2019/9/8 ryuuji_y) Wikipediaから移入されたデータと、ISIL由来のデータが重複しているケースがあります。双方の所在地を確認したうえで、同じと判断される図書館は統合しました。(2019/9/8 ryuuji_y)

Suisui 22:04 チュートリアルで出ていた、図書館の分類でISILが入っていないもの+ラベルに"立"を含むものを抽出しました。多くは図書館システムのようですが、群馬県や世田谷区の公共図書館には大きく抜けている箇所もあるようです。 クエリ https://w.wiki/86n ISILのリスト https://www.ndl.go.jp/jp/library/isil/__icsFiles/afieldfile/2019/06/27/isil_public_20190626(J).txt やっぱりGLAMプロジェクトで投入されたもののカタマリがなんなのコアよくわからないです。。

Suisui 01:44 ISILの一覧と、Wikidata側の日本語ラベルが完全一致しているものについて、ISIL番号登録までやりました。残り430件ほどが名称が不一致またはISILにないものです。 01:46 完全手動でやるには一日で終わらない件数なので、図書館システムぽいものだけ抜き出してみようかと考えてます

mnamihdk 00:16 「新発田市立図書館佐々木分室 (Q61901355)」「四万十市立図書館西土佐分館 (Q61901356)」「中城村護佐丸歴史資料図書館 (Q61901359)」の郵便番号欄になぜか英語機関名（の一部）が入力されてしまっていたので、郵便番号で入力し直しました。この3館がISIL管理台帳公共図書館ファイルの末尾の3館であることと関係があるのでしょうか。 あと、「相模原市立星が丘公民館図書室 (Q61898181)」「相模原市立大沼公民館図書室 (Q61898186)」「相模原市立大野台公民館図書室 (Q61898187)」の郵便番号の後ろになぜか「 @」が入力されてしまっていたので、削除しました。

Ryuuji Yoshimoto 18:22 -- ちょっと違うネタとして、オーテピア高知図書館をどう扱うかというのがあります。（カーリルのデータベースでは現状、正しい扱いができていません） この図書館は、県立図書館と市立図書館の共同運営なので、図書館システムが2つあることになります。それぞれにISILが付与されていますが、図書館はひとつ。各種IDは2つあったり、1つだけだったり。。。 18:26 カーリルでは　苦肉の策として、　 オーテピア高知図書館（高知県立図書館・高知市民図書館本館）　という名前で扱っています。Wikidata的には2館として扱って、それぞれの別名をオーテピア高知図書館とする感じでしょうか。

Ryuuji Yoshimoto 22:44 ↑所蔵管理のシステム的には特定の図書館に内包されない図書館の分館扱い的な〇〇書庫という場所は確かにあって、直接貸出をしていない、独立した建物というようなケースが該当しそうですね。実際の個々の資料は、各館に所属していそうですが、こういうのをlibrary stack (Q856603) というのでしょうね。あるいはデポジットライブラリー的な。 各クラスの説明は日本語のプロジェクトページにまとめていくとよさそうですね。

mnamihdk 22:56 あ〜そういう例もあるのですね。考えれば考えるほど複雑な…。 日本語のプロジェクトページにまとめていくのはいいですね。 オーテピア高知図書館のは3つとも項目作って、高知県立図書館と高知市民図書館本館はオーテピア高知図書館の一部とするpart of (P361)のはどうでしょう

mnamihdk 20:24 プロジェクトページのクエリ欄に、国内の図書館とその下位クラスに分類されている項目の件数と合計を一覧するクエリを追加しました。間違いや、もっと良い書き方があれば直してくださいますようお願いします。 https://www.wikidata.org/wiki/Wikidata:WikiProject_Libraries/Japan

mnamihdk 00:26 図書館に分類 (instance of) されている項目のうち、明らかに図書館のインスタンス（実例）ではない以下の項目の分類を変更しました。問題があれば訂正いただきますようお願いします。 図書館の自由に関する宣言 (http://www.wikidata.org/entity/Q11420351), 図書館員の倫理綱領 (http://www.wikidata.org/entity/Q11420353), 中小都市における公共図書館の運営 (http://www.wikidata.org/entity/Q24896597), 市民の図書館 (http://www.wikidata.org/entity/Q24859436), 山口県立山口図書館図書隠匿事件 (http://www.wikidata.org/entity/Q11467061), 船橋市西図書館蔵書破棄事件 (http://www.wikidata.org/entity/Q11614231), 岡崎市立中央図書館事件 (http://www.wikidata.org/entity/Q11472855), 学校図書館司書教諭講習規程 (http://www.wikidata.org/entity/Q11448258), 公立図書館職員令 (http://www.wikidata.org/entity/Q11392128), 国立国会図書館連絡調整委員会 (http://www.wikidata.org/entity/Q11421244)


データソースとなる情報源 edit

  1. ISIL管理台帳 (国立国会図書館、更新随時）
  2. 『日本の図書館　統計と名簿』（日本図書館協会、年刊）
  3. カーリル図書館API（カーリル、随時更新）
ISIL管理台帳
  • ISIL管理台帳ファイル（2019年9月26日現在）の公共図書館のデータ件数は4,988件、公共図書館以外（国立国会図書館、大学図書館、専門図書館、情報専門機関等）のデータ件数は2,579件
  • 日本におけるISILの付与対象は、ISO 15511:2011に基づいて図書館、博物館・美術館、文書館、その他（出版者や取次業者、資料や情報の流通に関わる組織等）を想定
  • 機関種別は図書館を1、博物館・美術館を2、文書館を3、その他機関を9とする
  • 機関IDは000001から連番で付与する。機関の廃止等で欠番が出ても埋めず、常に新しい番号を付与する
  • 原則として1館にひとつのISILを付与するが、中央館とは別に分館も個別のISILを持つことができる
  • ISIL管理台帳では中央館・分館の関係、機関の種別等の情報もメンテナンスしている
  • ISIL管理台帳は「共図書館」と「公共図書館以外（国立国会図書館、大学図書館、専門図書館、情報専門機関等）」に分割されている
  • ISILおよびISIL管理台帳で管理されている情報のいずれにも図書館種別に関するデータは含まれていない
  • ISILには公民館図書室も含まれている
  • ISILには移動図書館は含まれていない
  • 機関情報は、「初期登録データ（一括）」「更新データ（一括）」「登録希望機関からのフォーム経由の申請（個別）」のいずれかに基づいてISIL管理台帳に登録する。機関種別「1」（＝図書館）のデータの初期登録については、日本図書館協会（JLA）をはじめ、幾つかの関係団体の協力を得て登録対象となる機関の情報を入手し、あらかじめNDLでISILを採番・付与した（初期登録は図書館のみ。ISIL管理台帳公開時の登録数は4,926館）。
  • （参考）：CA1757 - 日本におけるISIL（アイシル）の導入 / 兼松芳之 | カレントアウェアネス・ポータル
日本の図書館
  • 日本図書館協会から毎年刊行されている図書館の悉皆的な統計書
  • 公共，大学，短期大学，高専図書館の個別データと調査項目ごとの集計を掲載
  • 全国集計の抜粋のみ日本図書館協会のホームページにも掲載
  • 図書館法に基づいて設置されている図書館のみ収録
  • 公立図書館は、図書館法第2条にいう図書館のうち、地方公共団体の設置する図書館、ただし公民館図書室は含まない
  • 私立図書館は、図書館法第2条にいう図書館のうち、日本赤十字社又は一般社団法人若しくは一般財団法人の設置する図書館で、県の教育委員会に届け出のあったもの
  • 専門図書館・情報専門機関・企業内図書室等に関しては収録されていない
  • 毎年4月に各都道府県立図書館および各大学・短期大学・高専図書館に公共図書館調査票、大学・短期大学・高専図書館調査票を送付
  • なお新館の情報源として使うことのできるものに 『図書館雑誌』（日本図書館協会、月刊）の「新館紹介」のページがある
カーリル図書館API
  • 「図書館データベース」機能あり
  • 全国の図書館の名称、住所、経緯度情報などをまとめた図書館データベースへのアクセスを提供
  • 指定した条件で図書館の一覧を取得する。緯度経度を指定した場合は、その地点から近い図書館を順に出力する
  • 条件に指定できるのは「都道府県名」「市区町村名」「図書館のシステムID」「緯度・経度」で、「都道府県名」「図書館のシステムID」「緯度・経度」のいずれかが必須
  • データにはカテゴリーとして「図書室・公民館」「図書館(地域)」「図書館(広域)」「大学」「専門」「移動・BM」の種別が含まれる


上記情報源による国内図書館数の比較 edit

ISIL *1 『日本の図書館』 *2 カーリル *3 Wikidata *4
抽出対象データ クエリ例 抽出件数
公共図書館 4,988 公
共
図
書
館 		私立 *5 19 私立 *10 私立図書館 https://w.wiki/Cxy 0
公立 移動図書館 *6 538 3,845 移動・BM 340 5,403 移動図書館 クエリ 0
公民館図書室 *7 - 図書室・公民館 1,901 公民館図書室 クエリ 0
町村立 620 3,219 図書館(地域) 3,102 町村立図書館 クエリ 0
市区立 2,599 市区立図書館 クエリ 0
都道府県立 58 88 図書館(広域) 60 都道府県立図書館 クエリ 0
公
共
図
書
館
以
外 		国立国会図書館 2,579 国立国会図書館 *8 30 国立図書館 クエリ 0
大学図書館 大
学
図
書
館 		国立 287 1,663 大学 1,507 1,797 国立大学図書館 クエリ 0
公立 132 公立大学図書館 クエリ 0
私立 1,008 私立大学図書館 クエリ 0
短大 175 短期大学図書館 クエリ 0
高専 *9 61 高等専門学校図書館 クエリ 0
専門図書館 専門 290 専門図書館 クエリ 0
情報専門機関等 情報専門機関 クエリ 0
合計 7,567 合計 5,527 合計 7,200 合計 0

注1. 2019年9月26日現在版による　 注2. 2018年版 (2019年2月28日発行)　による 注3. カーリル図書館API 2019年10月9日取得データによる 注4.
注5. 『日本の図書館』における収録対象の私立図書館は、日本赤十字社又は一般社団法人若しくは一般財団法人の設置する図書館ただし県の教育委員会に届け出のあったものとされている　
注6. この数字は台数　 注7. 『日本の図書館』における収録対象の公立図書館は、地方公共団体の設置する図書館ただし「公民館図書室は含まない」とされている　
注8. 省庁図書館もここに含まれている　 注9. 大学校図書館、大学共同利用機関等図書館もここに含まれている
注10. カーリル図書館APIで取得できる図書館データのカテゴリは「図書室・公民館」「図書館(地域)」「図書館(広域)」「大学」「専門」「移動・BM」の6つで「私立」というカテゴリはない

図書館種別 クエリ例 WDQSへのリンク 抽出件数
公共図書館
私立図書館 私立図書館及びその下位クラスに分類 https://w.wiki/Cxy 0
公立図書館 -
移動図書館 -


Wikidata からクエリによって取得できた国内図書館の種別別件数 edit

図書館種別 クエリ例 抽出件数
私立図書館 https://w.wiki/Cxy 0


図書館の分類 (Instance of) edit

GLAM (Q1030034) / cultural institution (Q5193377)
　∟ library (Q7075)
　　∟ national library (Q22806)
　　∟ public library (Q28564) <--> private library (Q380829)
　　　∟ public library of Japan (Q11392127)
　　∟ subscription library (Q7631964)
　　∟ special library (Q385994)
　　∟ research library (Q1438040)
　　　∟ academic library (Q856234) 

  reference library (Q1769139) universal library (Q2495568) non-departmental public body (Q3343298) depository library (Q28653690) rare book library (Q44234152)
  • 設置主体や運営母体による分類
  • 設置目的やサービス対象による分類


図書館のプロパティ edit

cf. https://www.wikidata.org/wiki/User:Suisui/Item/%E5%9B%B3%E6%9B%B8%E9%A4%A8

名前 edit

場所 edit

沿革 edit

組織 edit

法務 edit

  • 設置の根拠となった法律など

財務 edit

施設 edit

所蔵資料 edit

連絡先 edit

識別子 edit

統計的事項 edit

画像 edit

その他 edit

参考項目 edit


クエリ edit

図書館およびその下位クラスに分類されている日本国内の項目．ただし図書館システムに分類されているものを除く edit 

SELECT ?library ?libraryLabel ?classLabel ?isil ?ndl_auth ?postcode
WHERE {
  ?library (wdt:P31/wdt:P279*) wd:Q7075.  # instance of any subclass of library
  ?library wdt:P17 wd:Q17.  # 国 == 日本
  MINUS {
      ?library wdt:P31 wd:Q28324850  # 分類 != 図書館システム
   }
  OPTIONAL {?library wdt:P31 ?class}  # 分類
  OPTIONAL {?library wdt:P791 ?isil}  # ISIL識別子
  OPTIONAL {?library wdt:P349 ?ndl_auth}  # 国立国会図書館典拠ID
  OPTIONAL {?library wdt:P281 ?postcode}  # 郵便番号
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
}
Try it!

図書館およびその下位クラスに分類されている項目のクラスごとの件数（外国を含む） edit 

SELECT ?subclass ?subclassLabel ?count 
WHERE {
  {
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.  # instance of subclass
      ?subclass wdt:P279* wd:Q7075.  # any subclass of library
    }
    GROUP BY ?subclass
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)
Try it!

図書館およびその下位クラスに分類されている項目のクラスごとの件数（日本国内のみ） edit 

SELECT ?subclass ?subclassLabel ?count 
WHERE {
  {
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.  # instance of subclass
      ?subclass wdt:P279* wd:Q7075.  # any subclass of library
      ?library wdt:P17 wd:Q17.  # 国 == 日本
    }
    GROUP BY ?subclass
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)
Try it!

図書館およびその下位クラスに分類されている項目のクラスごとの件数（日本国内のみ） edit 

SELECT ?aggType ?subclassLabel ?count (?subclass AS ?subclassEntity) 
WHERE {
  {
    #　subclassのエンティティとsubclassごとの合計件数
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.
      ?subclass wdt:P279* wd:Q7075.
      ?library wdt:P17 wd:Q17.
    }
    GROUP BY ?subclass
  }
  UNION
  {
    #　subclassごとの合計のさらに合計（延べ件数＝複数のsubclassに分類されている場合はそれぞれを1件と数える＝件数に重複あり）
    SELECT ("延べ件数" AS ?aggType) (SUM(?count) AS ?count)
    WHERE {
      {
        SELECT (COUNT(DISTINCT ?library) AS ?count)  #　subclassごとの合計
        WHERE {
          ?library wdt:P31 ?subclass.
          ?subclass wdt:P279* wd:Q7075.
          ?library wdt:P17 wd:Q17.
        }
        GROUP BY ?subclass
      }
    }
  }
  UNION
  {
    #　項目のユニーク件数（複数のsubclassに分類されている場合でもIDが同じなら合わせて1件＝件数に重複なし）
    SELECT ("ユニーク件数" AS ?aggType) (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31/wdt:P279* wd:Q7075.
      ?library wdt:P17 wd:Q17.
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)
Try it!

日本国内の私立図書館及びその下位クラスに分類されている項目とその件数 edit 

SELECT ?subclass ?subclassLabel ?count 
WHERE {
  {
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      # 私立図書館及びその下位クラスに分類されている項目で国が日本であるもの
      ?library wdt:P31 ?subclass.
      ?subclass wdt:P279* wd:Q7631964.
      ?library wdt:P17 wd:Q17.
    }
    GROUP BY ?subclass
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)
Try it!

図書館に分類されている項目でISILが入っていないもの+ラベルに"立"を含むもの edit 

SELECT ?__ ?__Label ?loc ?jawp WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en". }
  ?__ (wdt:P31/wdt:P279*) wd:Q7075;
        wdt:P17 wd:Q17.
  OPTIONAL {?__ wdt:P791 ?isil;}
  FILTER (!BOUND(?isil)) 
  OPTIONAL { ?__ rdfs:label ?l. FILTER (lang(?l) = 'ja') }
  FILTER (BOUND(?l))
  FILTER (CONTAINS(?l, "立"@ja))
}
LIMIT 1000
Try it!

日本国内の図書館及びその下位クラスに分類されている項目のうちラベルに「文庫」を含むもの edit 

SELECT DISTINCT (?library AS ?entity) ?label ?isil ?ndl_auth ?postcode
WHERE {
  ?library wdt:P31/wdt:P279* wd:Q7075.
  ?library wdt:P17 wd:Q17.
  ?library rdfs:label ?label.
  OPTIONAL { ?library wdt:P791 ?isil. }
  OPTIONAL { ?library wdt:P349 ?ndl_auth. }
  OPTIONAL { ?library wdt:P281 ?postcode. }
  FILTER(LANG(?label) = "ja").
  FILTER(CONTAINS(?label, "文庫")).
}
Try it!

ShEx (Schema of an library: Shape Expressions) edit

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Mnamihdk&oldid=1197983583"