Wikidata

Wikidata:WikiProject KOS

(Redirected from User:JakobVoss/kostypes)

WikiProject Knowledge Organization Systems (KOS) is a WikiProject to improve coverage of information about knowledge organization system (Q6423319) View with SQID (KOS) in Wikidata.

GoalsEdit

  • Add KOS types and instances to Wikidata
  • Improve consistent use of properties for description of KOS
  • Make KOS data from Wikidata more usable
  • Extract KOS mappings from Wikidata

IntroductionEdit

A KOS is a set of concept (Q151885)   based on a mental model (Q1851867)  

PropertiesEdit

KOS typesEdit

See also Help:Modelling#Hierarchy of classes

KOS instancesEdit

KOS partsEdit

Overviews and reportsEdit

Some items of KOS types combine both a method and a KOS of one of its outcomes. For some areas both are separated items:

method KOS
has effect (P1542) / has cause (P828)
classification (Q13582682)     
categorization (Q912550)      		classification system (Q5962346)     
taxonomy (Q8269924)     
systematics (Q3516404)      		biological classification (Q11398)     

The item taxonomy (Q7211)      confuses some of the meanings and has some overlap with taxonomy (Q8269924), biological classification (Q11398), and classification system (Q5962346).

reports are automaticaly generated from queries:

Typical errorsEdit

  • Assignment of KOS instances to wrong classes and as subclasses instead of instances
  • ...

TasksEdit

KOS typesEdit

KOS instancesEdit

KOS parts and instancesEdit

QueriesEdit

# number of KOS types
SELECT (COUNT(distinct ?kos) AS ?count) {
  ?kos wdt:P279* wd:Q6423319
}
Try it! 
# number of KOS instances
SELECT (COUNT(distinct ?kos) AS ?count) {
  ?kos wdt:P31/wdt:P279* wd:Q6423319
}
Try it! 
# KOS types with number of instances and additional numbers
SELECT ?item ?itemLabel ?broader ?parents ?size ?sites {
  {  
    # number of additional superclasses
    SELECT ?item (count(distinct ?parent)-1 as ?parents) {
      ?item wdt:P279* wd:Q6423319
      OPTIONAL { ?item wdt:P279 ?parent }
    } GROUP BY ?item    
  } { 
    # number of instances
    SELECT ?item (count(distinct ?element) as ?size) {
     ?item wdt:P279* wd:Q6423319
     OPTIONAL { ?element wdt:P31 ?item }
    } GROUP BY ?item      
  } { 
    # number of sitelinks
    SELECT ?item (count(distinct ?site) as ?sites) {
      ?item wdt:P279* wd:Q6423319
      OPTIONAL { ?site schema:about ?item }
    } GROUP BY ?item    
  }
  OPTIONAL { ?item wdt:P279 ?broader }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
Try it! 
# number of KOS instances grouped by KOS type of first level
SELECT ?kostype ?kostypeLabel (COUNT(distinct ?kos) AS ?count) {
    ?kostype wdt:P279 wd:Q6423319 .
    ?kos wdt:P31/wdt:P279* ?kostype .
    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
    }
}
GROUP BY ?kostype ?kostypeLabel
ORDER BY DESC(?count)
Try it! 
# language coverage of KOS types
SELECT ?lang (COUNT(DISTINCT ?label) as ?items) WHERE {
    ?item wdt:P279* wd:Q6423319 .
   	?item rdfs:label ?label . # skos:altLabel/schema:description for alternative labels/descriptions
  	BIND(lang(?label) as ?lang) 
} 
GROUP BY ?lang
# HAVING (?items > 2) # limit to most used languages 
ORDER BY DESC(?items)
Try it! 
# classification systems with parts as Wikidata items
SELECT ?kos ?kosLabel (COUNT(DISTINCT ?part) as ?parts) {
  ?kos wdt:P31/wdt:P279* wd:Q5962346 .
  ?part wdt:P361 ?kos .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} GROUP BY ?kos ?kosLabel
ORDER BY DESC(?parts)
Try it! 
# classification systems with type of their parts
SELECT ?kos ?kosLabel ?parts ?partsLabel {
  ?kos wdt:P31/wdt:P279* wd:Q5962346 .
  ?kos wdt:P2670 ?parts .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
Try it!

Terminology registriesEdit

Instances of terminology registry (Q22692845) collect, describe and/or provide multiple KOS. Get all terminology registries with their BARTOC URI (if available) with this query: 

SELECT ?item ?itemLabel ?bartoc WHERE {
    ?item wdt:P31/wdt:P279* wd:Q22692845 .
    OPTIONAL {
      ?item wdt:P2689 ?id .
      BIND (IRI(CONCAT('http://bartoc.org/en/node/',?id)) AS ?bartoc) .
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
Try it!


ParticipantsEdit

The participants listed below can be notified using the following template in discussions:

{{Ping project|KOS}}

Related projectsEdit

Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata:WikiProject_KOS&oldid=954793166"