Wikidata:Forum/Archiv/2016/10

This page is an archive. Please do not modify it. Use the current page, even to continue an old discussion.

distinct-values constraint (Q21502410)

Hat da jemand eine passende Übersetzung? --Leyo 12:54, 2 October 2016 (UTC)

Ich habe mal einen Übersetzungsversuch gemacht. Wer bessere Vorschläge hat: nur zu… —MisterSynergy (talk) 13:27, 2 October 2016 (UTC)

Danke! --Leyo 13:25, 3 October 2016 (UTC)

Schnittmengen finden

Wie findet man Schnittmengen, also Items die bestimmte Links enthalten? Beispielsweise group or class of chemical substances (Q17339814) (Aussage) und CAS Registry Number (P231) (Identifikator). --Leyo 13:30, 3 October 2016 (UTC)

Am besten mit https://query.wikidata.org. Folgende Abfrage liefert alle Instanzen von group or class of chemical substances (Q17339814) (bzw. Unterklassen von Q17339814) mit CAS Registry Number (P231) zurück:

SELECT ?item ?itemLabel ?cas WHERE{
  ?item wdt:P31/wdt:P279* wd:Q17339814 .
  ?item wdt:P231 ?cas .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}

Try it!

Die Dokumentaton zum query service findest du unter Wikidata:SPARQL query service --Pasleim (talk) 13:41, 3 October 2016 (UTC)

Danke! Puh, das ist nicht ganz trivial. Wie würde die Abfrage ohne Unterklassen (oder ohne group of isomeric entities (Q15711994)) lauten? --Leyo 13:47, 3 October 2016 (UTC)

Um die Unterklassen zu ignorieren, entferne /wdt:P279*.

Falls du auch die Bezeichnungen nicht brauchst, kann man die Abfrage weiter vereinfachen:

SELECT * WHERE{
  ?item wdt:P31 wd:Q17339814 .
  ?item wdt:P231 ?cas .
}

Try it!

--Pasleim (talk) 13:53, 3 October 2016 (UTC)

Links auf Benutzerseiten

Es ist technisch ja nicht möglich, zu einem Item ein Link zu einer Benutzerseite hinzuzufügen. Wie kommen dann die ganzen Links auf der Wartungsliste Wikidata:Database reports/User pages zustande? 217.249.108.5 09:36, 3 October 2016 (UTC)

Spekulation: wikipediaseitig wurde der Artikel aus dem ANR in den BNR verschoben, und ein Bot hat hier übers API den Interwiki nachgezogen. Ich weiß nicht an welcher Stelle eine technische Begrenzung Benutzerseiten als Interwikilinks verhindert, deshalb halte ich das durchaus für möglich, auch wenn man das übers Web-Interface nicht hinbekommt. —MisterSynergy (talk) 09:52, 3 October 2016 (UTC)

Ich sehe keine technischen Begrenzungen. Hier konnte ich problemlos meine Benutzerseite als Link hinzufügen. Nur unsere Relevanzkriterien untersagen solche Links, von der Software aber kommen keine Bedingungen --Pasleim (talk) 09:57, 3 October 2016 (UTC)

Warum wurde keine technische Begrenzung implemntiert? Irgendwie muss man ja die Bots daran hindern, Benutzerseiten zu verlinken. 92.74.153.138 19:59, 3 October 2016 (UTC)

Neigung (Bauwerk)

Hallo, wie könnte man die Neigung von Bauwerken in Wikidata angeben. Wäre bspw. interessant beim Schiefen Turm von Pisa und ähnlich schiefen Gebäuden. --87.140.193.149 15:10, 4 October 2016 (UTC)

Wie wäre es damit? -- JakobVoss (talk) 20:33, 4 October 2016 (UTC)

Creative Commons 4.0

Hello! I'm writing from the Wikimedia Foundation to invite you to give your feedback on a proposed move from CC BY-SA 3.0 to a CC BY-SA 4.0 license across all Wikimedia projects. The consultation will run from October 5 to November 8, and we hope to receive a wide range of viewpoints and opinions. Please, if you are interested, take part in the discussion on Meta-Wiki.

Apologies that this message is only in English. This message can be read and translated in more languages here. Joe Sutherland (talk) 01:34, 6 October 2016 (UTC)

Cirrus-Suche in Wikidata

Gibt es hier wie auch in der Wikipedia die Möglichkeit, nur in den Labals o.ä. suchen zu lassen. Mich interessieren beispielsweise alle Items, in deren deutscher Bezeichnung der String " (Kurzfilm)" auftaucht. Queryzo (talk) 18:22, 6 October 2016 (UTC)

Nein das geht leider nicht. Es sollte aber in den Beispielen auf query.wikidata.org mindestens ein Beispiel geben das zeigt wie man nach Strings in Labels sucht. Sorry, dass ich gerade keinen direkten Link habe. --Lydia Pintscher (WMDE) (talk) 18:26, 6 October 2016 (UTC)

Bei den Beispielen habe ich etwas gefunden, und angepasst:

SELECT ?item ?label (LANG(?label) AS ?lang) WHERE {
  ?item wdt:P31/wdt:P279* wd:Q11424 .
  ?item rdfs:label ?label .
  FILTER(LANG(?label) = "de") .
  FILTER(STRENDS(?label, " (Kurzfilm)")) .
}

Try it!

Wenn man das auf allen items von Wikidata laufen lässt, kommt ein query timeout. Ich habe deshalb auf items eingeschränkt die instance of (P31) film (Q11424) (oder dessen Unterklassen) haben. —MisterSynergy (talk) 18:43, 6 October 2016 (UTC)

Danke, abgearbeitet. Nun hätte ich gern alle mit Jahreszahlen, also z.B. " (2001)" etc. Hier bräuchte man wohl einen RegEx. Kriegt das jemand hin? Queryzo (talk) 18:52, 6 October 2016 (UTC)

SELECT ?item ?label (LANG(?label) AS ?lang) WHERE {
  ?item wdt:P31/wdt:P279* wd:Q11424 .
  ?item rdfs:label ?label .
  FILTER(LANG(?label) = "de") .
  FILTER(REGEX(?label, " \\([12]\\d{3}\\)$")) .
}

Try it!

—MisterSynergy (talk) 19:12, 6 October 2016 (UTC)

Puh, 639 Results. @Pasleim: Könntest du die mal abräumen? Queryzo (talk) 19:30, 6 October 2016 (UTC)

Wenn Du einfach nur die Klammer entfernen möchtest: das sollte mit QuickStatements gehen. Du müsstest die Daten vom Query-Service als Datei laden und mit Excel (oder so) passend formatieren. —MisterSynergy (talk) 06:32, 7 October 2016 (UTC)

erledigt mit QuickStatements und Excel. Falls jemand in Zukunft es wiederholen möchte, hier eine Kurzanleitung:

1. den oben genannten Query abrufen und das Resultat als csv downloaden. Die .csv-Datei in Excel öffnen.
2. erste Zeile können wir löschen und das lästige http://www.wikidata.org/entity/ kann mit Suchen+Ersetzen entfernt werden.
3. zwischen Spalte A und B zwei neue Spalten einfügen. In Spalte A stehen nun die Q'ids, in Spalte D die schlechten Bezeichnungen.
4. in Zelle B1 Lde schreiben. (Lde steht in QuickStatements für Label Deutsch.)
5. in Zelle C1 soll die gute Bezeichnung stehen, d.h. wir wollen die letzten sieben Zeichen der schlechten Bezeichnung von Zelle D1 entfernen. Zudem müssen wir Anführungszeichen hinzufügen, damit QuickStatements richtig funktioniert. Dies erhalten wir, indem wir in Zelle C1 schreiben: =VERKETTEN("""",LINKS(D1,LÄNGE(D1)-7),"""")
6. Nun die Zellen B1 und C1 "packen" und über alle Zeilen nach unten ziehen.
7. Somit stehen in der Spalte A die Q'ids, in Spalte B Lde und in Spalte C die guten Bezeichnungen. Spalte A-C markieren und nach QuickStatements kopieren.
8. In QuickStatements auf "Do it" klicken :) --Pasleim (talk) 08:29, 8 October 2016 (UTC)

Sehr gut, es geht voran! Vielen Dank. Um nochmal zur Frage oben zurückzukommen, wie kriege ich nun alle mit " (Schauspieler)"? Das modifizierte Beispiel oben gibt leider einen Time Out. Queryzo (talk) 16:57, 8 October 2016 (UTC)

@Queryzo:

SELECT ?item ?label (LANG(?label) AS ?lang) WHERE {
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P106 wd:Q33999 .
  ?item rdfs:label ?label .
  FILTER(LANG(?label) = "de") .
  FILTER(STRENDS(?label, " (Schauspieler)")) .
}

Try it!

Das ist allerdings beschränkt auf actor (Q33999) wegen der Time-Outs. Viele Grüße, -- T.seppelt (talk) 20:09, 8 October 2016 (UTC)

Bild einbinden

Über Wiki-needs-picture bin ich auf Wikidata gestoßen und habe mich so gut wie möglich vertraut gemacht. Ich habe aber aber keine Anleitung gefunden, wie man ein Bild aus Wikimedia Commons hier einbinden kann. Habe alle möglichen Syntaxen versucht, jedesmal kommt Fehlermeldung. Objekt: Klosterkirche Münsterappel (Q1313083). Bild: https://commons.wikimedia.org/wiki/File:Km3l_aussen_einweihung_07.JPG. --Volmar (talk) 07:40, 15 October 2016 (UTC)

Als erstes musst du die richtige property finden. Hilfreich ist da z.B. Wikidata:List_of_properties/de. Dort kannst du nach "Bild" suchen und findest Property:P18, wo Beispiele zu sehen sind, wie man Bilder einbindet. Im Zweifelsfall schaust du nach wo das property verwendet wird und siehst weitere Beispiele. Auch die Diskussionsseite der Properties hat meist viele Infos. Ich habe gesehen, P18 hast du schon im item, deshalb habe ich das Bild gleich hinein gesetzt. --Molarus 08:14, 15 October 2016 (UTC)

Ich bekomme es immer noch nicht hin. Bei Objekt Q1407021 habe ich als Wert für das Bild (?i).+\.(jpg|jpeg|png|svg|tif|tiff|gif) (https://commons.wikimedia.org/wiki/File:Fernmeldeturm_Bad_Kreuznach.jpg) eingegeben. Wieso war das falsch?--Volmar (talk) 18:30, 16 October 2016 (UTC)

Grad ausprobiert, klappt. Es reicht, wenn Du als Eigenschaft "Bild" auswählst und dann den Dateinamen (hier "Fernmeldeturm Bad Kreuznach.jpg") angibst, wie er bei Commons angegeben ist (ohne das Präfix "File:"). —MisterSynergy (talk) 18:43, 16 October 2016 (UTC)

Vielen Dank. Also viel einfacher als gedacht. Es wäre nett, wenn das mal jemand auf Property talk:P18 eintragen könnte.--Volmar (talk) 19:10, 16 October 2016 (UTC)

ist ein Versuch sinnvoll und machbar?

Sowjetische und heute russische Militärgerätschaften haben fast ausnahmslos eine interne Bezeichnung als Projekt-0815 oder Objekt-4711 gehabt. Das ist in den entsprechenden WP-Artikeln zwar oft aber nicht immer so vermerkt. Manchmal haben die Artikel auch das Lemma wie die U-Boote de:Projekt 941 oder Panzer de:Objekt 640, oftmals nicht. Wäre es sinnvoll, dafür einen Eintrag bei Wikidata zu machen, aus dem eine Tabelle/Liste der Projekte/Objekte generiert werden kann? Sowas kann man freilich händisch machen aber das ist fehleranfällig, aufwendig und erfordert ständige Pflege. Ob und wie das geht, weiß ich nicht.Was meint ihr? --Ralf Roletschek (talk) 14:04, 19 October 2016 (UTC)

Hallo Ralf Roletschek, ich verstehe noch nicht ganz das Anliegen. Typischerweise haben wir hier Wikidata-Items zu den Wikipedia-Artikeln, so wie Typhoon-class submarine (Q330080) und Black Eagle (Q588014) (für die beiden genannten Geräte). Soll nun eine Liste von Geräten generiert werden, so wird für die Liste kein eigenes Item angelegt, sondern man sammelt alle Items ein, die bestimmte Gemeinsamkeiten teilen. Beispiel: alle Items, für deren operator (P137) gilt part of (P361) Soviet Armed Forces (Q7915590) oder Russian Armed Forces (Q193159). Den aktuellen Datenbestand kannst Du direkt abfragen (click-Link unter der Box):

SELECT ?item ?itemLabel ?branchLabel WHERE {
	?item wdt:P137 ?branch .
 	?branch wdt:P361* ?forces .
  	FILTER (?forces = wd:Q193159 || ?forces = wd:Q7915590) .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
}

Try it!

. Darin sind viele Sachen aus ruwiki (wenig überraschend), und auch die Gesamtzahl ist mit 933 nicht gerade überschaubar. Vielleicht kannst Du noch einmal etwas genauer skizzieren, was die Liste alles enthalten soll, dann könnten wir eine geeignetere Abfrage starten. Vielleicht hilft eine Einschränkung auf Items mit dewiki-Artikel? Viele Grüße —MisterSynergy (talk) 14:42, 19 October 2016 (UTC)

Ich kenne Wikidata noch zu wenig, nutze nur SemanticMediawiki ;) Deine verlinkte Abfrage ist interessant, um betroffene Einträge zu finden. Hätte z.B. jeder Eintrag in Soviet Armed Forces (Q7915590) ein Datenfeld "Projekt", würde man dort die jeweilige Projektnummer eintragen, dann könnte man die Abfrage einschränken. "Alle Einträge in Streitkräfte der Sowjetunion, deren Feld Projekt einen Eintrag hat"? Kann man daraus eine Tabelle generieren wie hier? --Ralf Roletschek (talk) 17:03, 19 October 2016 (UTC)

Und ich kenne das SemanticMediawiki nicht, aber ich glaube das war so eine Art Vorgänger. Ich verstehe noch nicht genau, was im einem Feld "Projekt" eingetragen werden könnte, meinst Du so eine Art interne Projektbezeichnung auf russisch? Dazu könnte man zum Beispiel native label (P1705) nutzen, dort eine russische Originalbezeichnung eingeben (das müsste man aber noch machen, ist wenig bis gar nicht der Fall zurzeit) und dann in der Abfrage nur die Items berücksichtigen, die dieses Label haben. Eine Liste kann man übrigens mit allen möglichen Tools abfragen, innerhalb Wikidatas, innerhalb Wikipedias, auf dem Toolserver oder auch extern als JSON und dann selbst darstellen. —MisterSynergy (talk) 17:22, 19 October 2016 (UTC)

Bei Typhoon-class submarine (Q330080) wäre das ein Eintrag im nicht existierenden Feld "Projekt", die Nummer 941. Klingt dort doppelt gemoppelt, bei T-95 (Q945261) wäre es aber beispielsweise 195 (nur in .ru, .uk und .vi WP so bezeichnet. Diese Projektnummern sind sowas wie ISBN bei Büchern oder der Gemeindeschlüssel bei Orten.

SMW ist sowas wie der Vorgänger von Wikidata. Es war im Gespräch, das einzusetzen, die Performance ist aber derart schlecht, daß alles neu programmiert wurde. --Ralf Roletschek (talk) 20:28, 19 October 2016 (UTC)

Willst Du denn nur die Items mit so einer Projektnummer haben, und sonst ausdrücklich nichts? Wenn ja, weißt Du wie das Programm hieß, das diese Geräte produziert und nummeriert hat? Hat das Programm evtl. irgendwo einen Wikipedia-Artikel und damit ein Wikidata-Item? Dann könnte man vllt. am besten sowas machen wie:

⟨ Typhoon-class submarine (Q330080)    ⟩ instance of (P31) ⟨ Item für sowjetisch-russisches Rüstungsprojekt oder so ⟩
series ordinal (P1545) ⟨ "941" ⟩

Also mit einem einfachen instance of (P31)-Claim und einem Qualifier für die Projektnummer arbeiten. Das wäre auch einfach abzufragen und als Liste darzustellen. —MisterSynergy (talk) 20:38, 19 October 2016 (UTC)

Puuuh... Kannst du das mal beispielsweise beim 941 machen? Ich bin etwas überfordert...--Ralf Roletschek (talk) 20:51, 19 October 2016 (UTC)

Habe da mal was ausprobiert, siehe Typhoon-class submarine (Q330080). Abfragen kann man das nun auch:

SELECT ?item ?itemLabel ?series WHERE {
	?item p:P31 [
      ps:P31 wd:Q27468928;
      pq:P1545 ?series
    ] .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,ru" }
}

Try it!

. Jetzt wünsche ich aber erstmal eine gute Nacht :-) —MisterSynergy (talk) 21:12, 19 October 2016 (UTC)

Eigenschaft-Einbindung beobachten

Gibt es eine Möglichkeit, die Ergänzung, Änderung oder Entfernung einer bestimmten Eigenschaft in Objekten zu beobachten? Änderungen an verlinkten Seiten ist nicht, was ich suche. Da auch andere Änderungen in den betreffenden Objekten angezeigt, dafür aber Entfernungen nicht. Ich frage insbesondere wegen ECHA Substance Infocard ID (P2566). --Leyo 20:07, 4 October 2016 (UTC)

Hängt so ein bisschen davon ab, wofür Du das beobachten möchtest. Wenn es zum Beispiel bei Wikipedia eine Vorlage zur Eigenschaft gibt, kannst Du grundsätzlich wikipediaseitig einen Wertevergleich vornehmen und je nach Ergebnis wartungskategorisieren. Ich versuche das bei dewiki gerade einzuführen, damit kannst Du zumindest die bei Wikipedia genutzten (bzw. grundsätzlich nutzbaren Daten) überwachen (Existenz, Änderungen und Entfernungen); siehe dazu de:Wikipedia:WikiProjekt_Vorlagen/Werkstatt#Wikidata_in_Vorlage:FISA.3F, de:Vorlage:FISA, und de:Wikipedia_Diskussion:Wikidata#Einrichtung_von_Wartungskategorien_für_Wikidata-Nutzung und beachte, dass von anderen Nutzern bei schon drei anderen Vorlagen ähnliches umgesetzt wurde. Eine andere Möglichkeit wäre, wenn Du Dir eine Listeria-Liste von User:ListeriaBot bauen lässt, wo alle Nutzungen aufgelistet werden. Wenn es Änderungen an der Liste gibt, dann kriegst Du einen diff mit Links… Viele Grüße, MisterSynergy (talk) 20:43, 4 October 2016 (UTC)

Danke für deine ausführliche Antwort. Ich möchte nicht nur die Einbindungen aus der de-WP beobachten, sondern alle. Kann eine Listeria-Liste auch bei Wikidata gepflegt werden oder geschieht dies in der de-WP? --Leyo 21:25, 4 October 2016 (UTC)

Die Liste für den Listeria-Bot kannst Du auch hier bei Wikidata anlegen. Eine Unterseite im BNR oder in einem WikiProject wäre wohl angemessen. Änderungen werden erfahrungsgemäß spätestens binnen tagesfrist vom Bot eingepflegt. —MisterSynergy (talk) 05:10, 5 October 2016 (UTC)

Hm, Template:Wikidata list sieht nicht ganz trivial aus. Ich werde mich da einlesen müssen. --Leyo 08:19, 5 October 2016 (UTC)

Ist eigentlich nicht so schwer, User:MisterSynergy/P2566 reicht da schon. Allerdings sehe ich gerade, dass der Bot sich über zuviele Nutzungen beschwert --- die Liste wird nur bei maximal 5000 Elementen bearbeitet, was ich bisher nicht wusste. Man könnte das nun aufteilen in ein paar Unterlisten, jeweils klein genug für diese Grenze, aber ich kenne gerade kein sinnvolles Kriterium, anhand dessen man das tun würde. Ich schaue mir das später nochmal an… Viele Grüße, MisterSynergy (talk) 08:35, 5 October 2016 (UTC)

@MisterSynergy: Hast du inzwischen ein sinnvolles Kriterium gefunden? Wie wär's mit einer Aufteilung anhand des Werts von P2566, P231 oder der Bezeichnung? --Leyo 21:00, 6 October 2016 (UTC)

Da es um P2566 geht, würde ich auch anhand dessen separieren --- auch wenn das evtl. nachher keine fachliche Bedeutung hat. Sonst läuft man nur in Schwierigkeiten, weil zB. P231 fehlt oder so. Ich habe mir das gerade angeschaut, es würde grob passen da vier Listen zu machen:

• P2566 startet mit "100.00" (zurzeit 4225 Ergebnisse)
• P2566 startet mit "100.0[12]" (zurzeit 2878 Ergebnisse)
• P2566 startet mit "100.0[3-9]" (zurzeit 2854 Ergebnisse) (siehe User:MisterSynergy/P2566)
• P2566 startet mit "100.[1-9]" (zurzeit 2381 Ergebnisse)

Wenn eine der Listen volläuft (5000 Elemente), kannst Du mit dem regex in der Abfrage relativ einfach Elemente umschichten, das sollte je nach zu erwartendem Ausbau aber nicht so häufig passieren.

Du müsstest so zwar vier Wartungsseiten beobachten, kriegst über die diffs des Bots aber alle Ergänzungen, Änderungen und Entfernungen auf der Eigenschaft mit. Leider kann der ListeriaBot nicht mehrere Listen auf einer Seite managen. Irgendwie ist das am Ende eine etwas hinkende Lösung, aber sie würde funktionieren :-) Viele Grüße, MisterSynergy (talk) 05:12, 7 October 2016 (UTC)

Vielen Dank für deine ausführliche Antwort! Ginge es (für eine weitere Wartungsseite) auch, auf Items mit Interwiki in die z.B. de-WP einzuschränken? So könnte für weitere Interessierte aus der de-WP die Beobachtung auf das Relevante eingeschränkt werden. --Leyo 06:52, 7 October 2016 (UTC)

Das geht in jedem Fall, da bewegen wir uns aber außerhalb meiner rudimentären SPARQL-Fähigkeiten. Wir versuchen mal:

SELECT ?item ?itemLabel ?itemDescription ?identifier WHERE {
  ?item wdt:P2566 ?identifier .
  FILTER EXISTS { ?wikilink schema:about ?item . ?wikilink schema:inLanguage "de" . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?identifier)

Try it!

Das sind 6599 Ergebnisse und würde auf zwei Seiten passen (am besten in dewiki). Aber ist das eine realistische Anzahl? Das kannst Du besser beurteilen… —MisterSynergy (talk) 07:06, 7 October 2016 (UTC)

Danke. Hm, ich hätte die Anzahl < 5000 erwartet, aber es kann schon sein, wenn man bedenkt, dass Vorlage:GESTIS zwar nur 3355-mal eingebunden wird, die Infobox Chemikalie aber 8370-mal. In der en-WP binden übrigens gemäss en:Special:Search/ECHA InfoCard 2345 die InfoCard-ID ein, aber laut der angepassten obigen Abfrage gibt es das „Potential“ für 8961. Die Differenz kommt daher, dass nur Artikel mit Chembox diese einbinden, nicht aber mit der Drugbox.

Wäre es möglich, die Aufteilung (und die Sortierung) anhand des Wikipedia-Lemmas zu machen? Das wäre wohl am nützlichsten. Wenn du magst, kannst du mir die beiden Listen unter de:Benutzer:Leyo/InfoCard/0–L und de:Benutzer:Leyo/InfoCard/M–Z oder ähnlich anlegen. --Leyo 08:16, 7 October 2016 (UTC)

Auch das wäre möglich, aber ich kriege das auf die Schnelle nicht hin und hab bis Montag nun wenig Zeit. Vielleicht klappt was heute Abend, vielleicht auch nicht. Wenn jemand anders möchte, dann nur zu, ansonsten schreibe ich mir das mal auf die to-do-Liste. Viele Grüße, MisterSynergy (talk) 08:35, 7 October 2016 (UTC)

Ich habe gerade noch schnell eine gute Idee gehabt, die tatsächlich funktioniert. Die Listen sind bei dewiki nun erstellt. Viele Grüße! —MisterSynergy (talk) 09:42, 7 October 2016 (UTC)

Toll, vielen Dank! Nur eine Frage habe ich noch: Wäre es möglich den vom Lemma abweichenden Linktext weglässt (Beispiel: [[(–)-α-Bisabolol|Bisabolol]])? --Leyo 22:31, 7 October 2016 (UTC)

Das ist glaub ich nicht so einfach. Zurzeit nimmt der Bot das de-Label von Wikidata, und eigentlich wäre es clever wenn wir dananch sortieren, nicht nach dem dewiki-Lemma. Wäre das auch okay? Dann stelle ich Dir das um… —MisterSynergy (talk) 04:52, 8 October 2016 (UTC)

Hm, schade. Wenn das nicht geht, dann ist wohl dein Vorschlag am besten. --Leyo 08:26, 8 October 2016 (UTC)

@MisterSynergy: Könntest du die Anpassung vornehmen, sofern nicht noch dir oder jemand anderem eine andere Lösung in den Sinn gekommen ist?

Aufgrund der extrem langen Diffs bei der Verschiebung der Zählung habe ich diese entfernt. Gibt es vielleicht die Möglichkeit, sich dort die Gesamtzahl ausgeben zu lassen? --Leyo 08:51, 15 October 2016 (UTC)

Ich denke da jetzt schon eine Woche drüber nach und mir kommt bisher keine sinnvolle Alternative in den Sinn. Ich mache mich morgen nochmal dran, wobei die Entfernung der Nummerierung schonmal gut aussieht. Viele Grüße, MisterSynergy (talk) 20:50, 15 October 2016 (UTC)

@Leyo: um hier mal zu einem Ende zu kommen: so richtig doll klappt das alles nicht, eine Sortierung nach dewiki-Lemma bekomme ich nicht brauchbar hin. Ich würde nun vorschlagen: (1) Sortierung nach de-label bei Wikidata (weil es eh angezeigt wird) und (2) keine Nummerierung zur Vermeidung der langen diffs. Das wäre wohl das übersichtlichste was möglich ist. Wenn Du mir grünes Licht gibst, passe ich Dir die beiden Listen schnell an. Viele Grüße! MisterSynergy (talk) 06:09, 21 October 2016 (UTC)

Danke für deine Rückmeldung! Ich bin mit deinem Vorschlag einverstanden. --Leyo 10:54, 21 October 2016 (UTC)

Zweiteiliger Aufsatz

Hallo, wie kann ich in Daseinskampf und gegenseitige Hilfe in der Entwicklung (Q19154093) eine Seitenangabe mit einer Heftnummer verknüpfen? Abbilden möchte ich die Angabe "Heft 1, S. 14–16; Heft 2, S. 42–46". --ChristianSW (talk) 16:48, 19 October 2016 (UTC)

Ich habe das mal was versucht. Passt das so? —MisterSynergy (talk) 16:58, 19 October 2016 (UTC)

Danke, habe auch darüber nachgedacht. Aber wird nun deutlich, dass es zwei Teile sind oder der Eindruck erweckt, der Aufsatz sei an zwei Stellen enthalten? --ChristianSW (talk) 17:06, 19 October 2016 (UTC)

Ergänzung: Habe die Gliederung mit römischen Zahlen als Ordnungsnummer eingetragen. Sieht passend aus. --ChristianSW (talk) 17:12, 19 October 2016 (UTC)

Mh, gute Frage. Auf die Schnelle kann ich dazu nichts finden, diese Ordnungsnummer ist formell nicht erlaubt nach Property talk:P1433, wo man das Thema auch diskutieren könnte. Ich finde aber auch auf Anhieb kein anderes Beispiel dazu… Weiß noch jemand Rat? —MisterSynergy (talk) 17:16, 19 October 2016 (UTC)

Ist nicht "Ordnungsnummer" die selbe Info wie "Ausgabe (Nr.)" und damit eins von beiden überflüssig? Nehmt doch das wo man römische Ziffern eintragen kann. --Molarus 19:38, 19 October 2016 (UTC)

Nein, die Übereinstimmung ist Zufall. In diesem Fall ist "Ausgabe (Nr.)" die Heftnummer, I und II sind die Teile des Aufsatzes. --ChristianSW (talk) 19:48, 19 October 2016 (UTC)

Ich habe da auf der entsprechenden Eigenschaftsseite Property talk:P1433 mal ein Thema zu aufgemacht. Wenn da bis morgen keine Antwort kommt, trage ich das nochmal bei WD:PC vor. —MisterSynergy (talk) 19:56, 19 October 2016 (UTC)

Danke für Deine Hilfe! --ChristianSW (talk) 20:03, 19 October 2016 (UTC)

Rank eines Items abfragen

Ich möchte gerne eine Datenbankabfrage machen, in welchen Items die Property:P1087 Statements hat, die nicht den Normal Rank haben, sondern z. B. einen Prefered Rank. Ein Beispiel wäre das Item Q685064. Wie geht das? 129.13.72.198 11:29, 11 October 2016 (UTC)

SELECT ?item ?itemLabel WHERE {
	?item p:P1087 ?eloStmt .
  	?eloStmt wikibase:rank wikibase:PreferredRank . 
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}

Try it!

—MisterSynergy (talk) 11:41, 11 October 2016 (UTC)

Oh, das sind viele. Eigentlich wollte ich die alle auf Normal Rank setzen, aber bei mehr als 2000 muss da wohl ein Bot ran. 129.13.72.198 12:23, 11 October 2016 (UTC)

Ist das denn sinnvoll? Bei den meisten (oder allen?) der gelisteten Items sind ja mehrere Werte angegeben, die allesamt korrekt sind (und sich durch Zeitstempel-Qualifier unterscheiden). Alle Werte brauchen deshalb mindestens normalen Rang, was auch der Fall ist. Man möchte die Datenbank aber auch so fragen können, dass nur ein Wert rauskommt -- was durch den bevorzugten Rang unter allen korrekten Werten markiert wird. Optimalerweise gibt es eine Festlegung, anhand welchen Kriteriums das passiert (z. B. der jüngste Wert). Wer dann alle Werte haben möchte, kann das trotzdem mit einer geeigneten Abfrage hinbekomen. —MisterSynergy (talk) 12:29, 11 October 2016 (UTC)

Ja, aber im Moment wird eigentlich immer der Wert vom Juni 2015 als Prefered markiert, vermutlich weil er im Juni 2015 ergänzt wurde und damals halt der aktuelle, bevorzugte war. Das ist im Oktober 2016 aber nicht mehr der Fall. Entweder man markiert immer den aktuellen als Prefered, was ich für unnötig halte, oder gar keinen. 129.13.72.198 12:31, 11 October 2016 (UTC)

Immer der aktuelle scheint mir am sinnvollsten. Bei monatlichen Aktualisierungen zieht das aber einigen Aufwand nach sich. User:EloBot, betrieben von User:Wesalius scheint in dem Gebiet aktiv zu sein, mit dem würde ich da erst einmal sprechen. Ein Wikidata:WikiProject Chess gibt es noch nicht. —MisterSynergy (talk) 12:37, 11 October 2016 (UTC)

You mentioned me, but my German language skills start and end in using translate.google.com :-) What is going on? --Wesalius (talk) 13:25, 11 October 2016 (UTC)

I just asked here how to find out Elo statements which have not Normal Rank. 129.13.72.198 14:17, 11 October 2016 (UTC)

More detail: I mentioned you because your bot is very active in adding Elo rating (P1087) statements here. Many chess players have multiple P1087 statements (for different points in time), and for some reason the June 2015 value is often marked with preferred rank and thus delivered when simple queries are performed. From what I read on your talk page, it wasn’t you or your bot who made this. It is a problem, however, which needs to be fixed by someone… and this is where you could perhaps help out with your bot.

It seems to be a good idea to mark the most recent value known with preferred rank, but this requires lots of updates. I don’t know whether you can add new values with preferred rank (only if it is the value of the most recent point in time) using your bot, and whether this would overwrite the old June-2015 preference. As far as I know, only one claim can carry the preferred rank. Do you have any idea, Wesalius? Thanks and regards, MisterSynergy (talk) 14:29, 11 October 2016 (UTC)

Okay I just tried to overwrite the preference: it does not work automatically, one can have multiple preferred ranks. This means that the old one has to be marked normal and the most recent one preferred in two independent edits. —MisterSynergy (talk) 14:32, 11 October 2016 (UTC)

@Laboramus: generally sets preferential ranks for recent values with his PreferentialBot.
--- Jura 14:36, 11 October 2016 (UTC)

This could be very useful as well, more as a permanent task. Laboramus would have to teach his bot to rank according to point in time (P585), which is not described on the bot’s user page at the moment. —MisterSynergy (talk) 14:40, 11 October 2016 (UTC)

True, I did not set those ranks. I think it would be best to set all elo ratings ranks to normal and then have the one running the query decide what elo he wants: most recent one? highest one? oldest one?

Normalizing the ranks shouldnt be a hard bot task, you can request it at Wikidata:Bot requests. --Wesalius (talk) 14:43, 11 October 2016 (UTC)

I founded Wikidata:WikiProject Chess. Also see Property_talk:P1087#Preferred_value:_Highest_or_most_recent.3F. --Wesalius (talk) 08:50, 24 October 2016 (UTC)

Wie Zahl ohne Genauigkeit eingeben?

Wahrscheinlich eine blöde Frage, aber ich schaffe es einfach nicht, eine Zahl ohne Plusminus 1 einzugeben. Wie macht man das? 92.75.205.208 18:27, 11 October 2016 (UTC)

Entweder einfach eingeben und in einem zweiten Edit aus dem ±1 ein ±0 machen, oder von Anfang an ±0 dranhängen. Wenn das zu schwierig zum Eingeben ist: +-0 geht auch. --YMS (talk) 18:30, 11 October 2016 (UTC)

Danke, auf diese einfache Lösung bin ich natürlich nicht gekommen. 92.75.205.208 18:55, 11 October 2016 (UTC)

Anschlussfrage: Gibt es eine Constraint-Vorlage, die auswertet, ob eine Zahl mit oder ohne Ungenauigkeit angegeben wurde? In Category:Constraint templates bin ich nicht fündig geworden. 129.13.72.198 10:55, 12 October 2016 (UTC)

Ich denke das müsstest Du auch mit dem Query-Service abfragen. Was anderes ist mir nicht bekannt. Worum geht’s eigentlich genau? —MisterSynergy (talk) 11:14, 12 October 2016 (UTC)

Naja, wieder um die Elo-Zahlen. Ich hab einige Male Elo-Zahlen eingegeben, und da ich noch nicht wusste, wie man das Plusminus wegkriegt, stand das halt immer dabei. Eventuell ist das auch anderen so gegangen, und diese Werte möchte ich jetzt halt aufspüren und korrigieren. Und wenn wir schonmal dabei sind, kannst du auch eine Abfrage erstellen, die alle Elo-Zahlen ermittelt, die keinen point-in-time-Qualifier haben? 129.13.72.198 13:14, 12 October 2016 (UTC)

SELECT ?item ?itemLabel ?elo WHERE {
	?item wdt:P106 wd:Q10873124 .
  	?item p:P1087 ?elostmt  .
  	?elostmt ps:P1087 ?elo . 
  	FILTER NOT EXISTS { ?elostmt pq:P585 ?foo }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
} ORDER BY ASC(?item)

Try it!

(Elo-Zahlen ohne point in time (P585)-Qualifier) —MisterSynergy (talk) 13:32, 12 October 2016 (UTC) Per Update auf Schachspieler eingegrenzt, die sollten dazu aber alle occupation (P106)chess player (Q10873124) haben.

Ah, diese Abfrage müsste noch auf Schachspieler eingegrenzt werden, da aktuell auch die ganzen Go-Spieler gefunden werden, bei denen nie ein Point-in-Time dabeisteht. Steak (talk) 13:34, 12 October 2016 (UTC)

SELECT ?item ?itemLabel ?elo ?lowerelo ?upperelo WHERE {
	?item wdt:P106 wd:Q10873124 .
  	?item p:P1087/psv:P1087 ?elostmt  .
  	?elostmt wikibase:quantityAmount ?elo . 
	?elostmt wikibase:quantityLowerBound ?lowerelo . 
	?elostmt wikibase:quantityUpperBound ?upperelo . 
  	FILTER ( ?upperelo - ?lowerelo > 0 )
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
} ORDER BY ASC(?item)

Try it!

(Elo-Zahlen von Schachspielern mit ±x, x!=0) —MisterSynergy (talk) 13:42, 12 October 2016 (UTC)

Solche Abfragen können (leicht modifiziert) mit Template:Complex constraint auch als Constraint auf der Property_talk-Seite eingesetzt werden, dann kriegst Du die bekannten Wartungslisten von Bots bereitgestellt. Inwiefern das in diesem Fall sinnvoll ist, will ich nicht bewerten. —MisterSynergy (talk) 13:45, 12 October 2016 (UTC)

Ich habe gesehen in der deWP arbeitet jemand an de:Vorlage:Elo-Diagramm. Gefällt mir. --Molarus 17:34, 12 October 2016 (UTC)

Das bin ich. Danke für die Blumen :) 92.75.208.110 17:48, 12 October 2016 (UTC)