Wikidata:WikiProject Filming Locations

This is Wikidata's WikiProject Filming Locations. The WikiProject covers an aspect of WikiProject Movies.

A "filming location" (Q1045481) is "a place where some or all of a film or television series is produced, in addition to or instead of using sets constructed on a movie studio backlot or soundstage. In filmmaking, a location is any place where a film crew will be filming actors and recording their dialog."

 

There are two main types of locations.

• Location shooting is the practice of filming in an actual setting
• Studio shoots in either a sound stage or backlot

Items for films can state the location with filming location (P915). It's not to be confused with the location the narrative is set. This aspect can be mentioned with narrative location (P840).

Purpose

• Improve and define the structure for information about filming locations on Wikidata
• Import some of the relevant data from Wikipedia categories
• Import the relevant data from Freebase

Participants

• Jura
• Shisma
• Antoine2711
• Manu1400
• Olea

Properties

• on items for films: filming location (P915)
• on categories to group films
  • category combines topics (P971): filming location (Q1045481)
  • category combines topics (P971): film (Q11424)
• locations: category for films shot at this location (P1740)

Map

All filming locations

• Items used: film (Q11424)   

• Properties used: instance of (P31)   , filming location (P915)   , coordinate location (P625)   , title (P1476)   , country (P17)   

• Features used: map (Q24515275)   

# Wikidata Map of Filming Locations
# by Jura1, rev. 2016-10-28, excludes countries
#defaultView:Map
SELECT 
	?film ?title ?filmLabel ?filmDescription 
	?filminglocation ?filminglocationLabel ?coor
WHERE
{
	?film wdt:P31 wd:Q11424 .
  	?film wdt:P915 ?filminglocation .
  	?filminglocation wdt:P625 ?coor .
  	OPTIONAL { ?film wdt:P1476 ?title } .
  	FILTER NOT EXISTS { ?filminglocation wdt:P17 ?filminglocation }
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en" }
}

Try it!

Popular filming locations

• Items used: film (Q11424)   

• Properties used: instance of (P31)   , subclass of (P279)   , filming location (P915)   , coordinate location (P625)   

• Features used: map (Q24515275)   

# Popular filming locations
# Source: https://twitter.com/WikidataFacts/status/797905751675125760
#defaultView:Map
SELECT ?location ?locationLabel ?coords ?count ?layer WHERE {
  {
    SELECT ?location (SAMPLE(?coordinates) AS ?coords) (COUNT(DISTINCT ?film) AS ?count) WHERE {
      ?film wdt:P31/wdt:P279* wd:Q11424;
            wdt:P915 ?location.
      ?location wdt:P625 ?coordinates.
    }
    GROUP BY ?location
    HAVING(?count >= 10)
  }
  BIND(COALESCE(
    IF(?count < 20, "<20", ?_),
    IF(?count < 50, "<50", ?_),
    IF(?count < 100, "<100", ?_),
    IF(?count < 200, "<200", ?_),
    IF(?count < 500, "<500", ?_),
    IF(?count < 1000, "<1000", ?_),
    "≥1000"
    ) AS ?layer).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Filming locations of James Bond films

• Items used: James Bond (Q2009573)   , film (Q11424)   

• Properties used: instance of (P31)   , subclass of (P279)   , filming location (P915)   , coordinate location (P625)   , country (P17)   , cast member (P161)   , character role (P453)   

• Features used: map (Q24515275)   

# Wikidata map of James Bond filming locations
# SPARQL by Jura1, 2016-11-05
#defaultView:Map
SELECT 	?film (CONCAT(str(?actorLabel), " /in/ ", str(?filmLabel), " -- the ", str(?filmDescription)) as ?layer) 
		?enwiki_article	?coor	
		?filminglocation	?filminglocationLabel
{	SELECT DISTINCT ?film	?filmLabel ?filmDescription 	?enwiki_article	?coor	?filminglocation	?filminglocationLabel ?actorLabel ?propertyLabel 
	{
  	?statement pq:P453 wd:Q2009573 .
  	?film p:P161 ?statement . ?statement ps:P161 ?actor .
  	?film wdt:P31/wdt:P279* wd:Q11424 .
  	?film wdt:P915 ?filminglocation .
  	?filminglocation wdt:P625 ?coor . 
    filter not exists { ?filminglocation wdt:P17 ?filminglocation }  
	OPTIONAL { ?enwiki_article schema:about ?film ; schema:isPartOf <https://en.wikipedia.org/> }
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . 
                            ?film rdfs:label ?filmLabel . ?film schema:description ?filmDescription . 
                            ?filminglocation rdfs:label ?filminglocationLabel . ?actor rdfs:label ?actorLabel  }
	}
}

Try it!

Examples

Examples : Film

Item	Batman (Q116852)
Statements	instance of (P31) film (Q11424) filming location (P915) England (Q21) Knebworth House (Q19841) Pinewood Studios (Q661896)

Examples: Category

Item	Category:Films shot in Amsterdam (Q10217113)	Category:Films set in Amsterdam (Q8457557)
Statements	instance of (P31) Wikimedia category (Q4167836) category combines topics (P971) filming location (Q1045481) Amsterdam (Q727) is a list of (P360) film (Q11424) filming location (P915): Amsterdam (Q727) opposite of (P461) Category:Films set in Amsterdam (Q8457557)	instance of (P31) Wikimedia category (Q4167836) category combines topics (P971) geographic setting of film (Q19502208) Amsterdam (Q727) is a list of (P360) film (Q11424) narrative location (P840): Amsterdam (Q727) opposite of (P461) Category:Films shot in Amsterdam (Q10217113)
Comment	(example)	(for comparison)

Examples : List

Item	list of films shot in Iceland (Q6620107)
Statements	instance of (P31) Wikimedia list article (Q13406463) is a list of (P360) film (Q11424) filming location (P915): Iceland (Q189)

Examples : Location

Item	Amsterdam (Q727)
Statements	category for films shot at this location (P1740) Category:Films shot in Amsterdam (Q10217113) country (P17) Netherlands (Q55)

Import from Wikipedia

Source: Category:Films by shooting location (Q55348)

Language	Categories	Films	Done
en	600?	9000?	?%

Resources

• Category:Films by shooting location (Q55348)
• Category:Lists of films by shooting location (Q8597380)
• Wikidata:Database reports/Constraint violations/P915